Тестирование атрибута файла в пакетном файле - PullRequest
Новая
       11

Тестирование атрибута файла в пакетном файле

9 голосов
/ 20 мая 2009

Я пишу командный файл, и мне нужно знать, доступен ли файл только для чтения. Как я могу это сделать?

Я знаю, как получить их, используя модификатор% ~, но я не знаю, что делать с этим выводом. Это дает что-то вроде -ra ------. Как я могу разобрать это в командном файле?

Ответы [ 2 ]

13 голосов
/ 20 мая 2009

Примерно так должно работать: 

@echo OFF

SETLOCAL enableextensions enabledelayedexpansion

set INPUT=test*

for %%F in (%INPUT%) do (
    set ATTRIBS=%%~aF
    set CURR_FILE=%%~nxF
    set READ_ATTRIB=!ATTRIBS:~1,1!

    @echo File: !CURR_FILE!
    @echo Attributes: !ATTRIBS!
    @echo Read attribute set to: !READ_ATTRIB!

    if !READ_ATTRIB!==- (
        @echo !CURR_FILE! is read-write
    ) else (
        @echo !CURR_FILE! is read only
    )

    @echo.
)

Когда я запускаю это, я получаю следующий вывод: 

File: test.bat
Attributes: --a------
Read attribute set to: -
test.bat is read-write

File: test.sql
Attributes: -ra------
Read attribute set to: r
test.sql is read only

File: test.vbs
Attributes: --a------
Read attribute set to: -
test.vbs is read-write

File: teststring.txt
Attributes: --a------
Read attribute set to: -
teststring.txt is read-write
7 голосов
/ 08 декабря 2014

Для проверки конкретного файла: 

dir /ar yourFile.ext >nul 2>nul && echo file is read only || echo file is NOT read only

Чтобы получить список файлов только для чтения 

dir /ar *

Чтобы получить список файлов для чтения / записи 

dir /a-r *

Чтобы вывести список всех файлов и сообщить, доступны ли они только для чтения или для чтения / записи: 

for %%F in (*) do dir /ar "%%F" >nul 2>nul && echo Read Only:  %%F|| echo Read/Write: %%F

EDIT

Ответ Патрика не удастся, если имя файла содержит !. Эту проблему можно решить, включив и выключив отложенное расширение в цикле, но есть и другой способ проверить значение %%~aF без обращения к отложенному расширению или даже к переменной среды: 

for %%F in (*) do for /f "tokens=1,2 delims=a" %%A in ("%%~aF") do (
  if "%%B" equ "" (
    echo "%%F" is NOT read only
  ) else (
    echo "%%F" is read only
  )
)
...