Создание данных контекста для первого и последнего вхождения каждого значения элемента

Question

С учетом следующего xml:

<container>
    <val>2</val>
    <id>1</id>
</container>
<container>
    <val>2</val>
    <id>2</id>
</container>
<container>
    <val>2</val>
    <id>3</id>
</container>
<container>
    <val>4</val>
    <id>1</id>
</container>
<container>
    <val>4</val>
    <id>2</id>
</container>
<container>
    <val>4</val>
    <id>3</id>
</container>

Я бы хотел вернуть что-то вроде

2 - 1
2 - 3
4 - 1
4 - 3

Используя набор узлов, я смог получить последнее вхождение через:

exsl:node-set($list)/container[not(val = following::val)]

но я не могу понять, как получить первый.

Answer 1

Чтобы получить первое и последнее вхождение (порядок документов) в каждой группе "<val>", вы можете использовать <xsl:key>, например:

<xsl:stylesheet 
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:output method="text" />

  <xsl:key name="ContainerGroupByVal" match="container" use="val" />

  <xsl:variable name="ContainerGroupFirstLast" select="//container[
    generate-id() = generate-id(key('ContainerGroupByVal', val)[1])
    or
    generate-id() = generate-id(key('ContainerGroupByVal', val)[last()])
  ]" />

  <xsl:template match="/">
    <xsl:for-each select="$ContainerGroupFirstLast">
      <xsl:value-of select="val" />
      <xsl:text> - </xsl:text>
      <xsl:value-of select="id" />
      <xsl:value-of select="'&#10;'" /><!-- LF -->
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

---

РЕДАКТИРОВАТЬ # 1: Небольшое объяснение, поскольку это может быть неочевидно сразу:

• <xsl:key> возвращает все <container> узлы, имеющие данный <val>. Вы используете функцию key(), чтобы запросить ее.
• <xsl:variable> - это то, где все это происходит. Это читается как:
  • для каждого из <container> узлов в документе ("//container") проверьте ...
  • … если он имеет тот же уникальный идентификатор (generate-id()), что и первый узел, возвращаемый key(), или последний узел, возвращаемый key()
  • , где key('ContainerGroupByVal', val) возвращает набор <container> узлов, соответствующих текущему <val>
  • , если уникальные идентификаторы совпадают, включить узел в выборку
• <xsl:for-each> выводит. С таким же успехом это может быть <xsl:apply-templates>.

---

РЕДАКТИРОВАТЬ # 2: Как справедливо отмечает Димитр Новатчев в комментариях, вы должны быть осторожны с использованием "//" сокращения XPath. Если вы можете избежать этого, во что бы то ни стало, сделайте это & ​​mdash; частично потому, что он потенциально выбирает узлы, которые вам не нужны, и главным образом потому, что он медленнее, чем более конкретное выражение XPath. Например, если ваш документ выглядит так:

<containers>
  <container><!-- ... --></container>
  <container><!-- ... --></container>
  <container><!-- ... --></container>
</containers>

тогда вы должны использовать "/containers/container" или "/*/container" вместо "//container".

---

РЕДАКТИРОВАТЬ # 3: Альтернативный синтаксис вышеупомянутого будет:

<xsl:stylesheet 
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:output method="text" />

  <xsl:key name="ContainerGroupByVal" match="container" use="val" />

  <xsl:variable name="ContainerGroupFirstLast" select="//container[
    count(
        .
      | key('ContainerGroupByVal', val)[1]
      | key('ContainerGroupByVal', val)[last()]
    ) = 2
  ]" />

  <xsl:template match="/">
    <xsl:for-each select="$ContainerGroupFirstLast">
      <xsl:value-of select="val" />
      <xsl:text> - </xsl:text>
      <xsl:value-of select="id" />
      <xsl:value-of select="'&#10;'" /><!-- LF -->
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

Объяснение: Оператор объединения XPath "|" объединяет свои аргументы в набор узлов. По определению набор узлов не может содержать дубликаты узлов & mdash; например: «. | . | .» создаст набор узлов, содержащий ровно один узел (текущий узел).

Это означает, что если мы создадим набор узлов объединения из текущего узла ("."), Узла "key(…)[1]" и узла "key(…)[last()]", его число будет равно 2, если (и только если) текущий узел равен одному из двух других узлов, во всех остальных случаях количество будет равно 3.

Answer 2

I. XSLT 1,0

По сути, такое же решение, как и у Tomalak, но более понятное Кроме того, оно завершено, поэтому вам нужно только скопировать и вставить документ XML и преобразование, а затем просто нажать " Transform "кнопка вашей любимой XSLT IDE :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

    <xsl:key name="kContByVal" match="container"
     use="val"/>

    <xsl:template match="/*">
      <xsl:for-each select=
       "container[generate-id()
                 =
                  generate-id(key('kContByVal',val)[1])
                 ]
       ">

       <xsl:variable name="vthisvalGroup"
        select="key('kContByVal', val)"/>

       <xsl:value-of select=
        "concat($vthisvalGroup[1]/val,
              '-',
              $vthisvalGroup[1]/id,
              '&#xA;'
              )
      "/>
       <xsl:value-of select=
        "concat($vthisvalGroup[last()]/val,
              '-',
              $vthisvalGroup[last()]/id,
              '&#xA;'
              )
        "/>
      </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к первоначально предоставленному документу XML (отредактирован, чтобы быть правильно сформированным):

<t>
    <container>
        <val>2</val>
        <id>1</id>
    </container>
    <container>
        <val>2</val>
        <id>2</id>
    </container>
    <container>
        <val>2</val>
        <id>3</id>
    </container>
    <container>
        <val>4</val>
        <id>1</id>
    </container>
    <container>
        <val>4</val>
        <id>2</id>
    </container>
    <container>
        <val>4</val>
        <id>3</id>
    </container>
</t>

желаемый результат получен :

2-1
2-3
4-1
4-3

Обратите внимание :

1. Мы используем метод Мюнхена для группировки , чтобы найти один элемент container для каждого набора таких элементов, имеющих одинаковое значение для val.
2. Из всего списка узлов container элементов с одинаковым значением val мы выводим необходимые данные для первого container элемента в группе и для последнего container элемент в группе.

II. XSLT 2.0

Это преобразование :

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output method="text"/>

    <xsl:template match="/*">
      <xsl:for-each-group select="container"
           group-by="val">
        <xsl:for-each select="current-group()[1], current-group()[last()]">
          <xsl:value-of select=
           "concat(val, '-', id, '&#xA;')"/>
        </xsl:for-each>
    </xsl:for-each-group>
    </xsl:template>
</xsl:stylesheet>

при применении к тому же XML-документу, что и выше, приводит к желаемому результату :

2-1
2-3
4-1
4-3

Обратите внимание :

1. Использование инструкции <xsl:for-each-group> XSLT.

2. Использование функции current-group().

Answer 3

Basic XPath :

//container[position() = 1]  <- this is the first one
//container[position() = last()]  <- this is the last one

Вот набор функций XPath более подробно.