последовательный порт не будет работать в Delphi - PullRequest
Новая
       35

последовательный порт не будет работать в Delphi

3 голосов
/ 01 ноября 2011

Я создаю простую программу на Delphi для отправки символа через COM-порт с использованием 2 параметров, первый параметр - это номер порта, а второй параметр - это символ для отправки. Поэтому, если я сохраню его как p.exe, «p.exe 20 A» отправит «A» через COM20. 

try
   PhoneNumber := ParamStr(2);

   if(StrToInt(ParamStr(1))>=10)then
   CommPort := '\\.\COM'+ParamStr(1)
   else
   CommPort := 'COM'+ParamStr(1);
   hCommFile := CreateFile(PChar(CommPort),
                          GENERIC_WRITE,
                          0,
                          nil,
                          OPEN_EXISTING,
                          FILE_ATTRIBUTE_NORMAL,
                          0);
   if hCommFile=INVALID_HANDLE_VALUE then begin
      ShowMessage('Unable to open '+ CommPort);
   end;
  if WriteFile(hCommFile, PChar(PhoneNumber)^, Length(PhoneNumber),NumberWritten, nil)=false then
    showmessage('Unable to send');
  PurgeComm(hCommFile,PURGE_TXCLEAR);
  FlushFileBuffers(hCommFile);
  CloseHandle(hCommFile);
  Application.Terminate;
except
  PurgeComm(hCommFile,PURGE_TXCLEAR);
  FlushFileBuffers(hCommFile);
  Application.Terminate;
end;

И я также использую гипертерминал с тем же номером COM, скорость передачи данных = 9600, flow_control = none, и это дает тот же результат. Персонаж отправил хорошо. Проблема в том, что я не могу запустить свою программу (p.exe) перед тем, как выполнить следующие шаги при каждом входе в Windows XP: Подключите через гипертерминал к назначенному COM, отключи это. тогда мой исполняемый файл может быть запущен. В противном случае, так же, как вы запускаете два сеанса гипертерминала в одном и том же COM, это не сработает. Кто-нибудь получил подсказку об этом? Я что-то пропустил в своем коде?

Ответы [ 2 ]

4 голосов
/ 01 ноября 2011

Я не вижу никаких настроек в вашем коде. Поэтому, возможно, вы полагаетесь на побочный эффект запуска HyperTerminal, который «заправляет» порт для вас. Взгляните на эту статью, где они проходят через все это: бод, четность и т. Д.

http://www.delphi -central.com / serial.aspx

Кажется, это полный рабочий пример. Посмотрите, сможете ли вы заставить это работать и использовать его как основу для сборки.

3 голосов
/ 01 ноября 2011

Вам необходимо использовать setcommstate для настройки скорости передачи и управления потоком. 

Function OpenPort( Var fHandle: THandle; fPort: String): Boolean;
Const
 RxBufferSize       = 32;
 TxBufferSize       = 32;
Var
 dcb                : TDCB;
 tms                : TCOMMTIMEOUTS;
Begin
 Result := False;
 Try
  If fHandle <> INVALID_HANDLE_VALUE Then
   CloseHandle( fhandle );
 Except
 End;
 Try
  //fport must be \\.\ URN format
  fhandle := CreateFile( PChar( fPort ), GENERIC_WRITE or GENERIC_READ, FILE_SHARE_WRITE ,
                         Nil, OPEN_EXISTING, FILE_ATTRIBUTE_NORMAL, 0 );
  If ( fhandle = INVALID_HANDLE_VALUE ) Then
   Begin
    result := false;
    exit;
   End;
  SetupComm( fhandle, RxBufferSize, TxBufferSize );

  If pos( 'LPT', fPort ) > 0 Then
   //
  Else
   Begin
    GetCommState( fhandle, dcb );
    dcb.DCBlength := sizeof( dcb );
    dcb.BaudRate := cbr_9600;
    dcb.Flags := 1;                     // binary...
    if dtr_rts then
    begin
     dcb.flags := dcb.Flags Or $20;      //DTR HANDSHAKE
     dcb.Flags := dcb.Flags Or $1000;    //rts handshake
     dcb.Flags := dcb.Flags Or 4;        //Outx_CtsFlow
     dcb.Flags := dcb.Flags Or 8;        //Outx_DsrFlow
     dcb.Flags := dcb.Flags Or $40;      //DsrSensitivity
     //dcb.Flags := dcb.Flags or $100;//Outx_XonXoffFlow
     //dcb.Flags := dcb.Flags or $200;//Inx_XonXoffFlow
    end;
    dcb.ByteSize := 8;
    dcb.Parity := EVENPARITY;
    dcb.StopBits := ONESTOPBIT;
    SetCommState( fhandle, dcb );
    GetCommTimeouts( fhandle, tms );
    tms.ReadIntervalTimeout := 100;//you can change multipler values with
    tms.ReadTotalTimeoutMultiplier := 100;//your values
    tms.ReadTotalTimeoutConstant := 1;
    SetCommTimeOuts( fhandle, tms );
   End;
  EscapeCommFunction( fhandle, CLRRTS Or CLRDTR Or SETRTS Or SETDTR );//for handshaking
  Result := True;
 Except
  Result := False;
 End;
End;

использование 

var 
    fporthandle:thandle;
   begin
    if OpenPort(fporthandle,'\\.\com1') then
      try
       writefile(fporthandle,pchar('TEST')...);
      finally
        closehandle(fporthandle);
      end;
...