Заполнение стилей с использованием одного графика в Mathematica - PullRequest
Новая
       0

Заполнение стилей с использованием одного графика в Mathematica

11 голосов
/ 19 декабря 2011

Могу ли я указать разные цвета заливки для одного графика, как показано ниже, или мне нужно "показать" несколько графиков?Допустим, я бы хотел, чтобы стиль заливки был таким же, как стиль PlotStyle. 

priorMean = 50;
priorVar = 100;

llhMean = 30;
llhVar = 40;

postMean=35.71;
postVar=28.57;


Plot[
     Evaluate@MapThread[
     Function[{\[Mu], \[Sigma]},
     PDF[NormalDistribution[\[Mu], Sqrt[\[Sigma]]], x]],
     {{priorMean, llhMean, postMean}, {priorVar, llhVar, postVar}}],
{x, 0, 100}, Filling -> Axis, PlotStyle -> {Red, Green, Blue}]

enter image description here

Ответы [ 4 ]

13 голосов
/ 20 декабря 2011

Вам нужно будет использовать FillingStyle для заполнения. Я думаю, вы застряли в синтаксисе для FillingStyle, который не такой же, как для PlotStyle, хотя Я ожидаю, что это будет. Вы должны будете назначить цвет для каждой кривой как FillingStyle -> {1 -> color1, 2 -> color2} и т. Д. Вот пример: 

colors = {Red, Green, Blue};
Plot[Evaluate@
  MapThread[
   Function[{\[Mu], \[Sigma]}, 
    PDF[NormalDistribution[\[Mu], Sqrt[\[Sigma]]], x]], {{priorMean, 
     llhMean, postMean}, {priorVar, llhVar, postVar}}], {x, 0, 100}, 
 Filling -> Axis, PlotStyle -> colors, 
 FillingStyle -> 
  MapIndexed[#2 -> Directive[Opacity[0.3], #] &, colors]]

enter image description here

9 голосов
/ 20 декабря 2011

Я предлагаю расширить определение Plot. Я делал это раньше. 

toDirective[{ps__} | ps__] := Flatten[Directive @@ Flatten[{#}]] & /@ {ps}

makefills = MapIndexed[#2 -> Join @@ toDirective@{Opacity[0.3], #} &, #] &;

Unprotect[Plot];
Plot[a__, b : OptionsPattern[]] :=
  Block[{$FSmatch = True},
    With[{fills = makefills@OptionValue[PlotStyle]}, 
      Plot[a, FillingStyle -> fills, b]
  ]] /; ! TrueQ[$FSmatch] /; OptionValue[FillingStyle] === "Match"

Имея это, вы можете использовать FillingStyle -> "Match" для автоматического стиля заливки в соответствии с основными стилями. 

Plot[{Sin[x], Cos[x], Log[x]}, {x, 0, 2 Pi},
  PlotRange -> {-2, 2},
  PlotStyle -> {{Blue, Dashing[{0.04, 0.01}]},
                {Thick, Dashed, Orange},
                {Darker@Green, Thick}},
  Filling -> Axis,
  FillingStyle -> "Match"
]

Mathematica graphics

8 голосов
/ 20 декабря 2011

Вы могли бы сделать что-то вроде 

With[{colours = {Red, Green, Blue}},
 Plot[Evaluate@
   MapThread[
    Function[{\[Mu], \[Sigma]}, 
     PDF[NormalDistribution[\[Mu], Sqrt[\[Sigma]]], x]], 
     {{priorMean, llhMean, postMean}, {priorVar, llhVar, postVar}}], 
  {x, 0, 100},
  Filling -> 
    MapIndexed[#2[[1]] -> {Axis, Directive[Opacity[.3, #1]]} &, colours], 
  PlotStyle -> colours]]

filling with different colours

3 голосов
/ 20 декабря 2011

Получается результат: 

Plot[Evaluate@
  MapThread[
   Function[{\[Mu], \[Sigma]}, 
    PDF[NormalDistribution[\[Mu], Sqrt[\[Sigma]]], x]], {{priorMean, 
     llhMean, postMean}, {priorVar, llhVar, postVar}}], {x, 0, 100}, 
 Filling -> {1 -> {Axis, Red}, 2 -> {Axis, Green}, 3 -> {Axis, Blue}},
  PlotStyle -> {Red, Green, Blue}]

Находится в справке под FillingStyle, Scope, Filling Style.

И альтернативно: 

f = MapThread[
   Function[{\[Mu], \[Sigma]}, 
    PDF[NormalDistribution[\[Mu], Sqrt[\[Sigma]]], x]],
   {{priorMean, llhMean, postMean}, {priorVar, llhVar, postVar}}];
c = {Red, Green, Blue};
Show[Array[
  Plot[f[[#]], {x, 0, 100}, Filling -> {1 -> {Axis, c[[#]]}}, 
    PlotRange -> {Automatic, 0.08}, PlotStyle -> c[[#]]] &, 3]]

enter image description here

...