замена многострочного шаблона в sed

Question

Я просто хочу выполнить следующие действия:

заменить

EXTRATHING {
};

на

SOMETHING {};

во входном файле.Для этого я попытался

sed -e 's/EXTRATHING {\n};/SOMETHING/' input_file.txt  >outfile.txt

Это не работает.Может кто-нибудь подсказать, как правильно сделать это с помощью sed?

Answer 1

sed -n '1h;1!H;${;g;s/EXTRATHING {\n};/SOMETHING {};/g;p;}' input_file.txt

сделает это.

Проблема в том, что он сохраняет всю входную строку в буфере sed.

См. sed и Многострочный поиск и замена. для получения дополнительной информации и более эффективной версии.

Answer 2

 sed -i.bak '/EXTRATHING/{N;s//SOMETHING/;s/\n//}' input_file.txt

Answer 3

sed -e '/begin/,/end/{s/begin/replacement/p;d}'

Answer 4

Это сложно сделать в sed, нужно писать подписки. Тем не менее, вы можете использовать однострочное использование perl:

perl -0777 -pe 's/EXTRATHING {\n/SOMETHING {/g' input_file.txt > outfile.txt

, где -0777 - разделитель записей (конечная строка в текстовых файлах) -p запускает команду для всех файлов и печатает на экране -e говорит, что это однострочная команда

Answer 5

perl -lne 's/\s*};\s*$/SOMETHING{};/g if(/\s*};\s*$/);$f=0;if(/EXTRATHING {\s*$/){next;$f=1}else{print}' your_file

проверено ниже:

> cat temp
fjbwjfbw
wefjkbwjk
jbefwejr
EXTRATHING {
};
ghekg
jhgjk
wefjkwngk
EXTRATHING {
  };
jbgvjnrg
jbfw
wefnkwk
EXTRATHING {
};
> perl -lne 's/\s*};\s*$/SOMETHING{};/g if(/\s*};\s*$/);$f=0;if(/EXTRATHING {\s*$/){next;$f=1}else{print}' temp
fjbwjfbw
wefjkbwjk
jbefwejr
SOMETHING{};
ghekg
jhgjk
wefjkwngk
SOMETHING{};
jbgvjnrg
jbfw
wefnkwk
SOMETHING{};
> 

, если вы хотите изменить встроенный файл. добавить флаг -i. как:

perl -i -lne '.......' your_file

Answer 6

Это может работать для вас:

 sed '/^EXTRATHING {/,/^};/c\SOMETHING{}' input_file.txt >output_file.txt

или если вы хотите отредактировать оригинальный файл:

sed -i '/^EXTRATHING {/,/^};/c\SOMETHING{}' input_file

РЕДАКТИРОВАТЬ: как требуется, вот пример:

cat <<! | sed '/^EXTRATHING {/,/^};/c\SOMETHING{}'
> aaa
> EXTRATHING {
> };
> bbb
> EXTRATHING {
> };
> ccc
> !
aaa
SOMETHING{}
bbb
SOMETHING{}
ccc

РЕДАКТИРОВАТЬ: Если первый и последний адреса являются последовательными строками, используйте это:

# cat <<\! | sed '/^EXTRATHING {/{N;s/^EXTRATHING {\n};/SOMETHING{}/}'
> aaa
> EXTRATHING {
> bbb
> };
> ccc
> EXTRATHING {
> };
> ddd
> !
aaa
EXTRATHING {
bbb
};
ccc
SOMETHING{}
ddd

Другой способ (возможно, проще?):

echo -e "EXTRATHING {\n};" | sed '$!N;s/^EXTRATHING {\n};/SOMETHING {};/;P;D'
SOMETHING {};