Использование объектов OLD и NEW для динамических операций внутри триггера - PullRequest
Новая
       1

Использование объектов OLD и NEW для динамических операций внутри триггера

1 голос
/ 26 марта 2012

Я хочу знать, могу ли я использовать объекты OLD и NEW для динамических операций внутри триггера.

Я ищу что-то вроде этого: -

  1. ABC - это таблица, для которой мне нужно написать Trigger.
  2. TracK_Table поддерживает список столбцов таблицы, которые необходимо отслеживать (регистрировать).

  3. f_log - это функция, которая вставляет изменения в данные в таблицу отслеживания (журнала). 

    CREATE OR REPLACE TRIGGER trg_TRACK
AFTER INSERT OR UPDATE OR DELETE ON ABC
FOR EACH ROW
declare
    v_old_val varchar2(1000);
    v_new_val varchar2(1000);
    n_ret int;
    n_id varchar(50);

    cursor cur_col is 
    SELECT  COLUMN_NAME,
        TABLE_name      
    FROM    track_TABLE
    WHERE   upper(TABLE_NAME) = upper('ABC') 
      AND exists (select  cname 
                    from col
                   where UPPER(tname) =upper('ABC') 
                     and upper(cname)=upper(COLUMN_NAME))
      AND upper(allow) = 'Y';

begin
   n_id:= :old.id;

   for i_get_col in c_get_col
   loop
      execute immediate 
         'begin 
            :v_old_val:= select '||i_get_col.column_name ||' 
                           from '||:old ||' 
                          where id = '||n_id ||'; 
          end;' using out v_old_val;
      execute immediate 
           'begin 
             :v_new_val:= select '||i_get_col.column_name ||' 
                            from '||:new ||' 
                            where id = '||n_id ||'; 
            end;' using out v_new_val;
      n_ret := f_log(n_id,i_get_col.column_name,v_old_val,v_new_val);
   end loop;
end;
/

Ответы [ 2 ]

1 голос
/ 26 марта 2012

Один вариант: нажмите логику, чтобы проверить, отслеживается ли столбец в процедуре f_log, а затем передайте все столбцы.

Например, если ваша таблица track_Table (table_name, column_name, allow)значения для каждого столбца, который вы хотите отслеживать, затем что-то вроде этого 

 CREATE OF REPLACE PROCEDURE f_log(  p_id          varchar2  
                                    ,p_table_name  varchar2
                                    ,p_column_name varchar2
                                    ,p_old_val     varchar2
                                    ,p_new_val     varchar2)
 as
    l_exists number;
    cursor chk_column_track IS
        SELECT  1
        FROM    track_TABLE           
        WHERE   upper(TABLE_NAME)  = upper(p_table_name)              
        AND     UPPER(column_name) = upper(p_column_name)
        AND     upper(allow) = 'Y'; 
 begin
    open chk_column_track;
    fetch chk_column_track into l_exists;
    if chk_column_track%found then
       --do the insert here
    end if;
    close chk_column_track;
 end;
 /

 CREATE OR REPLACE TRIGGER trg_TRACK 
 AFTER INSERT OR UPDATE OR DELETE ON ABC 
 FOR EACH ROW 
 DECLARE   
      n_id varchar(50); 
 BEGIN   
    n_id := NVL(:old.id, :new.id);   
    -- send all of the values to f_log and have it decide whether to save them
    f_log(:old.id,'COL1',:old.col1,:new.col1);   
    f_log(:old.id,'COL2',:old.col2,:new.col2);   
    f_log(:old.id,'COL3',:old.col3,:new.col3);   
    ... 
 END;

И ради бога, в верхнем регистре значения в вашей track_table при вставке, чтобы вам не нужно было UPPER () сохраненныеЗначения, что делает любой индекс для этих значений бесполезным!

Теперь это израсходует некоторые ресурсы, проверяя имя каждого столбца в каждой операции, но если вы не используете большие объемы, тогда это может быть управляемым.

В противном случае вам понадобится более элегантное решение.Как использование возможностей коллекций и предложение TABLE () для поиска track_table в массовых операциях.Имейте в виду, что в данный момент я удален от своей базы данных, поэтому я не скомпилировал этот код для тестирования. 

    CREATE OR REPLACE TYPE t_audit_row AS OBJECT (
   p_table_name   varchar2(30)
  ,p_column_name  varchar2(30)
  ,p_id           varchar2(50)
  ,p_old_val      varchar2(2000)
  ,p_new_val      varchar2(2000)
);

CREATE OR REPLACE TYPE t_audit_row_table AS TABLE OF t_audit_row;

CREATE OR REPLACE PROCEDURE f_log (p_audit_row_table t_audit_Row_table)
AS
begin
   -- see how we can match the contents of the collection to the values
   -- in the table all in one query. the insert is just my way of showing
   -- how this can be done in one bulk operation. Alternately you could make
   -- the select a cursor and loop through the rows to process them individually.
   insert into my_audit_log (table_name, column_name, id, old_val, new_val)
   select  p_table_name
          ,p_column_name
          ,p_id
          ,p_old_val
          ,p_new_val
   FROM   track_TABLE TT
         ,table(p_audit_row_table) art
   WHERE  tt.TABLE_NAME   = art.p_table_name                       
   AND    tt.column_name  = art.p_column_name         
   AND    tt.allow        = 'Y';
end;
/

CREATE OR REPLACE TRIGGER trg_TRACK   
AFTER INSERT OR UPDATE OR DELETE ON ABC   
FOR EACH ROW   
DECLARE          
  l_id           varchar(50);   
  l_audit_table  t_audit_row_table;
BEGIN        
  l_id := NVL(:old.id, :new.id);        
  -- send all of the values to f_log and have it decide whether to save them   
  l_audit_table := t_audit_row_table (
                      t_audit_row ('ABC','COL1',l_id, :old.col1, :new.col1)  
                      ,t_audit_row ('ABC','COL2',l_id, :old.col2, :new.col2)  
                      ,t_audit_row ('ABC','COL3',l_id, :old.col3, :new.col3)  
                      ,...  
                      ,t_audit_row ('ABC','COLn',l_id, :old.coln, :new.coln)  
                   );
  f_log(l_audit_table);
end;
/
1 голос
/ 26 марта 2012

Нет, вы не можете динамически обращаться к СТАРЫМ и НОВЫМ псевдопеременным.Что вы можете сделать, это использовать ваши данные track_table в скрипте или процедуре для генерации статических триггеров, которые выглядят следующим образом: 

CREATE OR REPLACE TRIGGER trg_TRACK
AFTER INSERT OR UPDATE OR DELETE ON ABC
FOR EACH ROW
DECLARE
  n_id varchar(50);
BEGIN
  n_id := NVL(:old.id, :new.id);
  f_log(:old.id,'COL1',:old.col1,:new.col1);
  f_log(:old.id,'COL3',:old.col3,:new.col3);
  ...
END;

Так что, если данные в таблице TRACK_CHANGES изменяются, вам просто нужно заново сгенерировать триггеры.

...