Как запланировать работу для запроса SQL для ежедневного запуска?

Question

Мне нужно знать, как ежедневно выполнять запрос SQL с помощью задания агента SQL Server с минимальными необходимыми параметрами конфигурации.

Answer 1

1. Разверните узел агента SQL Server, щелкните правой кнопкой мыши узел «Задания» в агенте SQL Server и выберите 'New Job'

2. В окне 'New Job' введите название работы и описание на вкладке 'General'.

3. Выберите 'Steps' в левой части окна и нажмите 'New' внизу.

4. В окне 'Steps' введите имя шага и выберите базу данных, с которой вы хотите выполнить запрос.

5. Вставьте команду T-SQL, которую вы хотите запустить, в командное окно и нажмите 'OK'.

6. Щелкните меню 'Schedule' слева от окна «Новое задание» и введите информацию о расписании (например, ежедневно и по времени).

7. Нажмите 'OK' - и это должно быть.

(Конечно, есть и другие варианты, которые вы можете добавить, но я бы сказал, что это тот минимум, который необходим для настройки и планирования работы)

Answer 2

Я сделал анимированный GIF из шагов в принятом ответе.Это из MSSQL Server 2012

Answer 3

Чтобы сделать это в t-sql, вы можете использовать следующие системные хранимые процедуры для планирования ежедневной работы.Этот пример запланирован ежедневно в 1:00.См. Справку Microsoft для получения подробной информации о синтаксисе отдельных хранимых процедур и допустимом диапазоне параметров.

DECLARE @job_name NVARCHAR(128), @description NVARCHAR(512), @owner_login_name NVARCHAR(128), @database_name NVARCHAR(128);

SET @job_name = N'Some Title';
SET @description = N'Periodically do something';
SET @owner_login_name = N'login';
SET @database_name = N'Database_Name';

-- Delete job if it already exists:
IF EXISTS(SELECT job_id FROM msdb.dbo.sysjobs WHERE (name = @job_name))
BEGIN
    EXEC msdb.dbo.sp_delete_job
        @job_name = @job_name;
END

-- Create the job:
EXEC  msdb.dbo.sp_add_job
    @job_name=@job_name, 
    @enabled=1, 
    @notify_level_eventlog=0, 
    @notify_level_email=2, 
    @notify_level_netsend=2, 
    @notify_level_page=2, 
    @delete_level=0, 
    @description=@description, 
    @category_name=N'[Uncategorized (Local)]', 
    @owner_login_name=@owner_login_name;

-- Add server:
EXEC msdb.dbo.sp_add_jobserver @job_name=@job_name;

-- Add step to execute SQL:
EXEC msdb.dbo.sp_add_jobstep
    @job_name=@job_name,
    @step_name=N'Execute SQL', 
    @step_id=1, 
    @cmdexec_success_code=0, 
    @on_success_action=1, 
    @on_fail_action=2, 
    @retry_attempts=0, 
    @retry_interval=0, 
    @os_run_priority=0, 
    @subsystem=N'TSQL', 
    @command=N'EXEC my_stored_procedure; -- OR ANY SQL STATEMENT', 
    @database_name=@database_name, 
    @flags=0;

-- Update job to set start step:
EXEC msdb.dbo.sp_update_job
    @job_name=@job_name, 
    @enabled=1, 
    @start_step_id=1, 
    @notify_level_eventlog=0, 
    @notify_level_email=2, 
    @notify_level_netsend=2, 
    @notify_level_page=2, 
    @delete_level=0, 
    @description=@description, 
    @category_name=N'[Uncategorized (Local)]', 
    @owner_login_name=@owner_login_name, 
    @notify_email_operator_name=N'', 
    @notify_netsend_operator_name=N'', 
    @notify_page_operator_name=N'';

-- Schedule job:
EXEC msdb.dbo.sp_add_jobschedule
    @job_name=@job_name,
    @name=N'Daily',
    @enabled=1,
    @freq_type=4,
    @freq_interval=1, 
    @freq_subday_type=1, 
    @freq_subday_interval=0, 
    @freq_relative_interval=0, 
    @freq_recurrence_factor=1, 
    @active_start_date=20170101, --YYYYMMDD
    @active_end_date=99991231, --YYYYMMDD (this represents no end date)
    @active_start_time=010000, --HHMMSS
    @active_end_time=235959; --HHMMSS

Answer 4

Использование T-SQL: Моя работа - выполнение хранимой процедуры. Вы можете легко изменить @command для запуска вашего sql.

EXEC msdb.dbo.sp_add_job  
   @job_name = N'MakeDailyJob',   
   @enabled = 1,   
   @description = N'Procedure execution every day' ; 

 EXEC msdb.dbo.sp_add_jobstep  
    @job_name = N'MakeDailyJob',   
    @step_name = N'Run Procedure',   
    @subsystem = N'TSQL',   
    @command = 'exec BackupFromConfig';

 EXEC msdb.dbo.sp_add_schedule  
    @schedule_name = N'Everyday schedule',   
    @freq_type = 4,  -- daily start
    @freq_interval = 1,
    @active_start_time = '230000' ;   -- start time 23:00:00

 EXEC msdb.dbo.sp_attach_schedule  
   @job_name = N'MakeDailyJob',  
   @schedule_name = N'Everyday schedule' ;

 EXEC msdb.dbo.sp_add_jobserver  
   @job_name = N'MakeDailyJob',  
   @server_name = @@servername ;

Answer 5

, если требуется ежедневное резервное копирование // следующего хранилища сценариев sql в C: \ Users \ admin \ Desktop \ DBScript \ DBBackUpSQL.sql

DECLARE @pathName NVARCHAR(512),
 @databaseName NVARCHAR(512) SET @databaseName = 'Databasename' SET @pathName = 'C:\DBBackup\DBData\DBBackUp' + Convert(varchar(8), GETDATE(), 112) + '_' + Replace((Convert(varchar(8), GETDATE(), 108)),':','-')+ '.bak' BACKUP DATABASE @databaseName TO DISK = @pathName WITH NOFORMAT, 
INIT, 
NAME = N'', 
SKIP, 
NOREWIND, 
NOUNLOAD, 
STATS = 10 
GO

, открыть планировщик задач

создать задачу-> выбрать Triggers вкладка Выбрать New.

Кнопка Выбрать Ежедневно Радиокнопка

нажать Ok Кнопка

, затем нажать Action вкладка Выбрать новый.

Поместите кнопку "C:\Program Files\Microsoft SQL Server\100\Tools\Binn\SQLCMD.EXE" -S ADMIN-PC -i "C:\Users\admin\Desktop\DBScript\DBBackUpSQL.sql" в текстовое поле программы / скрипта (убедитесь, что совпадает путь к вашим файлам и поместите путь в двойных кавычках в поле Пуск-> Поиск, и если оно найденозатем щелкните по нему и увидите, есть ли резервная копия или нет)

- указанный выше путь может быть введен 100, запись 90 "C:\Program Files\Microsoft SQL Server\90\Tools\Binn\SQLCMD.EXE" -S ADMIN-PC -i "C:\Users\admin\Desktop\DBScript\DBBackUpSQL.sql"

, затем нажмите кнопку ОК

Сценарий будет выполняться в срок, которое вы выбираете на вкладке Триггер ежедневно

наслаждайтесь .............

Answer 6

Вот пример кода:

Exec sp_add_schedule
    @schedule_name = N'SchedulName' 
    @freq_type = 1
    @active_start_time = 08300