В Perl, какой самый надежный способ определить пакет coderef? - PullRequest
Новая
       23

В Perl, какой самый надежный способ определить пакет coderef?

10 голосов
/ 12 июля 2011

У меня есть ряд служебных функций высшего порядка, которые берут ссылку на код и применяют этот код к некоторым данным. Некоторые из этих функций требуют локализации переменных во время выполнения подпрограмм. В начале я использовал caller, чтобы определить, в какой пакет локализоваться, аналогично тому, как показано в этом примере reduce function: 

sub reduce (&@) {
    my $code      = shift;
    my $caller    = caller;
    my ($ca, $cb) = do {
        no strict 'refs';
        map \*{$caller.'::'.$_} => qw(a b)
    };
    local (*a, *b) = local (*$ca, *$cb);
    $a = shift;
    while (@_) {
        $b = shift;
        $a = $code->()
    }
    $a
}

Первоначально эта техника работала нормально, однако, как только я попытался написать функцию-обертку для функции более высокого порядка, выяснить, как правильно вызвать вызывающего, становится сложно. 

sub reduce_ref (&$) {&reduce($_[0], @{$_[1]})}

Теперь, чтобы reduce заработал, мне нужно что-то вроде: 

    my ($ca, $cb) = do {
        my $caller = 0;
        $caller++ while caller($caller) =~ /^This::Package/;
        no strict 'refs';
        map \*{caller($caller).'::'.$_} => qw(a b)
    };

В этот момент встал вопрос о том, какие пакеты пропустить, в сочетании с дисциплиной никогда не использовать функцию из этих пакетов. Должен был быть лучший способ.

Оказывается, что подпрограмма, которую функции высшего порядка принимают в качестве аргумента, содержит достаточно метаданных для решения проблемы. Мое текущее решение - использовать модуль интроспекции B для определения тайника компиляции переданной подпрограммы. Таким образом, независимо от того, что происходит между компиляцией кода и его выполнением, функция высшего порядка всегда знает правильный пакет для локализации. 

    my ($ca, $cb) = do {
        require B;
        my $caller = B::svref_2object($code)->STASH->NAME;
        no strict 'refs';
        map \*{$caller.'::'.$_} => qw(a b)
    };

Итак, мой последний вопрос: лучший ли это способ определения пакета вызывающего абонента в этой ситуации? Есть ли какой-то другой способ, о котором я не думал? Есть ли какая-то ошибка, ожидающая моего текущего решения?

Ответы [ 2 ]

5 голосов
/ 12 июля 2011

Во-первых, вы можете использовать следующее и не требовать каких-либо изменений: 

sub reduce_ref (&$) { @_ = ( $_[0], @{$_[1]} ); goto &reduce; }

Но, вообще говоря, следующее действительно именно то, что вы хотите: 

B::svref_2object($code)->STASH->NAME

Вы хотите, чтобы$a и $b переменные сабвуфера __PACKAGE__, так что вы хотите знать сабвуфер __PACKAGE__, и это именно то, что это возвращает.Он даже исправляет следующее: 

{
   package Utils;
   sub mk_some_reducer {
      ...
      return sub { ... $a ... $b ... };
   }
}

reduce(mk_some_reducer(...), ...)

Он не исправляет все, но это невозможно без использования аргументов вместо $a и $b.

1 голос
/ 13 сентября 2011

На случай, если они кому-нибудь понадобятся, вот функции, которые я в итоге решил использовать: 

require B;
use Scalar::Util 'reftype';
use Carp 'croak';

my $cv_caller = sub {
    reftype($_[0]) eq 'CODE' or croak "not code: $_[0]";
    B::svref_2object($_[0])->STASH->NAME
};

my $cv_local = sub {
    my $caller = shift->$cv_caller;
    no strict 'refs';
    my @ret = map \*{$caller.'::'.$_} => @_;
    wantarray ? @ret : pop @ret
};

Что будет использоваться как: 

my ($ca, $cb) = $code->$cv_local(qw(a b));

в контексте исходного вопроса.

...