Flash AS3 - StartDrag () в StartDrag () дочернего мувиклипа - PullRequest
Новая
       17

Flash AS3 - StartDrag () в StartDrag () дочернего мувиклипа

0 голосов
/ 20 мая 2011

Привет всем, мой код указан ниже.

Как видите, у меня есть контейнер MC, который я добавил на сцену.Я установил ограничения перетаскивания, используя Rectangle ().Затем я добавляю дочерний мувиклип 'cat' в контейнер и хочу, чтобы это тоже можно было перетаскивать.Однако, как только я нажимаю на свою кошку при тестировании MC.Стреляет в точку x = 0 y = 0 на сцене и не двигается.

Контейнер MC можно перемещать без каких-либо проблем.

Если я удалю границы прямоугольника из функции startdrag () контейнеров.оба MC можно перетаскивать без каких-либо проблем.

любая помощь будет потрясающей.

спасибо 

//panning ability
my_x = 800 - myImage.width;
my_y = 480 - myImage.height;

myWidth = 0 - my_x;
myHeight = 0 - my_y;

container.addEventListener(MouseEvent.MOUSE_DOWN, bgMouseDown);
container.addEventListener(MouseEvent.MOUSE_UP, bgMouseUp);

 function bgMouseDown(evt:MouseEvent):void
{
    var object = evt.currentTarget;
    object.startDrag(false, new Rectangle(my_x, my_y, myWidth ,myHeight));
}

 function bgMouseUp(evt:MouseEvent):void
{
    var object = evt.currentTarget;
    object.stopDrag();
}

//adding ze cat

cat = new ACat();
container.addChild(cat);
cat.x = 100;
cat.y = 400;


cat.addEventListener(MouseEvent.MOUSE_DOWN, catMouseDown);
cat.addEventListener(MouseEvent.MOUSE_UP, catMouseUp);


 function catMouseDown(evt:MouseEvent):void
{
    var object = evt.currentTarget;
    object.startDrag(false);
}

 function catMouseUp(evt:MouseEvent):void
{
    var object = evt.currentTarget;
    object.stopDrag();
}

Ответы [ 3 ]

0 голосов
/ 20 мая 2011

Удалите слушателей из контейнера и создайте базовый класс для ваших перетаскиваемых объектов. 

package
{
    import flash.display.Sprite;
    import flash.geom.Rectangle;
    import flash.events.MouseEvent;

    public class Dragable extends Sprite
    {
        // vars
        private var _rect:Rectangle;

        /**
         * Constructor
         */
        public function Dragable()
        {
            addEventListener(MouseEvent.MOUSE_DOWN, _drag);
            addEventListener(MouseEvent.MOUSE_UP, _drop);
        }

        /**
         * MOUSE_DOWN
         */
        private function _drag(e:MouseEvent):void
        {
            if(_rect != null) startDrag(false, _rect);
            else startDrag();
        }

        /**
         * MOUSE_UP
         */
        private function _drop(e:MouseEvent):void
        {
            stopDrag();
        }

        /**
         * Define a boundary Rectangle
         * @param rect The Rectangle to define
         */
        public function set boundaries(rect:Rectangle):void
        {
            _rect = rect;
        }
    }
}

В этом списке слишком много преимуществ.

0 голосов
/ 22 мая 2011

Попробуйте evt.stopPropagation( ) в первой строке функции catMouseDown.

Также попробуйте cat.addEventListener(MouseEvent.MOUSE_DOWN, catMouseDown, true);

0 голосов
/ 20 мая 2011

Я думаю, что вы должны проверить, какая цель является текущей потому что событие запускается для контейнера при перетаскивании Cat mc

попробуйте что-нибудь подобное: 

function bgMouseDown(evt:MouseEvent):void
{
    var object = evt.currentTarget;
    if(evt.currentTarget !=container) return;
    object.startDrag(false, new Rectangle(my_x, my_y, myWidth ,myHeight));
}
...