Запрос SCCM из последовательности задач - возможно ли это? - PullRequest
Новая
       31

Запрос SCCM из последовательности задач - возможно ли это?

1 голос
/ 28 июля 2011

У меня есть VBscript, который отлично работает на моей рабочей станции.Он запрашивает SCCM, чтобы выяснить, в каком домене находится компьютер. Когда я запускаю его как часть последовательности задач, происходит сбой.Обратите внимание, что это почти последний шаг в последовательности задач, в Windows 7, а не в Windows PE. 

Option Explicit

Const wbemFlagReturnImmediately = &H10
Const wbemFlagForwardOnly = &H20

Dim computerName, userName, userPassword, server
Dim swbemLocator, swbemServices, providerLoc
Dim location, connection
Dim query, found, resource, resources

'--- Settings ---
userName = "domain\username"
userPassword = "password"
server = "domain.com"  

'--- Get computer name ---
computerName = CreateObject("WScript.Network").ComputerName
WScript.Echo"Computer name: " & computerName

'--- Connect ----
Set swbemLocator = CreateObject("WbemScripting.SWbemLocator")
swbemLocator.Security_.AuthenticationLevel = 6
Set swbemServices = swbemLocator.ConnectServer(server, "root\sms",userName,userPassword)
Set providerLoc = swbemServices.InstancesOf("SMS_ProviderLocation")
For Each location In providerLoc
    If location.ProviderForLocalSite = True Then
        WScript.Echo "SiteCode: " & location.SiteCode       
        Set connection = swbemLocator.ConnectServer(server, "root\sms\site_" + location.SiteCode)
    Else
        WScript.Echo "Not provider for local site."
    End If
Next

'--- Query & output ---
query = "SELECT * FROM SMS_FullCollectionMembership WHERE name = '" & computerName & "'"
Set resources = connection.ExecQuery(query, , wbemFlagForwardOnly Or wbemFlagReturnImmediately)
found = False
For Each resource In resources
    WScript.Echo "Domain: " & resource.Domain & " (" & resource.CollectionID & ")"
    found = True
    Exit For
Next
If Not found Then WScript.Echo "Computer not found!"

Если я открою командную строку, рутинную последовательность задач (используя F8 под Windows 7, а не Windows PE) и запускаю скрипт, я получаю:

SWbemLocator: Доступ запрещен

на линии: 

Set connection = swbemLocator.ConnectServer(server, "root\sms\site_" + location.SiteCode)

Есть мысли?В качестве альтернативы, есть ли другие предложения о том, как узнать, каким доменом был компьютер в последний раз, когда он был собран?

Ответы [ 2 ]

1 голос
/ 22 ноября 2011

Ваша последовательность задач выполняется в контексте локальной системной учетной записи, и по умолчанию эта учетная запись не имеет прав в SCCM.

Если вы определите «ваш домен \ компьютеры домена» в консоли администратора SCCM «Права доступа», «Пользователи» и предоставите им права на чтение и чтение ресурсов в Collection, вы сможете подключиться к серверу SCCM.

Обратите внимание, что вы должны сделать это на всех серверах сайтов, к которым вы хотите подключиться, эти определения не реплицируются между сайтами.

0 голосов
/ 04 декабря 2013

Я понимаю, что это очень старый пост, но у меня была эта проблема. У вас уже есть имя пользователя и пароль в скрипте, и он используется здесь 

Set swbemServices = swbemLocator.ConnectServer(server, "root\sms",userName,userPassword)

Однако чуть дальше вы устанавливаете соединение с сайтом без имени пользователя и пароля. 

Set connection = swbemLocator.ConnectServer(server, "root\sms\site_" + location.SiteCode)

Попробуйте это: 

Set connection = swbemLocator.ConnectServer(server, "root\sms\site_" + location.SiteCode, userName, userPassword)

Надеюсь, это кому-нибудь поможет!

...