как изменить нумерацию отфильтрованных элементов в наборе результатов

Question

XML:

<?xml version="1.0" encoding="utf-8"?>
<book>
    <chapter>
        <section name="a">...</section>
        <section name="b">...</section>
        <section name="c">...</section>
        <section name="d">...</section>
        <section name="e">...</section>
        ...
    </chapter>
    <appendix>
        <section name="reference">...</section>
    </appendix>
</book>

Привет, я хочу вывести все sections в узлы chapter и appendix. Разделы под приложением будут распечатаны однозначно. Но не всем разделам в главе разрешено распечатывать , они зависят от некоторых внешних условий (если имя раздела находится в списке разрешенных, переданном из Java-приложения).

Также sections в chapter должен выводиться с правильным порядковым номером перед именем секции , которое выглядит следующим образом:

Желаемый результат

1. b ...
2. д ...

(что означает, что секции a, c, e отфильтрованы)

У меня вопрос, как я могу получить желаемый результат для //chapter/section? Любые советы или помощь высоко ценится

Мой XSL:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:ex="http://example.com/namespace" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <xsl:param name="validChapters" />

    <xsl:function name="ex:isValidChapter" as="xs:boolean">
        <xsl:param name="str-in" as="xs:string"/>
        <xsl:choose>
            <xsl:when test="contains($validChapters, $str-in)">
                <xsl:sequence select="true()" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:sequence select="false()" />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:function>

    <xsl:template match="/">
        <xsl:apply-templates select="chapter" />
        <xsl:apply-templates select="appendix" />
    </xsl:template>

    <xsl:template match="chapter">
        ...
        <xsl:apply-templates select="section" />
    </xsl:template>

    <xsl:template match="appendix">
        ...
        <xsl:apply-templates select="section" />
    </xsl:template>

    <xsl:template match="section">
        ...
        <xsl:apply-templates />
    </xsl:template>

    <xsl:template match="//chapter/section">
        <xsl:if test="ex:isValidChapter(@name)">
            <fo:block>
                <xsl:number format="1."/>
                <xsl:value-of select="@name" />
            </fo:block>
            <xsl:apply-templates />
        </xsl:if>
    </xsl:template>

    ...
</xsl:stylesheet>

Answer 1

Ответ заключается в простом предоставлении атрибута count= вашей инструкции <xsl:number>:

        <xsl:number format="1." count="section[ex:isValidChapter(@name)]"/>

Таким образом, при нумерации разделов будут учитываться только «действительные» разделы, поэтому нумерациябудет правильным.

Также обратите внимание, что вам нужно изменить свой шаблон, который говорит:

<xsl:template match="/">
    <xsl:apply-templates select="chapter" />

, поскольку <chapter> не является дочерним элементом корневого узла.(Это дочерний элемент элемента документа, <book>.) Например,

<xsl:template match="/book">
    <xsl:apply-templates select="chapter" />

Кроме того, ваша функция не нуждается в выборе / когда / в противном случае для преобразования логического результата в логический.Его можно сократить до:

<xsl:function name="ex:isValidChapter" as="xs:boolean">
   <xsl:param name="str-in" as="xs:string"/>
   <xsl:sequence select="contains($validChapters, $str-in)"/>
</xsl:function>