As3, как позвонить и использовать внешний класс

Question

У меня есть этот классный пакет MP3pitch для As3, который я получил здесь: http://blog.andre -michelle.com / 2009 / pitch-mp3 / # more-483

package components
{
import flash.events.Event;
import flash.events.SampleDataEvent;
import flash.media.Sound;
import flash.net.URLRequest;
import flash.utils.ByteArray;

/**
 * @author Andre Michelle (andre.michelle@gmail.com)
 */
public class MP3Pitch 
{
    private const BLOCK_SIZE: int = 3072;

    private var _mp3: Sound;
    private var _sound: Sound;

    private var _target: ByteArray;

    private var _position: Number;
    private var _rate: Number;

    public function MP3Pitch( url: String )
    {
        _target = new ByteArray();

        _mp3 = new Sound();
        _mp3.addEventListener( Event.COMPLETE, complete );
        _mp3.load( new URLRequest( url ) );

        _position = 0.0;
        _rate = 1.0;

        _sound = new Sound();
        _sound.addEventListener( SampleDataEvent.SAMPLE_DATA, sampleData );
    }

    public function get rate(): Number
    {
        return _rate;
    }

    public function set rate( value: Number ): void
    {
        if( value < 0.0 )
            value = 0;

        _rate = value;
    }

    private function complete( event: Event ): void
    {
        _sound.play();
    }

    private function sampleData( event: SampleDataEvent ): void
    {
        //-- REUSE INSTEAD OF RECREATION
        _target.position = 0;

        //-- SHORTCUT
        var data: ByteArray = event.data;

        var scaledBlockSize: Number = BLOCK_SIZE * _rate;
        var positionInt: int = _position;
        var alpha: Number = _position - positionInt;

        var positionTargetNum: Number = alpha;
        var positionTargetInt: int = -1;

        //-- COMPUTE NUMBER OF SAMPLES NEED TO PROCESS BLOCK (+2 FOR INTERPOLATION)
        var need: int = Math.ceil( scaledBlockSize ) + 2;

        //-- EXTRACT SAMPLES
        var read: int = _mp3.extract( _target, need, positionInt );

        var n: int = read == need ? BLOCK_SIZE : read / _rate;

        var l0: Number;
        var r0: Number;
        var l1: Number;
        var r1: Number;

        for( var i: int = 0 ; i < n ; ++i )
        {
            //-- AVOID READING EQUAL SAMPLES, IF RATE < 1.0
            if( int( positionTargetNum ) != positionTargetInt )
            {
                positionTargetInt = positionTargetNum;

                //-- SET TARGET READ POSITION
                _target.position = positionTargetInt << 3;

                //-- READ TWO STEREO SAMPLES FOR LINEAR INTERPOLATION
                l0 = _target.readFloat();
                r0 = _target.readFloat();

                l1 = _target.readFloat();
                r1 = _target.readFloat();
            }

            //-- WRITE INTERPOLATED AMPLITUDES INTO STREAM
            data.writeFloat( l0 + alpha * ( l1 - l0 ) );
            data.writeFloat( r0 + alpha * ( r1 - r0 ) );

            //-- INCREASE TARGET POSITION
            positionTargetNum += _rate;

            //-- INCREASE FRACTION AND CLAMP BETWEEN 0 AND 1
            alpha += _rate;
            while( alpha >= 1.0 ) --alpha;
        }

        //-- FILL REST OF STREAM WITH ZEROs
        if( i < BLOCK_SIZE )
        {
            while( i < BLOCK_SIZE )
            {
                data.writeFloat( 0.0 );
                data.writeFloat( 0.0 );

                ++i;
            }
        }

        //-- INCREASE SOUND POSITION
        _position += scaledBlockSize;
    }
}

}

Как я могу включить его в свой «основной» файл as3 и использовать его?Я не могу просто вставить его в тот же файл, так как основной файл уже имеет свой собственный пакет и класс.

По сути, я пытаюсь загрузить звуковой файл, воспроизвести его иизменить его шаг по отношению к значениям, которые у меня уже есть.

Заранее спасибо.

Answer 1

Вы должны создать папку с тем же именем, что и пакет (здесь components), и поместить в нее этот класс. Затем с вашего основного импортируйте этот класс:

import components.MP3Pitch

Вам просто нужно создать экземпляр этого класса и использовать его в своем коде:

var pitcher:MP3Pitch = new MP3Pitch("mymp3.mp3");
pitcher.rate = 2;

Answer 2

package {

import components.MP3Pitch;

public class Main extends Sprite
{
    public function Main() {
       new MP3Pitch("http://path-to-mp3-file.com/");
    }

}
}