Разделить XML-файл по количеству записей / порогу и скопировать заголовок - XSLT 1.0 - PullRequest
Новая
       24

Разделить XML-файл по количеству записей / порогу и скопировать заголовок - XSLT 1.0

0 голосов
/ 03 мая 2011

У меня есть следующая структура XML 

<?xml version="1.0" encoding="UTF-8"?>
<ExportData>
<TransportHeader>
    <Timestamp>2011-01-16 06:00:33</Timestamp>
    <From>
        <Name>DynamicExport</Name>
        <Version>1.</Version>
    </From>
    <MessageId>d7b5c5b69a83</MessageId>
</TransportHeader>
<ExportConfig>
    <DateTimeFormat>yyyy-MM-dd HH:mm:ss</DateTimeFormat>
    <DecimalSymbol>.</DecimalSymbol>
</ExportConfig>
<DataSet> 
    <Tables>
        <Table>
            <RH>...</RH>
            <Rows>  
                <R>Data1</R>
                <R>Data2</R>
                <R>Data3</R>
                <R>Data4</R>
                <R>Data5</R>
            </Rows>
        </Table>
    </Tables>
</DataSet>
</ExportData>

и мне нужно разбить файл в зависимости от количества <R> элементов. Если имеется более 3 <R> элементов, необходимо создать второй выходной файл. Оба файла также нуждаются в информации заголовка.

Я придумал этот XSLT: 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xd="http://www.oxygenxml.com/ns/doc/xsl"
xmlns:redirect="http://xml.apache.org/xalan/redirect"
extension-element-prefixes="redirect"
exclude-result-prefixes="xd"
version="1.0">

<xsl:template match="/">
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="text() | @*"/>

<xsl:template match="Rows" name="Rows"> 
    <Rows>    
        <xsl:for-each select="R">
            <xsl:variable name="filename1" select="concat('output1','.xml')"/>
            <xsl:variable name="filename2" select="concat('output2','.xml')"/>
            <xsl:variable name="nodePosition" select="position()" />
            <xsl:if test="$nodePosition &lt; 3">
                <redirect:write select="$filename1">
                    <xsl:copy-of select="." />
                </redirect:write>
            </xsl:if>
            <xsl:if test="$nodePosition = 3 or $nodePosition &gt; 3">
                <redirect:write select="$filename2">
                        <xsl:copy-of select="." />
                </redirect:write> 
            </xsl:if>
        </xsl:for-each>  
    </Rows>        
</xsl:template>
</xsl:stylesheet>

Но два сгенерированных выходных файла содержат только «Data2» и «Data5». Не могли бы вы помочь мне выяснить, почему отсутствуют остальные 3 элемента данных? И как я могу добавить данные заголовка?

Для заголовка я придумал этот XSLT: 

<xsl:template match="//Rows">
    <xsl:apply-templates select="@*|Rows"/>
</xsl:template>

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

, который работает, когда я применяю его к упомянутому XML. Но я не смог объединить 2 XSLT - вывод просто испортился.

Большое спасибо за любую помощь! С наилучшими пожеланиями, Питер

Ответы [ 2 ]

1 голос
/ 03 мая 2011

Эта таблица стилей: 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:redirect="http://xml.apache.org/xalan/redirect"
 extension-element-prefixes="redirect">
    <xsl:strip-space elements="*"/>
    <xsl:param name="pLimit" select="3"/>
    <xsl:template match="node()|@*" name="identity">
        <xsl:param name="pGroup"/>
        <xsl:copy>
            <xsl:apply-templates select="node()|@*">
                <xsl:with-param name="pGroup" select="$pGroup"/>
            </xsl:apply-templates>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="/">
        <xsl:for-each select="//R[position() = 1 or position() = $pLimit + 1]">
            <redirect:write select="concat('output',position(),'.xml')">
                <xsl:apply-templates select="/node()">
                    <xsl:with-param name="pGroup" select="position()-1"/>
                </xsl:apply-templates>
            </redirect:write>
        </xsl:for-each>
    </xsl:template>
    <xsl:template match="R">
        <xsl:param name="pGroup"/>
        <xsl:if test="position() > $pLimit = $pGroup">
            <xsl:call-template name="identity"/>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

output1.xml: 

<ExportData>
    <TransportHeader>
        <Timestamp>2011-01-16 06:00:33</Timestamp>
        <From>
            <Name>DynamicExport</Name>
            <Version>1.</Version>
        </From>
        <MessageId>d7b5c5b69a83</MessageId>
    </TransportHeader>
    <ExportConfig>
        <DateTimeFormat>yyyy-MM-dd HH:mm:ss</DateTimeFormat>
        <DecimalSymbol>.</DecimalSymbol>
    </ExportConfig>
    <DataSet>
        <Tables>
            <Table>
                <RH>...</RH>
                <Rows>
                    <R>Data1</R>
                    <R>Data2</R>
                    <R>Data3</R>
                </Rows>
            </Table>
        </Tables>
    </DataSet>
</ExportData>

output2.xml 

<ExportData>
    <TransportHeader>
        <Timestamp>2011-01-16 06:00:33</Timestamp>
        <From>
            <Name>DynamicExport</Name>
            <Version>1.</Version>
        </From>
        <MessageId>d7b5c5b69a83</MessageId>
    </TransportHeader>
    <ExportConfig>
        <DateTimeFormat>yyyy-MM-dd HH:mm:ss</DateTimeFormat>
        <DecimalSymbol>.</DecimalSymbol>
    </ExportConfig>
    <DataSet>
        <Tables>
            <Table>
                <RH>...</RH>
                <Rows>
                    <R>Data4</R>
                    <R>Data5</R>
                </Rows>
            </Table>
        </Tables>
    </DataSet>
</ExportData>

Примечание : Это простое решение для не вложенных таблиц. Использование атрибута extension-element-prefixes.

1 голос
/ 03 мая 2011

Это преобразование показывает, как выполнить разбиение . Это оставлено в качестве упражнения, чтобы адаптировать его к вашим потребностям: 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="R[position() mod 3 =1]">
  <RGroup>
   <xsl:copy-of select=
    ".|following-sibling::R[not(position() > 2)]"/>
  </RGroup>
 </xsl:template>

 <xsl:template match="R"/>
</xsl:stylesheet>

При применении к этому документу XML (фрагмент оригинального документа): 

<Rows>
    <R>Data1</R>
    <R>Data2</R>
    <R>Data3</R>
    <R>Data4</R>
    <R>Data5</R>
</Rows>

производится желаемое разбиение: 

<Rows>
   <RGroup>
      <R>Data1</R>
      <R>Data2</R>
      <R>Data3</R>
   </RGroup>
   <RGroup>
      <R>Data4</R>
      <R>Data5</R>
   </RGroup>
</Rows>
...