Vbscript найти .apk и импортировать перспективы - PullRequest
Новая
       10

Vbscript найти .apk и импортировать перспективы

0 голосов
/ 19 сентября 2011

Я написал скрипт, который может найти .apk и автоматически импортировать в outlook.

Но у меня есть проблема. я могу установить 4 пути к папке. И скрипт посмотри путь к папкам и найди апк.

Но когда этот скрипт может найти папки .apk, программа завершает работу.

Этот скрипт не выглядит по другому пути. 

On Error Resume Next
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set objnet = CreateObject("wscript.network")
    Set olkApp = CreateObject("Outlook.Application") 
    Set objFolder = objFSO.GetFolder("C:\Documents and Settings\" & objnet.UserName & "\")
    Set objFolder = objFSO.GetFolder("C:\Documents and Settings\" & objnet.UserName & "\Local Settings\Application Data\Microsoft\Outlook")
    Set objFolder = objFSO.GetFolder("C:\Documents and Settings\" & objnet.UserName & "\Belgelerim\mail")
    Set objFolder = objFSO.GetFolder("C:\Documents and Settings\" & objnet.UserName & "\AppData\Local\Microsoft\Outlook")
    Set objFolder = objFSO.GetFolder("C:\Documents and Settings\" & objnet.UserName & "\Belgelerim\mailbox")
     For Each objFile in objFolder
         If LCase(objFSO.GetExtensionName(objFile.Name)) = "pst" Then
            olkApp.Session.AddStore objFile.Path
     End If
Next
MsgBox "Done"

Например, этот скрипт находит путь к папке .apk 

(Set objFolder = objFSO.GetFolder("C:\Documents and Settings\" & objnet.UserName & "\"))

И не смотрит другими путями.

Как решить эту проблему.

Спасибо за любую помощь.

1 Ответ

1 голос
/ 19 сентября 2011

Do никогда используйте On Error Resume Next для управления потоком программы. Это глупо. Проверьте на наличие предсказуемых ошибок, вместо того, чтобы позволять им отказывать. 

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objnet = CreateObject("WScript.Network")
Set olkApp = CreateObject("Outlook.Application") 

paths = Array( _
  "C:\Documents and Settings\" & objnet.UserName & "\", _
  "C:\Documents and Settings\" & objnet.UserName & "\Local Settings\Application Data\Microsoft\Outlook", _
  "C:\Documents and Settings\" & objnet.UserName & "\Belgelerim\mail", _
  "C:\Documents and Settings\" & objnet.UserName & "\AppData\Local\Microsoft\Outlook", _
  "C:\Documents and Settings\" & objnet.UserName & "\Belgelerim\mailbox" _
)

For Each path In paths
   If objFSO.FolderExists(path) Then
       For Each objFile in objFSO.GetFolder(path).Files
           If LCase(objFSO.GetExtensionName(objFile.Name)) = "pst" Then
                olkApp.Session.AddStore objFile.Path
           End If
       Next
   End If
Next

MsgBox "Done"
...