Почему Mathematica не оценивает этот RecurrenceTable численно?

Question

Я пытаюсь сделать RecurrenceTable с условными выражениями в Mathematica, и рекурсивный материал работает правильно, но он не оценит его полностью.

In:= RecurrenceTable[{x[n] == If[Mod[n, 2] == 0, x[n - 1], y[n - 1]], 
       y[n] == If[Mod[n, 2] == 0, R x[n - 1] (1 - x[n - 1]), y[n - 1]], 
       x[1] == x0, y[1] == 0}, {x, y}, {n, 1, 10}]

Out:= {{0.25, 0.}, {x[1], 3 (1 - x[1]) x[1]}, {y[2], y[2]}, {x[3], 
        3 (1 - x[3]) x[3]}, {y[4], y[4]}, {x[5], 3 (1 - x[5]) x[5]}, {y[6], 
        y[6]}, {x[7], 3 (1 - x[7]) x[7]}, {y[8], y[8]}, {x[9], 
        3 (1 - x[9]) x[9]}}

Это правильные результаты, но мне нужно, чтобы они были в числовой форме, т.е. {{0.25, 0.}, {0.25, 0.5625} ...

Есть ли способ сделать это? Спасибо!

Answer 1

Как правило, вы должны использовать Piecewise для математических функций и резервировать If для программирования потока.

Вы можете конвертировать множество If операторов, используя PiecewiseExpand:

If[Mod[n, 2] == 0, x[n - 1], y[n - 1]] // PiecewiseExpand
If[Mod[n, 2] == 0, r*x[n - 1] (1 - x[n - 1]), y[n - 1]] // PiecewiseExpand

Окончательный код может выглядеть примерно так:

r = 3;
x0 = 0.25;
RecurrenceTable[
 {x[n] == Piecewise[{{x[n - 1], Mod[n, 2] == 0}}, y[n - 1]],
  y[n] == Piecewise[{{r*x[n - 1] (1 - x[n - 1]), Mod[n, 2] == 0}}, y[n - 1]],
  x[1] == x0,
  y[1] == 0},
 {x, y},
 {n, 10}
]

{{0.25, 0.}, {0.25, 0.5625}, {0.5625, 0.5625}, {0.5625, 
  0.738281}, {0.738281, 0.738281}, {0.738281, 0.579666}, {0.579666, 
  0.579666}, {0.579666, 0.73096}, {0.73096, 0.73096}, {0.73096, 0.589973}}

Пара связанных точек:

1. Лучше не использовать заглавные буквы в именах символов, поскольку они могут конфликтовать со встроенными функциями.

2. Вы можете рассмотреть Divisible[n, 2] вместо Mod[n, 2] == 0, если хотите.

Answer 2

RecurrenceTable[{
 x[n] == Boole[ Mod[n,2] == 0 ] x[n-1] +
         Boole[ Mod[n,2] != 0 ] y[n-1],
 y[n] == Boole[ Mod[n,2] == 0 ] 3 x[n-1] (1-x[n-1]) + 
         Boole[ Mod[n,2] != 0 ] y[n-1],
 x[1] == .25, y[1] == 0},
 {x, y}, {n, 1, 10}]

с правками R = 3 и x0 = .25 дает ожидаемый результат.