Добавление разрыва строки в PDF с помощью XSL-FO? - PullRequest
Новая
       3

Добавление разрыва строки в PDF с помощью XSL-FO?

11 голосов
/ 20 июля 2011

Попытка создать файл PDF на основе XML и файл с использованием XMLSpy.

Я пытаюсь разбить поле на две строки в зависимости от содержимого поля.

Например, если мой varialbe = "John Doe AKA Johnny D", я хочу просмотреть его так:

Джон Доу

Джонни Д

Моя проблема в том, что я не могу заставить его работать даже со всеми семплами в сети.

Вот мой код:

& # хА; 

     <xsl:value-of disable-output-escaping="yes" select="concat(substring-before(//MyField,'AKA'),$newline,substring-after(//MyField,'AKA'))" /> 
  </xsl:when>

Так что в принципе, каждый раз, когда я нахожу строку "АКА", я хочу разбить поле на две строки. Итак, мой код находит строку, создает новую переменную, но все еще показывает одну строку. Я пытался создать переменную с пустой строкой, используя все виды техников, но все еще показывает одну строку.

Есть мысли?

Ответы [ 2 ]

16 голосов
/ 20 июля 2011

См. мой ответ здесь об использовании шестнадцатеричной ссылки на сущность и linefeed-treatment.

Редактировать

Я взял ваш кодиз комментариев и поместите его в шаблон в таблице стилей XSLT.Единственное, что я изменил, было:

  1. Я изменил вашу newline переменную на &#xA;.
  2. Я добавил linefeed-treatment="preserve" к вашему fo:block.

Используя фиктивный XML-файл и таблицу стилей XSLT, я создал документ XSL-FO, который при рендеринге с FOP выдает «John Doe» и «Johnny D» в отдельных строках.

Вот XML-файл: 

<doc>
  <MyField>John Doe AKA Johnny D</MyField>
</doc>

Вот таблица стилей XSLT: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="/">
    <fo:root>
      <fo:layout-master-set>
        <fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
          <fo:region-body margin="1in" margin-top="1.5in"/>
        </fo:simple-page-master>
      </fo:layout-master-set>
      <fo:page-sequence master-reference="my-page">
        <fo:flow flow-name="xsl-region-body">
          <xsl:apply-templates/>
        </fo:flow>
      </fo:page-sequence>
    </fo:root>
  </xsl:template>

  <xsl:template match="doc">
    <xsl:variable name="newline" select="'&#xA;'"/>        
    <xsl:variable name="MyVar">
      <xsl:choose>
        <xsl:when test="contains(//MyField,'AKA')">
          <xsl:value-of select="concat(substring-before(//MyField,'AKA'),$newline,substring-after(//MyField,'AKA'))"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="//MyField"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <fo:block linefeed-treatment="preserve">
      <xsl:value-of select="$MyVar"/>
    </fo:block>
  </xsl:template>

</xsl:stylesheet>

Вот итоговый XSL-FO: 

<fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
   <fo:layout-master-set>
      <fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
         <fo:region-body margin="1in" margin-top="1.5in"/>
      </fo:simple-page-master>
   </fo:layout-master-set>
   <fo:page-sequence master-reference="my-page">
      <fo:flow flow-name="xsl-region-body">
         <fo:root>
            <fo:layout-master-set>
               <fo:simple-page-master page-height="11in" page-width="8.5in" master-name="my-page">
                  <fo:region-body margin-top="1.5in" margin="1in"/>
               </fo:simple-page-master>
            </fo:layout-master-set>
            <fo:page-sequence master-reference="my-page">
               <fo:flow flow-name="xsl-region-body">
                  <fo:block linefeed-treatment="preserve">John Doe 
 Johnny D</fo:block>
               </fo:flow>
            </fo:page-sequence>
         </fo:root>
      </fo:flow>
   </fo:page-sequence>
</fo:root>

PDF - это отдельная страница размером 8,5 x 11 дюймов, на которой есть: 

John Doe
Johnny D
0 голосов
/ 22 июня 2016

Ответ @ daniel-haley по-прежнему выдает одну пару имен, если источник: 

<doc>
    <MyField>John Doe AKA Johnny D</MyField>
    <MyField>Johnny D AKA John Doe</MyField>
    <MyField>John Smith</MyField>
</doc>

(В XPath 1.0 преобразование набора узлов в строку возвращает строковое значение только узла в наборе узлов, который находится первым в порядке документа. См. https://www.w3.org/TR/xpath/#function-string.)

Таблица стилей ниже разделяет любой текстовый узел, содержащий "AKA". Так как вложение fo:block происходит от xsl:template для MyField, эта версия генерирует пустой fo:block, чтобы вызвать разрыв строки. 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
<xsl:output indent="yes" />
<xsl:strip-space elements="*" />

<xsl:template match="/">
    <fo:root>
        <fo:layout-master-set>
            <fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
                <fo:region-body margin="1in" margin-top="1.5in" />
            </fo:simple-page-master>
        </fo:layout-master-set>
        <fo:page-sequence master-reference="my-page">
            <fo:flow flow-name="xsl-region-body">
                <xsl:apply-templates />
            </fo:flow>
        </fo:page-sequence>
    </fo:root>
</xsl:template>

<!-- Could change to match on 'MyField/text()[contains(., ' AKA ')]'
     if necessary. -->
<xsl:template match="text()[contains(., ' AKA ')]">
    <xsl:value-of select="substring-before(., ' AKA ')" />
    <fo:block />
    <xsl:value-of select="substring-after(., ' AKA ')" />
</xsl:template>

<xsl:template match="MyField">
    <fo:block>
        <xsl:apply-templates />
    </fo:block>
</xsl:template>

</xsl:stylesheet>
...