TransformedDistribution в Mathematica - PullRequest
Новая
       16

TransformedDistribution в Mathematica

4 голосов
/ 02 марта 2011

Я разработал некоторый код для генерации случайных изменений из продукта LogNormalDistribution и StableDistribution: 

LNStableRV[{\[Alpha]_, \[Beta]_, \[Gamma]_, \[Sigma]_, \[Delta]_}, 

n_] := Module[{LNRV, SDRV, LNSRV},
  LNRV = RandomVariate[LogNormalDistribution[Log[\[Gamma]], \[Sigma]],
     n];
  SDRV = RandomVariate[
    StableDistribution[\[Alpha], \[Beta], \[Gamma], \[Sigma]], n];
  LNRV * SDRV + \[Delta]
  ]

(* Note the delta serves as a location parameter *)

Я думаю, что это прекрасно работает: 

LNStableRV[{1.5, 1, 1, 0.5, 1}, 50000];
Histogram[%, Automatic, "ProbabilityDensity", 
 PlotRange -> {{-4, 6}, All}, ImageSize -> 250]
ListPlot[%%, Joined -> True, PlotRange -> All]

Теперь я быМне нравится создавать TransformedDistribution в том же ключе, чтобы я мог использовать PDF [], CDF [] и т. д. в этом пользовательском дистрибутиве и легко выполнять графики и другие анализы.

Экстраполяция из примера в Центре документации>TransformedDistribution: 

\[ScriptCapitalD] = 
  TransformedDistribution[
   u v, {u \[Distributed] ExponentialDistribution[1/2], 
    v \[Distributed] ExponentialDistribution[1/3]}];

Я пробовал это: 

LogNormalStableDistribution[\[Alpha]_, \[Beta]_, \[Gamma]_, \
\[Sigma]_, \[Delta]_] := Module[{u, v},
   TransformedDistribution[
    u * v + \[Delta], {u \[Distributed] 
      LogNormalDistribution[Log[\[Gamma]], \[Sigma]], 
     v \[Distributed] 
      StableDistribution[\[Alpha], \[Beta], \[Gamma], \[Sigma]]}]
   ];

\[ScriptCapitalD] = LogNormalStableDistribution[1.5, 1, 1, 0.5, 1]

Что дает мне это: 

TransformedDistribution[
 1 + \[FormalX]1 \[FormalX]2, {\[FormalX]1 \[Distributed] 
   LogNormalDistribution[0, 0.5], \[FormalX]2 \[Distributed] 
   StableDistribution[1, 1.5, 1, 1, 0.5]}]

Но когда я пытаюсь построить PDF из PDFРаспределение, которое никогда не заканчивается (если я не позволял ему работать более минуты или двух): 

Plot[PDF[\[ScriptCapitalD], x], {x, -4, 6}] (* This should plot over the same range as the Histogram above *)

Итак, некоторые вопросы:

Имеет ли моя функция: LogNormalStableDistribution []есть смысл делать такие вещи?

Если да, могу ли я:

  • Просто нужно, чтобы участок [] работал дольше?
  • Изменить это как-нибудь?
  • Что я могу сделать, чтобы он работал быстрее?

Если нет:

  • Нужно ли подходить к этому по-другому?
  • Использовать MixtureDistribution?
  • Использовать что-то еще?

Любые идеи приветствуются.

Лучшие,

J

1 Ответ

4 голосов
/ 03 марта 2011

Ваш подход, использующий преобразованное распределение, просто прекрасен, но поскольку PDF в распределении не существует в закрытом виде, PDF[TransformedDistribution[..],x] не является подходящим способом, так как для каждого x будет применяться символический решатель.Лучше помассировать ваш дистрибутив, чтобы получить PDF.Пусть X - логнормально-устойчивая случайная переменная.Тогда 

CDF[LogNormalStableDistribution[params], x] == Probability[X <= x]

Но X==U*V + delta, следовательно, X<=x переводится в V<=(x-delta)/U.Это дает 

LogNormalStableCDF[{\[Alpha]_, \[Beta]_, \[Gamma]_, \[Sigma]_, \
\[Delta]_}, x_Real] := 
 Block[{u}, 
  NExpectation[
   CDF[StableDistribution[\[Alpha], \[Beta], \[Gamma], \[Sigma]], (x \
- \[Delta])/u], 
   u \[Distributed] LogNormalDistribution[Log[\[Gamma]], \[Sigma]]]]

Дифференцируя по x, мы получаем PDF: 

LogNormalStablePDF[{\[Alpha]_, \[Beta]_, \[Gamma]_, \[Sigma]_, \
\[Delta]_}, x_Real] := 
 Block[{u}, 
  NExpectation[
   PDF[StableDistribution[\[Alpha], \[Beta], \[Gamma], \[Sigma]], (x \
- \[Delta])/u]/u, 
   u \[Distributed] LogNormalDistribution[Log[\[Gamma]], \[Sigma]]]]

Используя это, вот график

enter image description here

...