Простой файл чтения / записи .dat в Delphi

Question

По какой-то причине моя учетная запись OpenID больше не существует, даже когда я использовал ее вчера. Но все равно.

Мне нужно сохранить данные записи в файл .dat. Я много пробовал, но все это было связано с базами данных и BLOB-объектами. Я не смог ничего из этого построить.

У меня есть следующая запись

   type
   Scores = record
     name: string[50];
     score: integer;
   end;  

var rank: array[1..3] of scores;

Мне просто нужен простой способ сохранения и чтения данных записи из файла .dat. У меня была книга о том, как это сделать, но она в школе.

Answer 1

Вам также следует взглянуть на file of -метод.

Это несколько устарело, но это хороший способ научиться работать с файлами.

Поскольку записи с динамическими массивами (включая обычные строки) не могут быть сохранены в файлах с помощью этого метода, строки Unicode не будут поддерживаться. Но string[50] основан на ShortStrings, и поэтому ваша запись уже не в юникоде ...

Запись в файл

var
  i: Integer;
  myFile: File of TScores;
begin
  AssignFile(myFile,'Rank.dat');
  Rewrite(myFile);

  try
    for i := 1 to 3 do
      Write(myFile, Rank[i]);
 finally
   CloseFile(myFile);
 end;
end; 

Чтение из файла

var
  i: Integer;
  Scores: TScores;
  myFile: File of TScores;
begin
  AssignFile(myFile, 'Rank.dat');
  Reset(myFile);

  try
    i := 1;
    while not EOF(myFile) do 
    begin
      Read(myFile, Scores);
      Rank[i] := Scores;      //You will get an error if i is out of the array bounds. I.e. more than 3
      Inc(i);
    end;
  finally
   CloseFile(myFile);
  end;
 end; 

Answer 2

Использовать потоки.Вот простая демонстрация (просто демонстрация - на практике нет необходимости каждый раз заново открывать поток файлов):

type
  Scores = record
    name: string[50];
    score: integer;
  end;

var rank: array[1..3] of scores;

procedure WriteScores(var Buf; Count: Integer);
var
  Stream: TStream;

begin
  Stream:= TFileStream.Create('test.dat', fmCreate);
  try
    Stream.WriteBuffer(Buf, SizeOf(Scores) * Count);
  finally
    Stream.Free;
  end;
end;

procedure ReadScore(var Buf; Index: Integer);
var
  Stream: TStream;

begin
  Stream:= TFileStream.Create('test.dat', fmOpenRead or fmShareDenyWrite);
  try
    Stream.Position:= Index * SizeOf(Scores);
    Stream.ReadBuffer(Buf, SizeOf(Scores));
  finally
    Stream.Free;
  end;
end;

// write rank[1..3] to test.dat
procedure TForm1.Button1Click(Sender: TObject);
begin
  rank[2].name:= '123';
  WriteScores(rank, Length(Rank));
end;

// read rank[2] from test.dat
procedure TForm1.Button2Click(Sender: TObject);
begin
  rank[2].name:= '';
  ReadScore(rank[2], 2 - Low(rank));
  ShowMessage(rank[2].name);
end;

Answer 3

Посмотрите в справке под «blockread» и или «blockwrite».Там, вероятно, будет пример