SQL 2005 - вопрос о параметрах варианта - PullRequest
Новая
       33

SQL 2005 - вопрос о параметрах варианта

1 голос
/ 01 сентября 2011

Я работаю над функцией, которая будет использоваться не менее чем 10 SProc, и, вероятно, будет расти после того, как ее сгладят.

Проблема, с которой я сталкиваюсь, заключается в том, что я не хочу разрабатывать функцию для каждого типа данных, поэтому тип данных SQL_VARIANT выглядит довольно удобным для данного действия. Я знаю, это может сделать ISNULL проверку типа данных, но я также хочу проверить, является ли передаваемое значение действительным числом, но функция ISNUMERIC не работает с SQL_VARIANT, и я не слишком уверен в функции SQL_VARIANT_PROPERTY.

Код до сих пор: 

CREATE FUNCTION dbo.mpt_Format_Number
(
    @value SQL_VARIANT
    , @money BIT
)
RETURNS VARCHAR
AS
BEGIN
    --Check for NULL value
    IF ISNULL(@value) BEGIN
        -- Value IS NULL, return NULL
        RETURN NULL
    END ELSE BEGIN
        -- Value is NOT NULL
        DECLARE @TMP VARCHAR
    END 
END

Ответы [ 2 ]

4 голосов
/ 01 сентября 2011 
CREATE FUNCTION dbo.mpt_Format_Number 
( 
    @value SQL_VARIANT 
    , @money BIT 
) 
RETURNS VARCHAR 
AS 
BEGIN 
--Check for NULL value 
IF @value is null  
          -- Value IS NULL, return NULL 
    RETURN NULL 
ELSE 
BEGIN 
    -- Value is NOT NULL 
    if isnumeric(convert(varchar(max), @value)) = 1 RETURN 'Y' -- is valid number
    --DECLARE @TMP VARCHAR 

END  
return 'N' --is not valid number 
END

Вы всегда можете проверить тип свойства с помощью этого синтаксиса. Должно быть легко отключить вашу функцию. 

declare @t SQL_VARIANT
set @t = '3'
select SQL_VARIANT_PROPERTY(@t, 'basetype')

Результат: 

varchar
0 голосов
/ 05 сентября 2011

В качестве окончательной реализации здесь приведена полная функция, как она использовалась. 

ALTER FUNCTION [dbo].[_mpt_Format_Number]
(
    @value SQL_VARIANT
    , @money BIT = 0
)
RETURNS VARCHAR(max)
AS
BEGIN
    DECLARE @ret VARCHAR(MAX)
    --Check for NULL value
    IF @value IS NULL BEGIN
        -- Value IS NULL, return NULL
        SET @ret = 'NULL'
    END ELSE BEGIN
        -- Value is NOT NULL

        --Check for Numeric Value
        IF ISNUMERIC(CONVERT(VARCHAR, @value)) = 0 BEGIN
            --Value is NOT a Number, return NULL
            SET @ret =  'NULL'
        END ELSE BEGIN
            --Value IS a Number
            declare @isNeg BIT
            declare @tmp varchar(max)
            set @tmp = convert(varchar(max), round(cast(@value as money), 0), 1)

            --Check if value is negative
            if @value < 0 begin
                --Value is Negative
                set @isNeg = 1
                --Remove the negative sign
                set @tmp = replace(@tmp, '-', '')
            end 

            --Remove the decimal plus any digits to the right of the decimal
            set @tmp = left(@tmp ,len(@tmp) - 3)

            --Is money set to True
            if @money = 1 begin
                --Pre-pend the dollar sign to value
                set @tmp = '$' + @tmp
            end

            --Is isNeg set to True
            if @isNeg = 1 begin
                --Encapsulate the value with parenthesis
                set @tmp = '(' + @tmp + ')'
            end

            SET @ret =  @tmp
        END 
    END 

    RETURN @ret
END
...