Сопоставление и извлечение строк

Question

У меня есть строка типа "ab.cde.fg.hi", и я хочу разбить ее на две строки.

1. "ab.cde.fg"
2. ".hi"

Как это сделать?Я получил некоторый написанный код, который получит мне вторую строку, но как мне получить оставшиеся?

$mystring = "ab.cde.fg";
$mystring =~ m/.*(\..+)/;
print "$1\n";

Answer 1

Вы уверены, что не ищете ...

($name,$path,$suffix) = File::Basename::fileparse($fullname,@suffixlist);

Answer 2

my @parts = /(.*)\.(.*)/s;

my @parts = split /\.(?!.*\.)/s;

my @parts = split /\.(?=[^.]*\z)/s;

Обновление : я неправильно прочитал. "." должны быть включены во второй части, но это не в выше. Выше должно быть:

my @parts = /(.*)(\..*)/s;

my @parts = split /(?=\.(?!.*\.))/s;

my @parts = split /(?=\.[^.]*\z)/s;

Answer 3

my ($first, $second) = $string =~ /(.*)(\..*)/;

Вы также можете использовать split:

my ($first, $second) = split /(?=\.[^.]+$)/, $string;

Answer 4

Для продвижения моей идеи использовать rindex для получения

   1) "ab.cde.fg" 
   2) ".hi"

из "ab.cde.fg.hi", я написал этот скрипт для упрощения экспериментов:

  use strict;
  use diagnostics;
  use warnings;
  use English;

  my @tests = (
      [ 'ab.cde.fg.hi', 'ab.cde.fg|.hi' ]
    , [ 'abxcdexfg.hi', 'abxcdexfg|.hi' ]
  );
  for my $test (@tests) {
    my $src = $test->[0];
    my $exp = $test->[1];
    printf "-----|%s| ==> |%s|-----\n", $src, $exp;
    for my $op (
        [ 'ikegami 1' , sub { shift =~ /(.*)\.(.*)/s; } ]
      , [ 'ikegami 2' , sub { split( /\.(?!.*\.\z)/s, shift) } ]
      , [ 'rindex'    , sub { my $p = rindex( $_[0], '.' );
                              (   substr($_[0], 0, $p)
                                , substr($_[0], $p)
                              ); }
        ]
    ) {
      my ($head, $tail) = $op->[1]( $src );
      my $res = join '|', ($head, $tail);
      my $ok  = $exp eq $res ? 'ok' : "fail: $exp expected.";
      printf "%12s: %-20s => %-20s : %s\n", $op->[0], $src, $res, $ok;
    }
  }

выход:

-----|ab.cde.fg.hi| ==> |ab.cde.fg|.hi|-----
   ikegami 1: ab.cde.fg.hi         => ab.cde.fg|hi         : fail: ab.cde.fg|.hi expected.
   ikegami 2: ab.cde.fg.hi         => ab|cde               : fail: ab.cde.fg|.hi expected.
      rindex: ab.cde.fg.hi         => ab.cde.fg|.hi        : ok
-----|abxcdexfg.hi| ==> |abxcdexfg|.hi|-----
   ikegami 1: abxcdexfg.hi         => abxcdexfg|hi         : fail: abxcdexfg|.hi expected.
   ikegami 2: abxcdexfg.hi         => abxcdexfg|hi         : fail: abxcdexfg|.hi expected.
      rindex: abxcdexfg.hi         => abxcdexfg|.hi        : ok