Как мне неоднократно вызывать каплю AppleScript с разными именами файлов?

Question

У меня есть прекрасная капля AppleScript, которая выполняет распознавание PDF-файла с помощью Adobe Acrobat.Я довольно хороший программист на Python, но на самом деле не понимаю AppleScript.У меня есть список всех PDF-файлов в моей системе, которые необходимо распознать.Было бы очень неприятно, когда нужно перетаскивать каждый элемент на одну вершину сценария.Я хотел бы иметь небольшую программу на Python, в которой каждый сценарий обрабатывает дроплет, или же я хотел бы изменить сценарий, чтобы он считывал текстовый файл и обходился без отбрасываемого содержимого.

Я пытался использовать osascript чтобы открыть PDF-файлы с помощью одного теста:

tell application "OCRIt-Acrobat"
  open alias "imac3:Users:vy32:FFJ.pdf"
end tell

И я получил эту прекрасную ошибку:

31:103: execution error: OCRIt-Acrobat got an error: alias "imac3:Users:vy32:FFJ.pdf" of «script» doesn’t understand the open message. (-1708)

Ну, это не слишком полезно.

Кто-нибудь знает, что мне делать?

Вот OCRIt-Acrobat во всей красе:

property mytitle : "ocrIt-Acrobat"
-- Modified from a script created by Macworld http://www.macworld.com/article/60229/2007/10/nov07geekfactor.html

-- I am called when the user open the script with a double click
on run
    tell me
        activate
        display dialog "I am an AppleScript droplet." & return & return & "Please drop a bunch of PDF files onto my icon to batch OCR them." buttons {"OK"} default button 1 with title mytitle with icon note
    end tell
end run

-- I am called when the user drops Finder items onto the script icon
-- Timeout of 36000 seconds to allow for OCRing really big documents
on open droppeditems
    with timeout of 36000 seconds
        try
            repeat with droppeditem in droppeditems
                set the item_info to info for droppeditem
                tell application "Adobe Acrobat Pro"
                    activate
                    open droppeditem
                end tell
                tell application "System Events"

                    tell application process "Acrobat"

                        click the menu item "Recognize Text Using OCR..." of menu 1 of menu item "OCR Text Recognition" of the menu "Document" of menu bar 1
                        try
                            click radio button "All pages" of group 1 of group 2 of group 1 of window "Recognize Text"
                        end try
                        click button "OK" of window "Recognize Text"

                    end tell

                end tell
                tell application "Adobe Acrobat Pro"
                    save the front document with linearize
                    close the front document
                end tell
            end repeat
            -- catching unexpected errors
        on error errmsg number errnum
            my dsperrmsg(errmsg, errnum)
        end try
    end timeout
end open

-- I am displaying error messages
on dsperrmsg(errmsg, errnum)
    tell me
        activate
        display dialog "Sorry, an error occured:" & return & return & errmsg & " (" & errnum & ")" buttons {"Never mind"} default button 1 with icon stop with title mytitle
    end tell
end dsperrmsg

Спасибо!

Answer 1

Нельзя сказать приложению appleScript открыть файл. Сценарии работают не так, даже если это приложение. Вы делаете это с помощью команды «run script», и вы можете передавать параметры этой командой. В качестве примера создайте эту яблочную капельку и сохраните ее на рабочем столе с именем «aaa».

on run argList
    try
        -- when an application is double-clicked it errors seemingly because no arguments are passed.
        -- class errors in this case so we can use that to set argList to {} so the script will work.
        class of argList
    on error
        set argList to {}
    end try
    someSubroutine(argList)
end run

on open argList
    someSubroutine(argList)
end open

on someSubroutine(argList)
    set argListCount to count of argList
    tell me
        activate
        display dialog "Count of arguments: " & argListCount
    end tell
end someSubroutine

Теперь создайте этот скрипт и запустите его ...

