VBScript - не знаю, почему мои аргументы не используются так же, как переменные - PullRequest
Новая
       17

VBScript - не знаю, почему мои аргументы не используются так же, как переменные

2 голосов
/ 20 мая 2009

Я написал VBScript для перечисления событий из журнала событий в определенный день.

Первый запрос на выбор из событий журнала событий NT между сегодняшней датой и вчерашней датой, 

Set colEvents = objWMIService.ExecQuery _
    ("Select * from Win32_NTLogEvent Where TimeWritten >= '" _ 
        & dtmStartDate & "' and TimeWritten < '" & dtmEndDate & "'")

Затем из приведенного выше запроса я хочу извлечь идентификаторы событий из файла журнала. 

For Each objEvent in colEvents
    If objEvent.Eventcode = EventNu And (objEvent.LogFile = EventLog) Then

Я поместил следующее в скрипт, и он работает, однако я хочу вместо этого использовать аргументы через командную строку (т.е. EventLogCheck.vbs EventNumber LogFile), но если я использую аргументы secion сценария, никакие элементы не возвращаются. Это сводит меня с ума. Полный скрипт ниже использует переменные, я закомментировал раздел аргументов, но вы можете раскомментировать их и поэкспериментировать с ними. Что я делаю неправильно? Спасибо за любую помощь! 

Const CONVERT_TO_LOCAL_TIME = True
Dim EventLog

EventNu = 18
EventLog = "System"

'Input from the command line
'If Wscript.Arguments.Count <= 1 Then
'   Wscript.Echo "Usage: EventLogCheck.vbs EventNumber LogFile"
'   Wscript.Quit
'End If

'EventNu = WScript.Arguments.Item(0)
'EventLog = WScript.Arguments.Item(1)

'For Each Computer In Wscript.Arguments

Set dtmStartDate = CreateObject("WbemScripting.SWbemDateTime")
Set dtmEndDate = CreateObject("WbemScripting.SWbemDateTime")
'DateToCheck = CDate("5/18/2009")
DateToCheck = date
dtmStartDate.SetVarDate DateToCheck, CONVERT_TO_LOCAL_TIME
dtmEndDate.SetVarDate DateToCheck + 1, CONVERT_TO_LOCAL_TIME

strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colEvents = objWMIService.ExecQuery _
    ("Select * from Win32_NTLogEvent Where TimeWritten >= '" _ 
        & dtmStartDate & "' and TimeWritten < '" & dtmEndDate & "'") 

For Each objEvent in colEvents
 If objEvent.Eventcode = EventNu And (objEvent.LogFile = EventLog) Then
    'Wscript.Echo "Category: " & objEvent.Category
    Wscript.Echo "Computer Name: " & objEvent.ComputerName
    Wscript.Echo "Event Code: " & objEvent.EventCode
    Wscript.Echo "Message: " & objEvent.Message
   ' Wscript.Echo "Record Number: " & objEvent.RecordNumber
   ' Wscript.Echo "Source Name: " & objEvent.SourceName
    Wscript.Echo "Time Written: " & objEvent.TimeWritten
    Wscript.Echo "Event Type: " & objEvent.Type
   ' Wscript.Echo "User: " & objEvent.User
    Wscript.Echo objEvent.LogFile
   End if
Next
'Next
WScript.Echo EventNu
WScript.Echo EventLog

1 Ответ

3 голосов
/ 20 мая 2009

Переданные аргументы обрабатываются как строки типа. Однако EventNu должен быть целым числом. Поэтому вам необходимо преобразовать аргументы в правильный тип, используя CInt и CStr: 

EventNu = CInt(WScript.Arguments.Item(0))
EventLog = CStr(WScript.Arguments.Item(1))
...