XSL: подсчет предыдущих уникальных братьев и сестер из дочерних узлов

Question

Я хочу применить таблицу стилей XSL, которая подсчитывает предыдущие уникальные узлы "ROLE" и выделяет следующий формат вывода ROLE / @ name, PERM / @ perfrom и количество уникальных узлов ROLE до текущего узла.
Это продолжение этого вопроса , но с немного большей сложностью. Я считаю, что метод Мюнхена - лучший способ реализовать это, потому что длина этого файла будет большой.

У меня есть следующий XML (извините за длину)

<?xml version="1.0" encoding="utf-8" ?>
<ROLEACTIONINFO>
  <ROLE name="TESTER">
    <ACTIONINFO>
      <PERMINFO>
        <PERM type="PT0" field="ALL" permfrom="PERM1565"/>
      </PERMINFO>
    </ACTIONINFO>
  </ROLE>
  <ROLE name="PARENT1">
    <ACTIONINFO>
    </ACTIONINFO>
  </ROLE>
  <ROLE name="PARENT1">
    <ACTIONINFO>
      <PERMINFO>
        <PERM type="PT8" field="ALL" permfrom="PERM1"/>
      </PERMINFO>
    </ACTIONINFO>
  </ROLE>
  <ROLE name="PARENT1">
    <ACTIONINFO>
      <PERMINFO>
        <PERM type="PT7" field="ALL" permfrom="PERM2"/>
        <PERM type="PT7" field="ALL" permfrom="PERM54"/>
      </PERMINFO>
    </ACTIONINFO>
  </ROLE>
  <ROLE name="PARENT2">
    <ACTIONINFO>
      <PERMINFO>
        <PERM type="PT6" field="ALL" permfrom="PERM1"/>
      </PERMINFO>
    </ACTIONINFO>
  </ROLE>
  <ROLE name="PARENT2">
    <ACTIONINFO>
      <PERMINFO>
        <PERM type="PT5" field="ALL" permfrom="PERM2"/>
      </PERMINFO>
    </ACTIONINFO>
  </ROLE>
  <ROLE name="PARENT3">
    <ACTIONINFO>
      <PERMINFO>
        <PERM type="PT2" field="ALL" permfrom="PERM44"/>
      </PERMINFO>
    </ACTIONINFO>
  </ROLE>
 </ROLEACTIONINFO>

Вот лист версии XSL, с которым я играл:

   <xsl:stylesheet version="1.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>
  <xsl:template match="text()"/>

  <xsl:key name="kRole" match="ROLE[ACTIONINFO/PERMINFO/PERM]" use="@name" />

  <xsl:template match="PERM">
    <xsl:variable name="roles-so-far" select="ancestor::ROLE | ancestor::ROLE/preceding-sibling::ROLE[ACTIONINFO/PERMINFO/PERM]"/>
    <!-- Only select the first instance of each ROLE name -->
    <xsl:variable name="roles-so-far-unique"              
                   select="$roles-so-far[generate-id(ancestor::ROLE) = generate-id(key('kRole',ancestor::ROLE/@name)[1])]"/>
    <xsl:apply-templates select="ancestor::ROLE/@name"/>
    <xsl:text>&#x9;</xsl:text>
    <xsl:apply-templates select="@permfrom"/>
    <xsl:text>&#x9;</xsl:text>
    <xsl:value-of select="count($roles-so-far-unique)"/>
    <!-- linefeed -->
    <xsl:text>&#xA;</xsl:text>
  </xsl:template>

</xsl:stylesheet>

Вот желаемый вывод:

TESTER  PERM1565    1
PARENT1 PERM1   2
PARENT1 PERM2   2
PARENT1 PERM54  2
PARENT2 PERM1   3
PARENT2 PERM2   3
PARENT3 PERM44  4

Вот фактический (неправильный) вывод:

TESTER  PERM1565    1
PARENT1 PERM1   2
PARENT1 PERM2   3
PARENT1 PERM54  3
PARENT2 PERM1   4
PARENT2 PERM2   5
PARENT3 PERM44  6

Заранее спасибо.

Answer 1

Это происходит от каждого <PERM>, беря соответственно <ROLE> и считая его уникальных предшественников:

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>

  <xsl:output method="text" />

  <xsl:variable name="TAB" select="'&#x09;'" />
  <xsl:variable name="LF"  select="'&#x0A;'" />

  <xsl:key name="kRole" match="ROLE" use="@name" />

  <xsl:template match="/">
    <xsl:apply-templates select="//PERM" />
  </xsl:template>

  <xsl:template match="PERM">
    <xsl:variable name="vThisRole" select="ancestor::ROLE[1]" />
    <xsl:variable name="vPrecedingRoles" select="
      ($vThisRole | $vThisRole/preceding-sibling::ROLE)
    " />
    <xsl:variable name="vUniquePrecedingRoles" select="
      $vPrecedingRoles[count(. | key('kRole', ./@name)[1]) = 1]
    " />
    <xsl:value-of select="
      concat(
        $vThisRole/@name, $TAB,
        @permfrom, $TAB,
        count($vUniquePrecedingRoles), $LF
      )
    " />
  </xsl:template>

</xsl:stylesheet>

Выход:

TESTER  PERM1565        1
PARENT1 PERM1   2
PARENT1 PERM2   2
PARENT1 PERM54  2
PARENT2 PERM1   3
PARENT2 PERM2   3
PARENT3 PERM44  4

XML, с которым вы имеете дело, находится в довольно плохом состоянии, если вы спросите меня. По крайней мере тот факт, что все, что имеет отношение к безопасности, выражается «количеством предшествующих уникальных имен» вместо правильной структуры данных, заставляет меня почесать голову. ;-) Есть ли шанс, что вы можете изменить ввод?