Erlang: gen_server падает при запуске поверх супервизора - PullRequest
Новая
       9

Erlang: gen_server падает при запуске поверх супервизора

2 голосов
/ 03 мая 2011

Итак, я потратил МНОГО времени и все еще не нашел ответа.

У меня есть простой tcp сервер в gen_server, который принимает сообщения через telnet и печатает их в консоли: 

-module(st_server).

-behaviour(gen_server).
%% --------------------------------------------------------------------
%% Include files
%% --------------------------------------------------------------------

%% --------------------------------------------------------------------
%% External exports
-export([start_link/0, start_link/1, stop/0]).

%% gen_server callbacks
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).

-define(SERVER, ?MODULE).
-define(DEFAULT_PORT, 1055).

-record(state, {lsock, port}).

%% ====================================================================
%% External functions
%% ====================================================================

%%--------------------------------------------------------------------
%% @doc Starts the server.
%%
%% @spec start_link(Port::integer()) -> {ok, Pid}
%% where
%%  Pid = pid()
%% @end
%%--------------------------------------------------------------------
start_link(Port) ->
    gen_server:start_link({local, ?SERVER}, ?MODULE, [Port], []),
    io:format("Server name: ~w, port: ~w.~n", [?SERVER, Port]).

%% @spec start_link() -> {ok, Pid}
%% @doc Calls `start_link(Port)' using the default port.
start_link() -> start_link(?DEFAULT_PORT).

%%-------------------------------------------------------------------- 
%% @doc Stops the server. 
%% @spec stop() -> ok 
%% @end 
%%-------------------------------------------------------------------- 
stop() ->
    gen_server:cast(?SERVER, stop).

%% ====================================================================
%% Server functions
%% ====================================================================

%% --------------------------------------------------------------------
%% Function: init/1
%% Description: Initiates the server
%% Returns: {ok, State}          |
%%          {ok, State, Timeout} |
%%          ignore               |
%%          {stop, Reason}
%% --------------------------------------------------------------------
init([Port]) ->
    {ok, LSock} = gen_tcp:listen(Port, [{active, true}]),
    {ok, #state{lsock = LSock, port = Port}, 0}.

%% --------------------------------------------------------------------
%% Function: handle_cast/2
%% Description: Handling cast messages
%% Returns: {noreply, State}          |
%%          {noreply, State, Timeout} |
%%          {stop, Reason, State}            (terminate/2 is called)
%% --------------------------------------------------------------------
handle_cast(stop, State) ->
    {stop, normal, State}.

handle_call(_Request, _From, State) ->
    {reply, ok, State}.

%% --------------------------------------------------------------------
%% Function: handle_info/2
%% Description: Handling all non call/cast messages
%% Returns: {noreply, State}          |
%%          {noreply, State, Timeout} |
%%          {stop, Reason, State}            (terminate/2 is called)
%% --------------------------------------------------------------------


handle_info({tcp, _Socket, Data}, State) ->
    io:format("Incoming info: ~s", [Data]),
    {noreply, State};

handle_info({tcp_closed, _Socket}, #state{lsock = LSock} = State) ->
    {ok, _Sock} = gen_tcp:accept(LSock),
    {noreply, State};

handle_info(timeout, #state{lsock = LSock} = State) ->
    {ok, _Sock} = gen_tcp:accept(LSock),
    {noreply, State}.

%% --------------------------------------------------------------------
%% Function: terminate/2
%% Description: Shutdown the server
%% Returns: any (ignored by gen_server)
%% --------------------------------------------------------------------
terminate(Reason, _State) ->
    io:format("~nServer shutdown. Reason: ~s.~n", [Reason]),
    ok.

%% --------------------------------------------------------------------
%% Func: code_change/3
%% Purpose: Convert process state when code is changed
%% Returns: {ok, NewState}
%% --------------------------------------------------------------------
code_change(_OldVsn, _State, _Extra) ->
    {ok, _State}.

%% --------------------------------------------------------------------
%%% Internal functions
%% --------------------------------------------------------------------

И руководитель: 

-module(st_sup).

-behaviour(supervisor).
%% --------------------------------------------------------------------
%% Include files
%% --------------------------------------------------------------------

%% --------------------------------------------------------------------
%% External exports
%% --------------------------------------------------------------------
-export([]).

%% --------------------------------------------------------------------
%% Internal exports
%% --------------------------------------------------------------------
-export([
     init/1,
     start_link/0
        ]).

%% --------------------------------------------------------------------
%% Macros
%% --------------------------------------------------------------------
-define(SERVER, ?MODULE).

%% --------------------------------------------------------------------
%% Records
%% --------------------------------------------------------------------

%% ====================================================================
%% External functions
%% ====================================================================

start_link() ->
    supervisor:start_link({local, ?SERVER}, ?MODULE, []).

%% ====================================================================
%% Server functions
%% ====================================================================
%% --------------------------------------------------------------------
%% Func: init/1
%% Returns: {ok,  {SupFlags,  [ChildSpec]}} |
%%          ignore                          |
%%          {error, Reason}
%% --------------------------------------------------------------------
init([]) ->
    Server = {st_server, {st_server, start_link, []},
                permanent, 2000, worker, [st_server]},
    Children = [Server],
    RestartStrategy = {one_for_one, 0, 1},
    {ok, {RestartStrategy, Children}}.

%% ====================================================================
%% Internal functions
%% ====================================================================

Я запускаю это в консоли erlang: 

st_sup:start_link().

И получите это: 

Server name: st_server, port: 1055.
** exception exit: shutdown

Это означает, что супервизор по какой-то причине отключает сервер. Если я запускаю сервер сам (st_server: start_link.), Он работает просто отлично.

Итак, вопрос в том, как заставить это работать без выключений?

Ответы [ 2 ]

5 голосов
/ 03 мая 2011

На первый взгляд, это вероятно потому, что возвращаемое значение st_server:start_link/1 является возвращаемым значением вызова io:format/2.

Это хорошо, когда вы вызываете st_server:start_link() непосредственно в REPL, носупервизор, вероятно, ожидает возвращаемого значения, более похожего на {ok, Pid}.

. Это можно исправить, просто поменяв две строки в st_server:start_link/1, чтобы он возвращал значение вызова в gen_server:start_link/4: 

start_link(Port) ->    
    io:format("Server name: ~w, port: ~w.~n", [?SERVER, Port]),
    gen_server:start_link({local, ?SERVER}, ?MODULE, [Port], []).
1 голос
/ 04 мая 2011

Странным значением является также RestartStrategy супервизора, для которого установлено значение {one_for_one,0,1}. Это означает, что супервизор сдается после более чем нулевого перезапуска в течение 1 секунды, фактически он сдается после первого сбоя ребенка. Как правило, это не то, что вы хотите от руководителя.

...