Entity Framework - как узнать, что вызывает ошибку ссылочной целостности?

Question

Работая со структурой сущностей, мой код использует LINQ для получения коллекции объектов, которые необходимо удалить из базы данных. Эта коллекция иногда довольно велика в зависимости от обстоятельств - 30 или 40 предметов.

Я продолжаю пытаться удалить эти объекты из связанных объектов, чтобы я мог их удалить, затем вызываю context.DeleteObject () для каждого и, наконец, context.SaveChanges ().

В большинстве случаев это работает очень хорошо, особенно когда коллекция удаляемых объектов очень мала. Однако, когда он большой, этот код иногда выдает ошибку вокруг ссылочной целостности, а именно:

The DELETE statement conflicted with the REFERENCE constraint 
\"FK_ServiceFeatureSchemaFragmentSchemaFragment_SchemaFragment\". 
The conflict occurred in database \"MyDataBase\", 
table \"dbo.ServiceFeatureSchemaFragmentSchemaFragment\".\r\n
The statement has been terminated. 

Похоже, что иногда мои объекты имеют дополнительные ограничения, которые я не могу найти и удалить из пары перед удалением.

То, с чем я борюсь, это то, что, поскольку я работаю с относительно большой коллекцией, я не могу понять, какие из них вызывают это. Я ищу предложения относительно того, как я могу двигаться вперед, идентифицируя проблемные объекты каким-либо образом, например, есть ли способ, которым вы можете заранее определить, будут ли объекты в коллекции вызывать подобные ошибки перед вами? удалить их? Или другой подход?

Предложения с благодарностью приняты.

Answer 1

Напишите хранимую процедуру в SQL Server, где вы можете увидеть влияние ваших отношений FK / PK без дополнительного уровня отображения EF, чтобы запутать вещи. В этом примере для запуска удаления используется либо целочисленный ezUserID из таблицы основного профиля пользователя, либо GUID членства в ASP.NET.

Вы можете просто использовать Каскадные удаления, когда определяете свои отношения ...

SET ANSI_NULLS ON
SET QUOTED_IDENTIFIER ON
GO


CREATE PROC [dbo].[ezUser_Delete]
    @ezUserID int = NULL,
    @UserName nvarchar(128) = NULL
AS
BEGIN
    SET NOCOUNT ON

    DECLARE @UserID uniqueidentifier;

    --DECLARE @TranName VARCHAR(20);   --Generally shouldn't use named transactions in stored procedures
    --SELECT @TranName = 'MyTransaction';
    SET XACT_ABORT ON

    IF @ezUserID IS NULL AND @UserName IS NULL RETURN 0

