Как вы сортируете выходные данные Data :: Dumper?

Question

Я хочу сбросить значения моего объекта и хэша, но он продолжает печатать ключи не по порядку. Как я могу сбросить ключи в (рекурсивном) порядке сортировки?

use Data::Dumper;
print Dumper $obj;

Answer 1

Установите $Data::Dumper::Sortkeys = 1, чтобы получить порядок сортировки Perl по умолчанию. Если вы хотите настроить порядок, установите $Data::Dumper::Sortkeys на ссылку на подпрограмму, которая получает ссылку на хеш в качестве входных данных и выводит ссылку на список ключей хеша в том порядке, в котором вы хотите, чтобы они отображались.

# sort keys
$Data::Dumper::Sortkeys = 1;
print Dumper($obj);

# sort keys in reverse order - use either one
$Data::Dumper::Sortkeys = sub { [reverse sort keys %{$_[0]}] };
$Data::Dumper::Sortkeys = sub { [sort {$b cmp $a} keys %{$_[0]}] };
print Dumper($obj);

Answer 2

Краткий ответ для нетерпеливых

Используйте взамен Data :: Dumper :: Concise .Сортирует ваши ключи.Используйте это следующим образом:

use Data::Dumper::Concise;

my $pantsToWear = {
    pony       => 'jeans',
    unicorn    => 'corduroy',
    marsupials => {kangaroo => 'overalls', koala => 'shorts + suspenders'},
};

warn Dumper($pantsToWear);

Больше слов для любопытных

Data :: Dumper :: Concise также дает вам более компактный и легкий для чтения вывод.

Примечаниечто Data :: Dumper :: Concise равно Data :: Dumper с разумными значениями конфигурации по умолчанию, установленными для вас.Это эквивалентно использованию Data :: Dumper следующим образом:

use Data::Dumper;
{
  local $Data::Dumper::Terse = 1;
  local $Data::Dumper::Indent = 1;
  local $Data::Dumper::Useqq = 1;
  local $Data::Dumper::Deparse = 1;
  local $Data::Dumper::Quotekeys = 0;
  local $Data::Dumper::Sortkeys = 1;
  warn Dumper($var);
}

Answer 3

Из документации Data::Dumper:

$Data::Dumper::Sortkeys or $OBJ->Sortkeys([NEWVAL])
Can be set to a boolean value to control whether hash keys are dumped in sorted order. 
A true value will cause the keys of all hashes to be dumped in Perl's default sort order. 
Can also be set to a subroutine reference which will be called for each hash that is dumped. 
In  this case Data::Dumper will call the subroutine once for each hash, passing it the 
reference of the hash. The purpose of the subroutine is to return a reference to an array of 
the keys that will be dumped, in the order that they should be dumped. Using this feature, you 
can control both the order of the keys, and which keys are actually used. In other words, this 
subroutine acts as a filter by which you can exclude certain keys from being dumped. Default is  
0, which means that hash keys are not sorted.

Answer 4

Можно установить для переменной $Data::Dumper::Sortkeys значение true, чтобы получить сортировку по умолчанию:

use Data::Dumper;
$Data::Dumper::Sortkeys  = 1;

my $hashref = {
    bob => 'weir',
    jerry =>, 'garcia',
    nested => {one => 'two', three => 'four'}};

print Dumper($hashref), "\n";

или добавьте подпрограмму для сортировки ключей по вашему желанию.

Answer 5

Для тех, кто хочет отсортировать хэш-значение по значению при печати с помощью Data::Dumper, вот пример:

$Data::Dumper::Sortkeys = sub {
    # Using <=> to sort numeric values
    [ sort { $_[0]->{$a} <=> $_[0]->{$b} } keys %{ $_[0] } ]
};

А вот более читаемая альтернатива, которая делает то же самое, но с переменной для хранения хэша. Это менее эффективно, но для небольших хэшей некоторые могут найти это лучше:

$Data::Dumper::Sortkeys = sub {
    my %h = %{$_[0]};
    # cmp for string comparisons
    [ sort { $h{$a} cmp $h{$b} } keys %h ];
};

Answer 6

сортировка ascii и полная цифра:

$Data::Dumper::Sortkeys = sub {
  no warnings 'numeric';
  if(join('',keys %{$_[0]})=~/\d+/)
  {
    [ sort { $a <=> $b } keys %{$_[0]} ]
  }
  else
  {
    return [sort(keys %{$_[0]})];
  }
};