Как вы можете перегрузить функцию в ActionScript? - PullRequest
Новая
       24

Как вы можете перегрузить функцию в ActionScript?

11 голосов
/ 19 сентября 2011

Я хочу, чтобы функция могла иметь различные типы.AS3 не поддерживает непосредственную перегрузку ... поэтому я не могу сделать следующее: 

//THIS ISN'T SUPPORTED BY AS3

function someFunction(xx:int, yy:int, someBoolean:Boolean = true){
    //blah blah blah
}
function someFunction(arr:Array, someBoolean:Boolean = true){
    someFunction(arr[0], arr[1], someBoolean);
}

Как я могу обойти это и при этом иметь функцию, способную принимать аргументы различных типов?

Ответы [ 2 ]

21 голосов
/ 19 сентября 2011

Если вы просто хотите иметь возможность принимать любой тип, вы можете использовать *, чтобы разрешить любой тип: 

function someFunction( xx:*, yy:*, flag:Boolean = true )
{
  if (xx is Number) {
    ...do stuff...
  } else if (xx is String) {
    ...do stuff...
  } else {
    ...do stuff...
  }
}

Если у вас есть большое количество различных параметров, где порядок не важен, используйте объект параметров: 

function someFunction( options:Object )
{
  if (options.foo) doFoo();
  if (options.bar) doBar();
  baz = options.baz || 15;
  ...etc...
}

Если у вас переменное количество параметров, вы можете использовать параметр ... (остальные) : 

function someFunction( ... args)
{
  switch (args.length)
  {
    case 2:
      arr = args[0];
      someBool = args[1];
      xx = arr[0];
      yy = arr[1];
      break;
    case 3:
      xx = args[0];
      yy = args[1];
      someBool = args[2];
      break;
    default:
      throw ...whatever...
  }
  ...do more stuff...
}

Для случаев, когда вам нужно вызвать общую функцию для нескольких классов, вы должны указать интерфейс, общий для каждого класса: 

function foo( bar:IBazable, flag:Boolean )
{
  ...do stuff...
  baz = bar.baz()
  ...do more stuff...
}
2 голосов
/ 19 сентября 2011

Может иметь только: 

function something(...args):void
{
    trace(args[0], args[1]);
}

Таким образом, вы можете легко просматривать свои аргументы и тому подобное (и даже проверять тип аргумента): 

function something(...args):void
{
    for each(var i:Object in args)
    {
        trace(typeof(i) + ": " + i);
    }
}

something("hello", 4, new Sprite()); // string: hello
                                     // number: 4
                                     // object: [object Sprite]
...