Реализация Фибоначчи в сборке, дающая неожиданные результаты - PullRequest
Новая
       20

Реализация Фибоначчи в сборке, дающая неожиданные результаты

4 голосов
/ 23 октября 2011

Я пытаюсь написать версию кода Фибоначчи на ассемблере, которая дает n-е число Фибоначчи и возвращает его.

Почему-то возникают проблемы с сохранением возвращаемого значения чисел Фибоначчи и их сложением.

Я хочу напечатать n-е число Фибоначчи.

Я сделал некоторые изменения в моем коде, теперь он все еще неверен, но он ближе. Теперь он говорит мне, что 11-е число Фибоначчи равно 48. Все еще неверно, но мы где-то правы? 

.text

    .globl _fibonacci
_fibonacci:
    pushl %ebp
    movl %esp,%ebp
    push %esi
    movl 8(%ebp),%esi

    cmp $1,%esi
    jle BASE
    sub $1,%esi
    push %esi
    call _fibonacci
    add $4,%esp
    movl %eax,%edx
    sub $1,%esi
    push %esi
    call _fibonacci
    add $4,%esp
    add %eax,%edx
    movl %edx,%eax

DONE:
    pop %esi
    pop %ebp
    ret

BASE:
    mov $1,%eax
    jmp DONE

Я вызываю этот ассемблерный код, используя C: 

#include <stdio.h>

int fibonacci(int n);

int main(void){
  int n=111;
  int x=fibonacci(n);
  printf("The %d fibonaacci number is %d\n",n,x);
}

Ответы [ 2 ]

2 голосов
/ 23 октября 2011

Ваши рекурсивные вызовы удушают %edx. Вам нужно pushl %edx в вашем прологе и popl %edx в вашем постлоге, например: 

.text

    .globl _fibonacci
/* fib(n) = fib(n-1) + fib(n-2) */
_fibonacci:
    pushl %ebp
    movl %esp,%ebp
    pushl %esi
    pushl %edx  /* <-- PUSH TO SAVE BEFORE CLOBBERING */
    movl 8(%ebp),%esi

    /* 0th and 1st numbers are defined to be 1. */
    cmpl $1,%esi
    jle BASE

    /* find fib(n-1) */
    subl $1,%esi
    pushl %esi
    call _fibonacci

    addl $4,%esp
    movl %eax,%edx  /* <-- %edx CLOBBERED! */

    /* find fib(n-2) */
    subl $1,%esi
    pushl %esi
    call _fibonacci

    addl $4,%esp
    addl %edx,%eax

DONE:
    popl %edx  /* <-- POP TO RESTORE AFTER CLOBBERING */
    popl %esi
    popl %ebp
    ret

BASE:
    movl $1,%eax
    jmp DONE

Использование этого драйвера: 

// BUILD -arch i386 ONLY
// clang -arch i386 fib.s fibo.c -o fibo
#include <stdio.h>

int fibonacci(int n);

void Test(int i) {
  int r = fibonacci(i);
  printf("fib(%d) -> %d\n", i, r);
}

int main(void){
  for (int i = 0; i < 10; ++i) {
    Test(i);
  }
  return 0;
}

Тестовый прогон выглядит так: 

$ ./fibo 
fib(0) -> 1
fib(1) -> 1
fib(2) -> 2
fib(3) -> 3
fib(4) -> 5
fib(5) -> 8
fib(6) -> 13
fib(7) -> 21
fib(8) -> 34
fib(9) -> 55
1 голос
/ 23 октября 2011

Проблема в том, что вам нужно быть более осторожным с использованием регистров в рекурсивных вызовах.

Ваш код предполагает, что %edx сохраняет свое значение при втором вызове.

Однако это не так, потому что _fibonacci меняет его.

...