xslt - не может получить доступ к текущему узлу с помощью селектора атрибутов - PullRequest
Новая
       0

xslt - не может получить доступ к текущему узлу с помощью селектора атрибутов

1 голос
/ 27 сентября 2011

Я пытаюсь преобразовать xml-файл с таблицей стилей xsl в html.

это ява 

TransformerFactory tFactory = TransformerFactory.newInstance();
            Transformer transformer = tFactory.newTransformer(new StreamSource(classLoader.getResourceAsStream("driving.xsl")));
            StreamResult drivingHtml = new StreamResult(new StringWriter());
            transformer.transform(new StreamSource(classLoader.getResourceAsStream("driving.xml")), drivingHtml);
            System.out.println(drivingHtml.getWriter().toString());

это некоторые из XML: 

<?xml version="1.0" encoding="UTF-8"?>
<user xmlns="http://notreal.org/ns1" xmlns:poi="http://notreal2.org/ns2">
    <address type="primary">
        <street>1031 Court St.</street>
        <city>Monhegan, NY</city>
    </address>

    <address type="secondary">
        <street> Elm St.</street>
    </address>

это xsl: 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/">
        <html>
            <head>
            <title>User</title>
            </head>
             <body>
                       <p>Detailed Addresses</p>
                       <table>
                 <th>Primary</th>
                 <th>Secondary</th>
                          <tr>
                <xsl:apply-templates select="/user/address"/>
                          </tr>
                         </table>
             </body>
         </html>
    </xsl:template>

     <xsl:template match="address">
          <td>
             <xsl:value-of select=".[@type='primary']/street" />
             <xsl:value-of select=".[@type='secondary']/street" />
          </td>
          <td>
             <xsl:value-of select=".[@type='primary']/city" />
             <xsl:value-of select=".[@type='secondary']/city" />
          </td>
     </xsl:template>
</xsl:stylesheet>

когда я запускаю это, я получаю "не могу скомпилировать таблицу стилей"

1 Ответ

1 голос
/ 27 сентября 2011

Ваша основная проблема, основанная на предоставленном коде XML и XSLT, заключается в том, что ваш код вообще не учитывает тот факт, что элементы в документе XML находятся в пространстве имен по умолчанию .

Как обрабатывать XML-документ с пространством имен по умолчанию - это часто задаваемые вопросы - просто выполните поиск по тегам xslt и xpath, и вы найдете множество хороших ответов.

Вот одно из возможных решений :

Это преобразование : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:x="http://notreal.org/ns1"
 exclude-result-prefixes="x">
 <xsl:output method="xml" omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <html>
    <head>
     <title>User</title>
    </head>
    <body>
      <p>Detailed Addresses</p>
       <table>
        <thead>
         <xsl:apply-templates select="x:address/@type"/>
        </thead>
        <tr>
         <xsl:apply-templates select="x:address/x:street"/>
        </tr>
        <tr>
         <xsl:apply-templates select="x:address/x:city"/>
        </tr>
       </table>
    </body>
  </html>
 </xsl:template>

 <xsl:template match="@type">
  <th><xsl:value-of select="."/></th>
 </xsl:template>

 <xsl:template match="x:address/*">
  <td><xsl:value-of select="."/></td>
 </xsl:template>
</xsl:stylesheet>

при применении к полному и правильно сформированному документу XML, который включает фрагмент XML, представленный в вопросе : 

<user xmlns="http://notreal.org/ns1"
xmlns:poi="http://notreal2.org/ns2">
    <address type="primary">
        <street>1031 Court St.</street>
        <city>Monhegan, NY</city>
    </address>

    <address type="secondary">
        <street>203 Elm St.</street>
        <city>Pittsburgh, PA</city>
    </address>
</user>

дает (что кажется) желаемый, правильный результат : 

<html>
   <head>
      <title>User</title>
   </head>
   <body>
      <p>Detailed Addresses</p>
      <table>
         <thead>
            <th>primary</th>
            <th>secondary</th>
         </thead>
         <tr>
            <td>1031 Court St.</td>
            <td>203 Elm St.</td>
         </tr>
         <tr>
            <td>Monhegan, NY</td>
            <td>Pittsburgh, PA</td>
         </tr>
      </table>
   </body>
</html>
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...