Использование XSLT для перевода файла XML - PullRequest
Новая
       1

Использование XSLT для перевода файла XML

5 голосов
/ 26 ноября 2011

Я хочу перевести данный XML-файл (это грамматика RelaxNG) на другие языки через XSLT. Предположим, XML-файл: 

<?xml version="1.0" encoding="UTF-8"?>
<grammar>
  <element name="table" />
  <element name="chair" />
</grammar>

Теперь я думал о том, чтобы иметь таблицу стилей XSLT с такой информацией, как 

en=table, de=Tisch, fr=table
en=chair, de=Stuhl, fr=chaise
...  (there will be many, many more entries)

Но я мог бы также поместить эту информацию во внешний файл (я начинаю с нуля). Можете ли вы дать мне совет, как сформулировать XSLT? Я думал об использовании <xsl:key> для этого, но я никогда не привык к ключам в XSLT. Результат должен выглядеть следующим образом, когда я создаю перевод на немецкий язык: 

<?xml version="1.0" encoding="UTF-8"?>
<grammar lang="de">
  <element name="Tisch" />
  <element name="Stuhl" />
</grammar>

1 Ответ

6 голосов
/ 26 ноября 2011

Это преобразование : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pFrom" select="'en'"/>
 <xsl:param name="pTo" select="'de'"/>

 <xsl:key name="kIdByLangVal" match="@dId"
  use="concat(../../@lang, '+', ../@value)"/>

 <xsl:key name="kValByLangId" match="@value"
  use="concat(../../@lang, '+', ../@dId)"/>

 <xsl:variable name="vDicts" select=
  "document('file:///c:/temp/delete/dicts.xml')"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="@name">
  <xsl:variable name="vCur" select="."/>

  <xsl:attribute name="name">
   <xsl:for-each select="$vDicts">
    <xsl:value-of select=
     "key('kValByLangId',
          concat($pTo, '+',
                key('kIdByLangVal',
                    concat($pFrom, '+', $vCur)
                   )
                 )
        )
     "/>
   </xsl:for-each>
  </xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML : 

<grammar>
    <element name="table" />
    <element name="chair" />
</grammar>

и имеющемуфайл C:\temp\delete\dicts.xml как : 

<dictionaries>
 <dictionary lang="en">
  <word dId="1" value="table"/>
  <word dId="2" value="chair"/>
 </dictionary>
 <dictionary lang="de">
  <word dId="1" value="Tisch"/>
  <word dId="2" value="Stuhl"/>
 </dictionary>
</dictionaries>

дает желаемый, правильный результат : 

<grammar>
   <element name="Tisch"/>
   <element name="Stuhl"/>
</grammar>
...