Преобразование определенных документов XML с XSLT

Question

HI

мои XML-документы имеют следующую компоновку

<root>
  <child>
    <item type="ID">id1</item>
    <item type="TEXT">text1</item>
  </child>

  <child>
    <item type="ID"/>
    <item type="TEXT">text2</item>
  </child>

  <child>
    <item type="ID"/>
    <item type="TEXT">text3</item>
  </child>

  <child>
    <item type="ID">id2</item>
    <item type="TEXT">text4</item>
  </child>

  <child>
    <item type="ID"/>
    <item type="TEXT">text5</item>
  </child>

  ...
</root>

Каждый раз, когда есть пустой тег элемента с type = ID, это означает, что он имеет то же значение, что и предыдущий брат. Теперь я хочу преобразовать это в

<root>
  <child id="id1">text1text2text3</child>
  <child id="id2">text4text5</child>

  ...
</root>

Мое решение для этого

<?xml version="1.0"?>

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template match="/">
    <root>
      <xsl:apply-templates select="//child/item[@type='ID'][text()='id1' or text()='id2']"/>
    </root>
  </xsl:template>

  <xsl:template match="child/item[text()='id1' or text()='id2']">
    <child id="{text()}">
      <xsl:value-of select="./../item[@type='TEXT']/."/>
      <xsl:apply-templates select="./../following::*[1]/item[@type='ID'][not(text()='id1' or text()='id2')]"/>
    </child>
  </xsl:template>

  <xsl:template match="child/item[not(text()='id1' or text()='id2')]">
    <xsl:value-of select="./../item[@type='TEXT']/."/>
    <xsl:apply-templates select="./../following::*[1]/item[@type='ID'][not(text()='id1' or text()='id2')]"/>
  </xsl:template>

</xsl:stylesheet>

Это работает, но уродливо и негибко. Например, что если бы у меня были произвольные значения идентификатора, а не только id1 и id2. У кого-нибудь есть хороший совет или лучшее решение?

Answer 1

XSLT 2.0 решение:

<xsl:template match="root">
  <xsl:for-each-group select="child" 
                      group-starting-with="child[string(item[@type='ID'])]">
    <child id="{item[@type='ID']}">
      <xsl:value-of select="current-group()/item[@type='TEXT']" separator=""/>
    </child>
  </xsl:for-each-group>
</xsl:template>

Answer 2

Это преобразование XSLT 1.0 :

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:key name="kFollowing" match="item[@type='TEXT']"
      use="((..|../preceding-sibling::child)
                       /item[@type='ID'and string(.)]
           )[last()]"/>

 <xsl:template match="/*">
  <root>
   <xsl:apply-templates select=
       "*[item[@type='ID' and string(.)]]"/>
  </root>
 </xsl:template>

 <xsl:template match="*">
  <child id="{item[@type='ID']}">
   <xsl:copy-of select="key('kFollowing', item[@type='ID'])/text()"/>
  </child>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML :

<root>
    <child>
        <item type="ID">id1</item>
        <item type="TEXT">text1</item>
    </child>
    <child>
        <item type="ID"/>
        <item type="TEXT">text2</item>
    </child>
    <child>
        <item type="ID"/>
        <item type="TEXT">text3</item>
    </child>
    <child>
        <item type="ID">id2</item>
        <item type="TEXT">text4</item>
    </child>
    <child>
        <item type="ID"/>
        <item type="TEXT">text5</item>
    </child>  ...
</root>

производитискомый, правильный результат :

<root>
   <child id="id1">text1text2text3</child>
   <child id="id2">text4text5</child>
</root>

Объяснение : Использование ключа для выражения связи между всеми сопоставленными элементами item с первым предшествующим item с @type='ID' и дочерний текстовый узел.

Answer 3

Эта таблица стилей XSLT 1.0 должна делать это:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

    <xsl:output indent="yes"/>

    <xsl:template match="/*">
        <root>
            <!-- visit each "child" element with a non-blank ID -->
            <xsl:for-each select="child[item[@type=&apos;ID&apos;] != &apos;&apos;]">
                <xsl:variable name="this-id" select="item[@type=&apos;ID&apos;]"></xsl:variable>
                <child id="{$this-id}">
                    <!-- visit this node and each following "child" element which
                        1. has a blank ID, and
                        2. whose immediate preceding non-blank ID child element is this one -->                        
                    <xsl:for-each select=".|following-sibling::child
                        [item[@type=&apos;ID&apos;] = &apos;&apos;]
                        [preceding-sibling::child[item[@type=&apos;ID&apos;] != &apos;&apos;][1]/item[@type=&apos;ID&apos;]=$this-id]">
                        <xsl:value-of select="item[@type=&apos;TEXT&apos;]"/>
                    </xsl:for-each>
                </child>

            </xsl:for-each>
        </root>
    </xsl:template>    

</xsl:stylesheet>