Программа для преобразования времени в секундах в формат чч: мм: сс

Question

Я пытаюсь сделать простую программу для преобразования времени в секундах в формат чч: мм: сс.Но для некоторых конкретных входных значений он выдает неправильный формат времени.Вот что я пробовал:

Public Class Form1
    Dim Hours, Minutes, Seconds As Integer

    Private Sub btnReset_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnReset.Click
        lblHours.Text = "00"
        lblMinutes.Text = "00"
        lblSeconds.Text = "00"
        txtTimeSeconds.Text = ""
        txtFormattedTime.Text = ""
    End Sub

    Private Sub btnCalculate_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnCalculate1.Click
        Seconds = Integer.Parse(txtTimeSeconds.Text)
        Hours = Seconds / 3600
        Seconds = Seconds Mod 3600
        Minutes = Seconds / 60
        Seconds = Seconds Mod 60

        lblHours.Text = Hours.ToString.PadLeft(2, "0"c)
        lblMinutes.Text = Minutes.ToString.PadLeft(2, "0"c)
        lblSeconds.Text = Seconds.ToString.PadLeft(2, "0"c)

        txtFormattedTime.Text = Hours.ToString.PadLeft(2, "0"c) & ":" & Minutes.ToString.PadLeft(2, "0"c) & ":" & Seconds.ToString.PadLeft(2, "0"c)
    End Sub
End Class

Работает, когда входное значение равно 30:

Не работает, когда входное значение равно 31:

Что я сделал не так?Как я могу решить эту проблему?

Answer 1

В .NET существует класс TimeSpan , который делает ваш код простым и элегантным.

Пример:

dim iSecond as double = 0 'Total number of seconds
Dim iSpan As TimeSpan = TimeSpan.FromSeconds(iSecond)

lblHours.Text = iSpan.Hours.ToString.PadLeft(2, "0"c)
lblMinutes.Text = iSpan.Minutes.ToString.PadLeft(2, "0"c)
lblSeconds.Text = iSpan.Seconds.ToString.PadLeft(2, "0"c)

txtFormattedTime.Text = iSpan.Hours.ToString.PadLeft(2, "0"c) & ":" & _
                        iSpan.Minutes.ToString.PadLeft(2, "0"c) & ":" & _
                        iSpan.Seconds.ToString.PadLeft(2, "0"c)

Answer 2

Visual Basic имеет два оператора деления, / и \. Оператор / выдает результат типа Double. Вы вычисляете 31/60 = 0,51666 ... Затем вы присваиваете этот результат целому числу, которое требует округления. Таким образом, получая 1, а не 0.

Вы хотите использовать оператор \, оператор целочисленного деления. Обрезает результат.

Answer 3

Надеюсь, этот код будет полезен

Dim ts As TimeSpan = TimeSpan.FromSeconds(227) 'or --> Dim ts As New TimeSpan(0, 0, 0, 227, 0)

Dim mydate As DateTime = New DateTime(ts.Ticks)
MessageBox.Show(mydate.ToString(("HH:mm:ss")))

Answer 4

Вы используете целые числа для хранения ваших данных, но деление дает вам двойные.При преобразовании его обратно в целые числа оно округляется до ближайшего округленного числа.Таким образом, 0.5 становится 0, но 0.51 становится 1.

Answer 5

Dim SecondsDifference as integer = 2500  
Dim hms = TimeSpan.FromSeconds(SecondsDifference)
Dim h = hms.Hours.ToString
Dim m = hms.Minutes.ToString
Dim s = hms.Seconds.ToString
MsgBox("Hour:" + h + " Min:" + m + " Sec:" + s)

Answer 6

Я знаю, что на этот вопрос уже отвечали некоторое время, но я подумал, что мог бы поделиться своим решением проблемы под рукой. Если вы поместите количество секунд в объект TimeSpan, вы сможете легко извлечь дни, часы, минуты, секунды и даже доли секунды, используя метод TimeSpan.toString(). Используя идентичные формы и имена объектов, я использовал следующий код для достижения желаемых результатов.

Public Class Form1
Private Sub btnReset_Click(sender As Object, e As EventArgs) Handles btnReset.Click
    lblHours.Text = "00"
    lblMinutes.Text = "00"
    lblSeconds.Text = "00"
    txtTimeSeconds.Text = ""
    txtFormattedTime.Text = ""
End Sub
Private Sub btnCalculate_Click(sender As Object, e As EventArgs) Handles btnCalculate.Click
    Dim tsSeconds = TimeSpan.FromSeconds(Convert.ToDouble(txtTimeSeconds.Text))
    lblHours.Text = tsSeconds.ToString("hh")
    lblMinutes.Text = tsSeconds.ToString("mm")
    lblSeconds.Text = tsSeconds.ToString("ss")
    txtFormattedTime.Text = tsSeconds.ToString("hh\:mm\:ss")
End Sub
End Class

Посетите здесь для получения дополнительной информации об используемом методе.

Answer 7

Для txtformattedtime.text = ... Я думаю, "ispan.tostring" также будет работать.