Как разобрать вложенные теги с помощью XSLT в последовательности?

Question

У меня есть сценарий ниже для моего XML.

<content>
  <para>text-1 <emphasis type="bold">text-2</emphasis> text-3</para>
</content>

Я хочу разобрать, как показано ниже

<content>
<p>text-1 <b>text-2</b> text-3</p>
</content>

Я создал свой XSLT, как показано ниже

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
<xsl:output method="xml" encoding="ISO-8859-1" indent="no"/>

<xsl:template name="para">
    <p>
        <xsl:value-of select="text()" disable-output-escaping="yes"/>
        <xsl:for-each select="child::*">
            <xsl:if test="name()='emphasis'">
                <xsl:call-template name="emphasis"/>
            </xsl:if>
        </xsl:for-each>

    </p>
</xsl:template>
<xsl:template name="emphasis">
    <xsl:if test="attribute::type = 'bold'">
        <b>
            <xsl:value-of select="text()" disable-output-escaping="yes"/>
        </b>
    </xsl:if>
</xsl:template>

<xsl:template match="/">
    <content>
        <xsl:for-each select="content/child::*">
            <xsl:if test="name()='para'">
                <xsl:call-template name="para"/>
            </xsl:if>
        </xsl:for-each>
    </content>
</xsl:template>
</xsl:stylesheet>

XSLT, представленный выше, генерирует вывод, как показано ниже

<content>
 <p>text-1  text-3<b>text-2 </b></p>
</content>

Пожалуйста, направьте меня со своими предложениями, как я могу получить желаемое?

Answer 1

сделай так;)

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>

    <xsl:template match="content">
        <content><xsl:apply-templates select="para" /></content>
    </xsl:template>

    <xsl:template match="emphasis [@type='bold']">
        <b><xsl:value-of select="." /></b>
    </xsl:template>

</xsl:stylesheet>

когда вы делаете это так, шаблон по умолчанию будет ловить text-1 и text-3

Answer 2

Чтобы сделать это, вам просто нужно расширить стандартное Identity Transform специальными случаями для соответствия ваших para и emphasis элементов.Например, для элементов para необходимо заменить para на p , а затем продолжить сопоставление всех дочерних узлов

<xsl:template match="para">
    <p>
        <xsl:apply-templates select="@*|node()"/>
    </p>
</xsl:template>

Итак, с учетом следующего XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" />

    <!-- This is the Identity Transform -->
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <!-- Replace para with p -->
    <xsl:template match="para">
        <p>
            <xsl:apply-templates select="@*|node()"/>
        </p>
    </xsl:template>

    <!-- Replace emphasis with b -->
    <xsl:template match="emphasis[@type='bold']">
        <b>
            <xsl:apply-templates select="node()"/>
        </b>
    </xsl:template>
</xsl:stylesheet>

Применительно к следующему входному XML

<content> 
  <para>text-1 <emphasis type="bold">text-2</emphasis> text-3</para> 
</content> 

Ниже выводится

<content>
    <p>text-1 <b>text-2</b> text-3</p>
</content>

Вы должны увидетьнасколько легко распространиться на другие случаи, если у вас в XML есть больше тегов для преобразования.