set appPath to (path to desktop as text) & "aaa.app"
run script file appPath with parameters {1, 2}

При запуске таким образом используется "on run argList". Вы можете бросить вещи на него и использовать обработчик "on open argList". Если вы дважды щелкнете по нему снова, будет использоваться «on run argList».

Так что это демонстрирует, как вы можете делать, как хотите. Просто используйте команду «run script» и передайте пути к файлам в параметрах.

Answer 2

Вызывая alias, вы по сути делаете прямой вызов файла по этому точному пути. Если псевдоним не может быть найден, то Applescript выдает ошибку.Если вы читаете список из текстового файла, то может возникнуть ошибка при создании списка, который вы не проверяете.Как минимум, вам нужно использовать системные события, чтобы убедиться, что вы работаете с действительным файлом:

on FileExists(theFile) -- (String) as Boolean
    tell application "System Events"
        if exists file theFile then
            return true
        else
            return false
        end if
    end tell
end FileExists

У меня есть этот шаблон, который я использую для обработки любого количества файлов или папок, которые были сброшены на капле.Пока все ваши целевые файлы находятся в одной иерархии папок, вам не понадобится этот внешний список файлов:

property kTargetFileExtensions : {"txt", "rtf", "pdf"}
property pValidFileList : {}

on open of theFiles -- Executed when files or folders are dropped on the script

    set fileCount to (get count of items in theFiles)

    repeat with thisFile from 1 to fileCount
        set theFile to item thisFile of theFiles

        my processInitialFile(theFile)

    end repeat

    my processValidFileList()

end open

on run {} -- Executed when the script is run from within the editor
    set sourceFolder to (choose folder)

    my processInitialFile(sourceFolder)

    my processValidFileList()
end run

on processInitialFile(theFile)
    tell application "System Events"
        set file_info to get info for theFile
    end tell

    if visible of file_info is true then -- check for the file extension here as well
        if folder of file_info is true then
            my createList(theFile)
        else
            set targetFileFound to isTargetFile(fileName, kTargetFileExtensions) of me

            if (targetFileFound) then
                set end of pValidFileList to theFile
            end if
        end if
    end if
end processInitialFile

on processValidFileList() -- (void) as void
    set firstFile to 1
    set lastFile to (count pValidFileList)
    repeat with thisFile from firstFile to lastFile
        set theFile to item thisFile of pValidFileList

        log theFile

        (* enter file processing code here. *)

    end repeat

end processValidFileList

on createList(mSource_folder)
    set item_list to ""

    tell application "System Events"
        set item_list to get the name of every disk item of (mSource_folder as alias)
    end tell

    set item_count to (get count of items in item_list)

    repeat with i from 1 to item_count
        set the_properties to ""

        set the_item to item i of the item_list
        set fileName to the_item
        set the_item to ((mSource_folder & the_item) as string) as alias

        tell application "System Events"
            set file_info to get info for the_item
        end tell

        if visible of file_info is true then -- check for the file extension here as well
            if folder of file_info is true then
                my createList(the_item)
            else
                set targetFileFound to isTargetFile(fileName, kTargetFileExtensions) of me

                if (targetFileFound) then
                    set end of pValidFileList to the_item
                end if
            end if
        end if

    end repeat
end createList

on isTargetFile(theFilename, theTargetExtensions) -- (string, array) as boolean
    set AppleScript's text item delimiters to "."
    set fileNameList to every text item of theFilename
    set AppleScript's text item delimiters to ""

    try
        set theFileExtension to item 2 of fileNameList as string
    on error
        return false
    end try

    set firstTargetExtension to 1
    set lastTargetExtension to (count theTargetExtensions)
    repeat with thisTargetExtension from firstTargetExtension to lastTargetExtension
        set targetExtension to item thisTargetExtension of theTargetExtensions
        if theFileExtension is targetExtension then
            return true
        end if
    end repeat

    return false
end isTargetFile