Как получить локальный IP-адрес с помощью Inno Setup - PullRequest
Новая
       12

Как получить локальный IP-адрес с помощью Inno Setup

12 голосов
/ 29 мая 2011

Как я могу получить локальный IP-адрес пользователя с помощью Inno Setup?

Я думал об использовании Win32 API GetIpAddrTable, но неясно, как выполнить настройку.

Есть ли у кого-нибудь другой способ?Или знаете как это сделать?

Ответы [ 2 ]

21 голосов
/ 30 мая 2011

Это зависит от того, хотите ли вы IPv4-адрес или IPv6-адрес.Но поскольку вы упомянули GetIpAddrTable и он возвращает только адреса IPv4, я подозреваю, что это то, что вы хотели.

У каждой машины может быть несколько локальных IP-адресов.Поэтому я возвращаю их как TStringList.
У компьютера, на котором я тестировал следующее, было 5 IP-адресов.

Поскольку Inno Setup не поддерживает указатели, мне пришлось делать все через Array of Byte длябуфер.

Приведенный ниже код представляет собой полный скрипт Inno Setup, который демонстрирует, как использовать эту функцию. 

[Setup]
AppName=Test
AppVersion=1.5
DefaultDirName={pf}\test

[Code]

const
 ERROR_INSUFFICIENT_BUFFER = 122;


function GetIpAddrTable( pIpAddrTable: Array of Byte;
  var pdwSize: Cardinal; bOrder: WordBool ): DWORD;
external 'GetIpAddrTable@IpHlpApi.dll stdcall';


procedure GetIpAddresses(Addresses : TStringList);
var 
 Size : Cardinal;
 Buffer : Array of Byte;
 IpAddr : String;
 AddrCount : Integer;
 I, J : Integer;
begin
  { Find Size }
  if GetIpAddrTable(Buffer,Size,False) = ERROR_INSUFFICIENT_BUFFER then
  begin
     { Allocate Buffer with large enough size }
     SetLength(Buffer,Size);
     { Get List of IP Addresses into Buffer }
     if GetIpAddrTable(Buffer,Size,True) = 0 then
     begin
       { Find out how many addresses will be returned. }
       AddrCount := (Buffer[1] * 256) + Buffer[0];
       { Loop through addresses. }
       For I := 0 to AddrCount - 1 do
       begin
         IpAddr := '';
         { Loop through each byte of the address }
         For J := 0 to 3 do
         begin
           if J > 0 then
             IpAddr := IpAddr + '.';
           { Navigate through record structure to find correct byte of Addr }
           IpAddr := IpAddr + IntToStr(Buffer[I*24+J+4]);
         end;
         Addresses.Add(IpAddr);
       end;
     end;
  end;
end;

function InitializeSetup(): Boolean;
var
 SL : TStringList;
begin
  SL := TStringList.Create;
  GetIpAddresses(SL);
  MsgBox(SL.Text, mbInformation, MB_OK);
  SL.Free;
end;
8 голосов
/ 29 мая 2011

Создайте внешнюю DLL, которая возвращает список IP-адресов, и прочитайте этот список в скрипте Inno Setup.

В этой статье вы найдете пример кода, как создать DLL и как ее вызвать в скрипте InnoSetup.

В этом посте SO вы узнаете, как получить IP-адреса с помощью библиотеки Indy или обычного WinApi.

...