Обновление кода VB6 с Outlook 2007 до Outlook 2010

Question

Мы хотим обновить наш код VB6 для использования Outlook 2010, но мы получаем следующую ошибку: Active x cannot create object

Это наш текущий код:

Public Sub SendEmail()

  Set emailOutlookApp = CreateObject("Outlook.Application.12")

  Set emailNameSpace = emailOutlookApp.GetNamespace("MAPI")
  Set emailFolder = emailNameSpace.GetDefaultFolder(olFolderInbox)

  Set emailItem = emailOutlookApp.CreateItem(olMailItem)
  Set EmailRecipient = emailItem.Recipients
  EmailRecipient.Add (EmailAddress)
  EmailRecipient.Add (EmailAddress2)

  emailItem.Importance = olImportanceHigh
  emailItem.Subject = "My Subject"
  emailItem.Body = "The Body"

'-----Send the Email-----'
  emailItem.Save
  emailItem.Send

'-----Clear out the memory space held by variables-----'
  Set emailNameSpace = Nothing
  Set emailFolder = Nothing
  Set emailItem = Nothing
  Set emailOutlookApp = Nothing
Exit Sub

Я не уверен, что "Outlook.Application.12" правильно. Но я не могу найти однозначного ответа на этот вопрос.

Answer 1

Для Outlook 2010 это определенно ядро ​​Outlook.Application.14. Но я не знаю, что насчет офиса 2007. Я думаю, что это Outlook.Application.12, а для более низких версий это просто "Outlook.Application".

Answer 2

Вот код, на который я переключился на 2010 год:

Private Sub EmailBlahbutton_Click()

Dim mOutlookApp As Object
Dim OutMail As Object
Dim Intro As String

On Error GoTo ErrorHandler

Set mOutlookApp = GetObject("", "Outlook.application")
Set OutMail = mOutlookApp.CreateItem(0)

With Application
    .EnableEvents = False
    .ScreenUpdating = False
End With

'These are the ranges being emailed.
ActiveSheet.Range(blahblahblah).Select

'Intro is the first line of the email
Intro = "BLAHBLAHBLHA"

'Set the To and Subject lines.  Send the message.
With OutMail
    .To = "blahblah@blah.com"
    .Subject = "More BLAH here"
    .HTMLBody = Intro & RangetoHTML(Selection)
    .Send
End With

With Application
    .EnableEvents = True
    .ScreenUpdating = True
End With

ActiveSheet.Range("A1").Select
ActiveWindow.ScrollColumn = ActiveCell.Column
ActiveWindow.ScrollRow = ActiveCell.Row

Set OutMail = Nothing
Set mOutlookApp = Nothing

Exit Sub

ErrorHandler:
    Set mOutlookApp = CreateObject("Outlook.application")
    Resume Next

End Sub

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2010
Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook

TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

'Copy the range and create a new workbook to past the data in
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
  .Cells(1).PasteSpecial Paste:=8
  .Cells(1).PasteSpecial xlPasteValues, , False, False
  .Cells(1).PasteSpecial xlPasteFormats, , False, False
  .Cells(1).Select
  Application.CutCopyMode = False
  On Error Resume Next
  .DrawingObjects.Visible = True
  .DrawingObjects.Delete
  On Error GoTo 0
End With

'Publish the sheet to a htm file
With TempWB.PublishObjects.Add( _
  SourceType:=xlSourceRange, _
  Filename:=TempFile, _
  Sheet:=TempWB.Sheets(1).Name, _
  Source:=TempWB.Sheets(1).UsedRange.address, _
  HtmlType:=xlHtmlStatic)
  .Publish (True)
End With

'Read all data from the htm file into RangetoHTML
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.ReadAll
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                      "align=left x:publishsource=")

'Close TempWB
TempWB.Close savechanges:=False

'Delete the htm file we used in this function
Kill TempFile

Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing

End Function

Answer 3

Почему вы явно указываете версию?Почему бы просто не установить emailOutlookApp = CreateObject ("Outlook.Application")

Answer 4

Попробуйте "Outlook.Application.14". Не уверен, если это связано, хотя: проблема обновления с 2007 до 2010

Я понимаю, что это не совсем проблема, но она может привести вас на правильный путь.