Проверьте наличие дочернего узла и применение шаблонов

Question

У меня есть следующая упрощенная структура XML:

<?xml version="1.0" encoding="UTF-8"?>
<ExportData>
<TransportHeader>
    <Timestamp>2011-01-16 06:00:33</Timestamp>
    <From>
        <Name>DynamicExport</Name>
        <Version>1.</Version>
    </From>
    <MessageId>d7b5c5b69a83</MessageId>
</TransportHeader>
<ExportConfig>
    <DateTimeFormat>yyyy-MM-dd HH:mm:ss</DateTimeFormat>
    <DecimalSymbol>.</DecimalSymbol>
</ExportConfig>
<DataSet> 
    <Tables>
        <Table>
            <RH>...</RH>
            <Rows>
                <R>Data1</R>
                <R>Data2</R>
                <R>Data3</R>
                <R>Data4</R>
                <R>Data5</R>
            </Rows>
        </Table>
    </Tables>
</DataSet>
</ExportData>

Я должен проверить, существуют ли <R> элементы или нет. Если элементов <R> не существует, отображение необходимо прервать, в противном случае необходимо создать элемент <Line> для <R>.

Я придумал это решение, которое до сих пор прекрасно работает:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output encoding="ISO-8859-1" method="xml" indent="yes" />

<!-- suppress nodes that are not matched -->
<xsl:template match="text() | @*">
    <xsl:apply-templates select="text() | @*"/>
</xsl:template>

<xsl:template match="/">
    <xsl:choose>
        <xsl:when test="not(ExportData/DataSet/Tables/Table/Rows/node())">
            <xsl:message terminate="yes">No line items</xsl:message>
        </xsl:when>
        <xsl:otherwise>
            <xsl:apply-templates/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template match="/ExportData/DataSet/Tables/Table/Rows">
    <INVOIC02>
        <!-- apply LINE ITEMS template -->
        <xsl:apply-templates select="R"/>
    </INVOIC02>
</xsl:template>

<!-- Template creating LINE ITEMS -->
<xsl:template match="R">

    <Line>
        <elements></elements>
    </Line>
</xsl:template>


</xsl:stylesheet>

Если имеется <R> элементов, вывод будет таким:

<?xml version="1.0" encoding="ISO-8859-1"?>
<INVOIC02>
<Line>
    <elements/>
</Line>
<Line>
    <elements/>
</Line>
<Line>
    <elements/>
</Line>
<Line>
    <elements/>
</Line>
<Line>
    <elements/>
</Line>
</INVOIC02>

Если есть только <Rows/> и нет <R> s, отображение прерывается.

Теперь у меня два вопроса:

- Является ли мой тест для <R> элементов надежным: test="not(ExportData/DataSet/Tables/Table/Rows/node())"?

-Я использую <xsl:apply-templates> для создания <Line> элементов вместо <xsl:for-each> конструкции. Мои выражения XPath в порядке или я могу сделать их лучше?

Спасибо за любой ответ или предложение.

С наилучшими пожеланиями, Питер

Answer 1

Надежен ли мой тест для элементов: test = "not (ExportData / DataSet / Tables / Table / Rows / node ())"

Ну, вы хотите, чтобы он потерпел неудачу, если нет элементов R, или потерпел неудачу, если Rows не имеет дочернего элемента node(), который включал бы любой элемент (не только *) 1010 *), text(), comment() или processing-instruction()?

Если вы действительно хотите проверить, что существует хотя бы один элемент R, являющийся дочерним по отношению к Rows, вам следует настроить критерии теста так, чтобы они были более конкретными:

test="not(ExportData/DataSet/Tables/Table/Rows/R)"

В противном случае он может пройти этот тест и продолжить обработку, а не генерировать нужный контент.

I am using <xsl:apply-templates> to create the <Line> items instead of an 
<xsl:for-each> construct. 
Are my XPath expressions okay or could I make them better?

Вы можете избавиться от условной логики <xsl:if> внутри вашего шаблона для корневого узла и переместить эту логику в шаблон для Rows, который не содержит R дочерних элементов. Использование логики в критериях xsl:template @match облегчает оптимизацию процессоров XSLT, что может привести к повышению производительности.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output encoding="ISO-8859-1" method="xml" indent="yes" />

    <!-- suppress nodes that are not matched -->
    <xsl:template match="text() | @*">
        <xsl:apply-templates select="text() | @*"/>
    </xsl:template>

    <!--All Rows must contain an R.  
        If we encounter any that do not, terminate the transform -->
    <xsl:template match="/ExportData/DataSet/Tables/Table/Rows[not(R)]">
        <xsl:message terminate="yes">No line items</xsl:message>
    </xsl:template>

    <!--match for Rows that have R children -->
    <xsl:template match="/ExportData/DataSet/Tables/Table/Rows[R]">
        <INVOIC02>
            <!-- apply LINE ITEMS template -->
            <xsl:apply-templates select="R"/>
        </INVOIC02>
    </xsl:template>

    <!-- Template creating LINE ITEMS -->
    <xsl:template match="R">      
        <Line>
            <elements></elements>
        </Line>
    </xsl:template>

</xsl:stylesheet>

Answer 2

Просто проверьте

<xsl:if test="R">
   <!--What you want to do here-->
</xsl:if>

Это проверит, имеет ли узел R дочерний элемент.

Buddhika