BEGIN TRY
    BEGIN TRANSACTION;

            IF ISNULL(@ezUserID, 0) > 0

                BEGIN
                    SELECT @UserID = UserID FROM ezUsers WHERE ezUserID = @ezUserID
                    SELECT @UserName = UserName FROM aspnet_Users WHERE UserID = @UserID 
                    IF (@UserName IS NULL)
                        BEGIN
                            ROLLBACK TRANSACTION;
                            RETURN -1
                        END
                END

            ELSE IF (LEN(ISNULL(@UserName,'')) > 0)

                BEGIN
                    SELECT @UserID = UserID FROM aspnet_Users WHERE UserName = @UserName
                    SELECT @ezUserID = ezUserID FROM ezUsers WHERE UserID = @UserID  
                    IF (@ezUserID IS NULL)
                        BEGIN
                            ROLLBACK TRANSACTION;
                            RETURN -1
                        END
                END

            ELSE 
                RETURN -1

            SELECT 'DELETE' AS [Command]
                , U.UserID
                , U.UserName
                , RoleName
                , M.Email
                , EU.ezUserID
                , EU.FirstName, EU.LastName
                , CallSign
                , Gender
                , UIR.RoleID

            FROM dbo.aspnet_Users U 
                    LEFT OUTER JOIN dbo.aspnet_Membership M ON U.UserID = M.UserID

                    LEFT OUTER JOIN dbo.ezUsers EU ON U.UserID = EU.UserID      

                    LEFT OUTER JOIN dbo.aspnet_UsersInRoles UIR ON U.UserID = UIR.UserID
                    LEFT OUTER JOIN dbo.aspnet_Roles R ON UIR.RoleID = R.RoleID     
            WHERE U.UserID = @UserID 

            IF @UserID IS NULL
                RETURN -1

            DELETE FROM dbo.ezUsersDating   WHERE ezUserID = @ezUserID  
            DELETE FROM dbo.ezUsersPhysicalIdentity WHERE ezUserID = @ezUserID

            DELETE FROM dbo.ezMessages WHERE AuthorID = @ezUserID

            DELETE FROM dbo.ezTheUsual WHERE ezUserID = @ezUserID
            DELETE FROM dbo.ezRentals WHERE ezUserID = @ezUserID

            DELETE FROM dbo.ezUsersSharedActivities WHERE ezUserID = @ezUserID

            DELETE FROM dbo.ezCurrentVehicle WHERE UVID IN (SELECT UVID FROM dbo.ezUsersVehicles WHERE ezUserID = @ezUserID)
            DELETE FROM dbo.ezDriverVehicles WHERE ezUserID = @ezUserID  -- Delete this Table
            DELETE FROM dbo.ezOwnerVehicles WHERE OwnerID = @ezUserID   
            DELETE FROM dbo.ezUsersVehicles WHERE ezUserID = @ezUserID

            DELETE FROM dbo.ezPL8Messages 
                WHERE PL8ID IN (
                SELECT PL8ID FROM dbo.ezPL8s WHERE VehicleID IN (SELECT VehicleID FROM dbo.ezVehicles WHERE CreatedBy = @ezUserID))

            DELETE FROM dbo.ezPL8s WHERE VehicleID IN (SELECT VehicleID FROM dbo.ezVehicles WHERE CreatedBy = @ezUserID)

            DELETE FROM dbo.ezPL8s_Vehicles WHERE VehicleID IN (SELECT VehicleID FROM dbo.ezVehicles WHERE CreatedBy = @ezUserID)

            DELETE FROM dbo.ezVehicles WHERE CreatedBy = @ezUserID

            DELETE FROM dbo.ezImages_Users
            WHERE ImageID IN (SELECT ImageID FROM dbo.ezImages 
                                WHERE UploadedBy = @ezUserID)

            DELETE FROM dbo.ezImages_Users
            WHERE ezUserID = @ezUserID

            DELETE FROM dbo.ezImages 
            WHERE UploadedBy = @ezUserID

            DELETE FROM dbo.ezPets
            WHERE ezUserID = @ezUserID

            DELETE FROM dbo.ezAccounts
            WHERE CPID IN (SELECT CPID FROM dbo.ezCompany_People WHERE ezUserID = @ezUserID)

            DELETE FROM dbo.ezCompany_People
            WHERE ezUserID = @ezUserID          

            DELETE FROM dbo.ezMedicals
            WHERE ezUserID = @ezUserID

            DELETE FROM dbo.ezVehicles WHERE CreatedBy = @ezUserID

            DELETE FROM dbo.ezParentChildren WHERE ParentID = @UserID OR ChildID = @UserID
            DELETE FROM dbo.ezEmergencyContacts WHERE ezUserID = @ezUserID

            DELETE FROM dbo.ezDriveThrus_Customers WHERE ezUserID = @ezUserID   

            DELETE FROM dbo.ezRelationshipsP2P WHERE RelFromID = @UserID OR RelToID = @UserID

            DELETE FROM [dbo].[ezPL8Meaning] WHERE ezUserID = @ezUserID

            DELETE FROM dbo.ezUsers WHERE UserID = @UserID 

            DELETE FROM dbo.aspnet_PersonalizationPerUser WHERE UserID = @UserID
            DELETE FROM dbo.aspnet_Profile WHERE UserID = @UserID
            DELETE FROM dbo.aspnet_UsersInRoles WHERE UserID = @UserID

            DELETE FROM dbo.aspnet_Membership WHERE UserID = @UserID    

            DELETE FROM dbo.aspnet_Users WHERE UserID = @UserID     

    COMMIT TRANSACTION;  
END TRY

BEGIN CATCH
    SELECT ERROR_NUMBER(), ERROR_MESSAGE();
    IF @@TRANCOUNT > 0  
        ROLLBACK TRANSACTION;

    RAISERROR('Error', 16, 1)
    RETURN 0
END CATCH

END 






GO