Как заново связать комбобокс в winforms?

Question

У меня есть приложение Winforms, и в поле со списком при загрузке формы для источника данных установлено значение DataTable. Данные хорошо отображаются в выпадающем списке.

Затем, когда пользователь нажимает кнопку, я хочу создать новую таблицу данных и назначить ее в качестве источника данных для комбинированного списка.

Проблема в том, что после установки нового источника данных в качестве источника данных элементы в выпадающем списке не изменяются. Вот код, который я использую.

dlCustomer.DataSource = Nothing
        dlCustomer.DataSource = dtCustomers
        dlCustomer.DisplayMember = "Name"
        dlCustomer.Refresh()

Кто-нибудь знает, как сделать так, чтобы в выпадающем списке отображались правильные данные во второй раз, когда я назначаю для него источник данных?

Answer 1

Это должно сработать, по крайней мере, это сработало в быстром тесте, который я бросил вместе. Вот код; он просто ожидает форму с ComboBox и кнопкой:

    Public Class Form1

        Private dtOne As DataTable
        Private dtTwo As DataTable

        Private Sub InitializeTables()
            dtOne = New DataTable("TableOne")
            With dtOne
                .Columns.Add("Text", GetType(String))
                .Columns.Add("Value", GetType(Integer))
            End With

            dtTwo = New DataTable("TableTwo")
            With dtTwo
                .Columns.Add("Text", GetType(String))
                .Columns.Add("Value", GetType(Integer))
            End With

            Dim newRow As DataRow
            For index As Integer = 0 To 2
                newRow = dtOne.NewRow
                newRow.ItemArray = (New Object() {SpellIt(index), index})
                dtOne.Rows.Add(newRow)
            Next

            For index As Integer = 2 To 0 Step -1
                newRow = dtTwo.NewRow
                newRow.ItemArray = (New Object() {SpellIt(index), index})
                dtTwo.Rows.Add(newRow)
            Next

            dtOne.AcceptChanges()
            dtTwo.AcceptChanges()

        End Sub

        Private Shared Function SpellIt(ByVal int As Integer) As String
            Select Case int
                Case 0 : Return "Zero"
                Case 1 : Return "One"
                Case 2 : Return "Two"
                Case Else : Throw New ArgumentOutOfRangeException("Bleh!")
            End Select
        End Function

        Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
            InitializeTables()

            Me.Label1.DataBindings.Add("Text", ComboBox1, "SelectedValue")

            Me.ComboBox1.DataSource = dtOne
            Me.ComboBox1.DisplayMember = "Text"
            Me.ComboBox1.ValueMember = "Value"

        End Sub

        Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
            Me.ComboBox1.DataBindings.Clear()
            Me.ComboBox1.DataSource = Nothing

            Me.ComboBox1.DataSource = dtTwo
            Me.ComboBox1.DisplayMember = "Text"
            Me.ComboBox1.ValueMember = "Value"

        End Sub

    End Class