Как эта таблица стилей может производить вывод HTML - PullRequest
Новая
       0

Как эта таблица стилей может производить вывод HTML

0 голосов
/ 08 января 2012

Как заполнить следующую таблицу стилей, которая должна выводить HTML на рисунке 1.

Я стилизовал некоторую ее часть, но не смог сделать ее точно такой же, как на рисунке 1. Я попытался "скопировать"элемент "в XSL, но дал мне повторяющиеся результаты.

Это мой XML: 

<?xml version="1.0"?> 
<?xml-stylesheet type="text/xsl" href="research.xsl"?> 
<ResearchGroups xmlns="http://www.sam.com/sam.html"> 

<Group name="Intelligent Systems Group" id="ISG"> The Intelligent 
Systems Group pursues internationally-leading research in a wide 
range of intelligent systems. </Group> 

<Group name="Robotics" id="RBT"> The Essex robotics group is one of 
the largest mobile robotics groups in the UK. </Group> 

<Staff name="Callaghan, Vic" title="Professor" groups="ISG RBT"> 
Intelligent environments and robotics. </Staff> 
<Staff name="Gu, Dongbing" title="Dr" groups="RBT"> Multi-agent 
and distributed control systems. </Staff> 
</ResearchGroups>

Мой XSLT: 

    <xsl:stylesheet  
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
        xmlns:rg="http://www.sam.com/sam.html"  
        xmlns="http://wwww.w3.org/1999/xhtml"  
        version="2.0">    <xsl:template match="/"> 
        <html>    
          <head> <title>Research Groups</title> </head> 
          <body> <xsl:apply-templates select="//rg:Group"/> </body>  
        </html>      </xsl:template>    <xsl:template match="rg:Group"> 
        <xsl:variable name="ID" select="@id"/>  
        <h3> <a name="{$ID}"> <xsl:value-of select="@name"/> </a> </h3>  
        <p> <xsl:value-of select="text()"/>  </p>     
</xsl:template>  
</xsl:stylesheet>

HTML Рисунок 1

таблица стилей XSLT должна вывести следующий HTML

enter image description here

1 Ответ

1 голос
/ 08 января 2012

Как-то так я думаю: 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:rg="http://www.sam.com/sam.html" xmlns="http://wwww.w3.org/1999/xhtml" version="2.0">
    <xsl:template match="/">
        <html>
            <head>
                <title>Research Groups</title>
            </head>
            <body>
                <xsl:apply-templates select="//rg:Group"/>
            </body>
        </html>
    </xsl:template>
    <xsl:template match="rg:Group">
        <xsl:variable name="ID" select="@id"/>
        <h3>
            <a name="{$ID}">
                <xsl:value-of select="@name"/>
            </a>
        </h3>
        <p>
            <xsl:value-of select="text()"/>
        </p>
        <ul>
            <xsl:apply-templates select="//rg:Staff[contains(@groups, current()/@id)]">
                <xsl:with-param name="curGroup"><xsl:value-of select="@id"/></xsl:with-param>
            </xsl:apply-templates>
        </ul>
    </xsl:template>
    <xsl:template match="rg:Staff">
        <xsl:param name="curGroup"/>
        <li>
            <xsl:value-of select="@name"/>
            <xsl:text>: </xsl:text>
            <xsl:value-of select="text()"/>
            <xsl:if test="//rg:Group[(@id != $curGroup) and contains(current()/@groups, @id)]">
                <xsl:text> ( </xsl:text>
                <xsl:apply-templates select="//rg:Group[(@id != $curGroup) and contains(current()/@groups, @id)]" mode="otherGroups"/>
                <xsl:text> ) </xsl:text>
            </xsl:if>
        </li>
    </xsl:template>
    <xsl:template match="rg:Group" mode="otherGroups">
        <a href="#{@id}">
            <xsl:value-of select="@id"/>    
        </a>
    </xsl:template>
</xsl:stylesheet>
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...