Возвращение списка в ANTLR для проверки типов, язык Java - PullRequest
Новая
       18

Возвращение списка в ANTLR для проверки типов, язык Java

3 голосов
/ 14 октября 2011

Я работаю над ANLTR для поддержки проверки типов.У меня проблемы в какой-то момент.Я попытаюсь объяснить это на примере грамматики, предположим, что у меня есть следующее: 

@members {
    private java.util.HashMap<String, String> mapping = new java.util.HashMap<String, String>();
}

var_dec  
    : type_specifiers d=dec_list? SEMICOLON 
    {
         mapping.put($d.ids.get(0).toString(), $type_specifiers.type_name);
         System.out.println("identext = " + $d.ids.get(0).toString() + " - " + $type_specifiers.type_name);
    };

type_specifiers returns [String type_name]
    : 'int' { $type_name = "int";}
    | 'float' {$type_name = "float"; }
    ;

dec_list returns [List ids]
    : ( a += ID brackets*) (COMMA ( a += ID brackets* ) )* 
    {$ids = $a;}
    ; 

brackets : LBRACKET (ICONST | ID) RBRACKET;

ID : ('a'..'z'|'A'..'Z'|'_') ('a'..'z'|'A'..'Z'|'0'..'9'|'_')*;
LBRACKET : '[';  
RBRACKET : ']';

В правиле dec_list вы увидите, что я возвращаю List с идентификаторами.Однако в var_dec когда я пытаюсь поместить первый элемент списка (я использую только get(0) только для того, чтобы увидеть возвращаемое значение из правила dec_list, я могу повторить его позже, это не моя точка зрения) в отображениеЯ получаю целую строку, например 

[@4,6:6='a',<17>,1:6]

для ввода 

int   a, b;

Я пытаюсь получить текст каждого идентификатора, в данном случае a и b в списке индексов 0 и 1 соответственно.

У кого-нибудь есть идеи?

1 Ответ

4 голосов
/ 14 октября 2011

Оператор += создает List из Token с, а не только текст, соответствующий этим Token с.Вам нужно будет инициализировать List в блоке @init{...} правила и самостоятельно добавить внутренний текст токенов.

Кроме того, вам не нужно делать это: 

type_specifiers returns [String type_name]
  :  'int' { $type_name = "int";}
  |  ...
  ;

просто получите доступ к атрибуту type_specifiers text из правила, в котором вы его используете, и удалите оператор returns, например: 

var_dec
  :  t=type_specifiers ... {System.out.println($t.text);}
  ;

type_specifiers
  :  'int'
  |  ...
  ;

Попробуйте что-то вроде этого: 

grammar T;

var_dec  
  :  type dec_list? ';' 
     {
       System.out.println("type = " + $type.text);
       System.out.println("ids  = " + $dec_list.ids);
     }
  ;

type
  :  Int
  |  Float
  ;

dec_list returns [List ids]
@init{$ids = new ArrayList();}
  :  a=ID {$ids.add($a.text);} (',' b=ID {$ids.add($b.text);})*
  ;

Int   : 'int';
Float : 'float';
ID    : ('a'..'z'|'A'..'Z'|'_') ('a'..'z'|'A'..'Z'|'0'..'9'|'_')*;
Space : ' ' {skip();};

, который выведет на консоль следующее: 

type = int
ids  = [a, b, foo]

Если вы запустите следующий класс: 

import org.antlr.runtime.*;

public class Main {
  public static void main(String[] args) throws Exception {
    TLexer lexer = new TLexer(new ANTLRStringStream("int a, b, foo;"));
    TParser parser = new TParser(new CommonTokenStream(lexer));
    parser.var_dec();
  }
}
...