Гото было неожиданным в это время пакетной Windows 7 Starter

Question

Этот код разработан для того, чтобы напоминать более простую версию игрового процесса про покемонов.Я только закодировал в атаках.Я провел тщательное тестирование и обнаружил сообщение об ошибке (в то время Goto было неожиданным), когда пользователь подтвердил свою атаку.ПРЕДУПРЕЖДЕНИЕ!!Код длиной 96 строк.В конце я поставлю проблемный раздел, чтобы вы могли пропустить этот первый огромный кусок.

@echo off
Set H1=20
Set A1=8
Set D1=6
Set S1=5
Set H2=14
Set A2=5
Set D2=4
Set S2=8
:Begin
CLS
Echo Bulbasur
Echo %H2%/14      /\       
Echo           (__) ___  
Echo           l __lo.ol 
Echo           l_\ l_\"  
Echo.        
Echo     _ 
Echo *  / \ 
Echo \\l  )
Echo  \\__l   Charmander
Echo             %H1%/20
Echo -Attack -Capture
Echo -Item   -Run 
Set /p Move=Action?
If %move%==Attack goto Attack
If %move%==Catpure goto capture
If %move%==Item goto Item
If %move%==Run Goto Run
Echo I'm sorry, Charmander can't do that. 
Pause
goto Begin
:Attack
ClS
Echo Attacks
Echo 1)Tackle
Echo 2)Growl
Echo 3)Ember
Echo 4)Scratch
Set /p attack=Which one?
If %attack%==Tackle goto Tackle
If %attack%==1 goto Tackle
If %attack%==Growl Goto Growl
If %attack%==2 goto Growl
If %attack%==Ember goto Ember
If %attack%==3 goto Ember
If %attack%==Scratch goto Scratch
If %attack%==4 goto Scratch
If %attack%==Cancel goto Begin
Echo I didn't get that
Goto Attack
:Tackle
CLS
Echo Tackle Hits The opponent where it hurts. EVERYWHERE.
Echo Do you want to?
set /p accept=Yes/No?
If %acccept%==Yes goto Combat
If %acccept%==No goto Begin
Echo I didn't get that.
goto Tackle 
:Growl
CLS
Echo Growl lowers the opponents attack.
Echo Do you want to?
set /p accept=Yes/No?
If %acccept%==Yes goto Status
If %acccept%==No goto Begin
Echo I didn't get that.
goto Growl
:Scratch
CLS
Echo Scratch hits the foe with a claw.
Echo Do you want to?
set /p accept=Yes/No?
If %acccept%==Yes goto Combat
If %acccept%==No goto Begin
Echo I didn't get that.
goto  Scratch
:Ember
CLS
Echo Ember hits the opponent with a small fire.
Echo Do you want to?
set /p accept=Yes/No?
If %acccept%==Yes goto Combat
If %acccept%==No goto Begin
Echo I didn't get that.
goto Ember
:Combat
CLS
If NOT %attack%==Growl If NOT %attack%==2 set /a H2=%H2%-(%A1%^2/%D2%)
set /a H1=%H1%-(%A2%^2/%D1%)
goto Begin
:Status
CLS
Set /a A1=%A1%-1
goto Combat

Проблемная область:

:Tackle
CLS
Echo Tackle Hits The opponent where it hurts. EVERYWHERE.
Echo Do you want to?
set /p accept=Yes/No?
If %acccept%==Yes goto Combat
If %acccept%==No goto Begin
Echo I didn't get that.
goto Tackle 

Код получается здесь хорошо, но один разЯ здесь, он не ожидает команды goto.Кто-нибудь может исправить эту говядину?(Примечание. Снасть - всего лишь пример. Ни одна из атак не работает.) РЕДАКТИРОВАТЬ: если пользователь вводит «Да», «Нет», бред или ничего, он по-прежнему выдает то же сообщение об ошибке (переход был неожиданным в это время)

Answer 1

Вы должны поставить его в кавычки:

if "%accept%"=="yes" goto combat
if "%accept%"=="no" goto begin

Вернее, если вы не хотите, чтобы оно чувствительно к регистру:

if /i "%accept%"=="yes" goto combat
if /i "%accept%"=="no" goto begin

Answer 2

Ваша проблема в том, что эта строка:

set /p accept=Yes/No?

НЕ использует то же имя переменной, что и эти:

If %acccept%==Yes goto Combat
If %acccept%==No goto Begin

Выше переменных есть "ccc", но перваяпросто "cc"

EDIT

Привет, user1205760;У меня есть время, чтобы потратить, поэтому я взял вашу программу и сделал ее несколько меньше.Это моя версия:

@echo off

Setlocal EnableDelayedExpansion
Set Actions=Attack Capture Item Run
Set Attacks=Tackle Growl Ember Scratch Cancel
Set i=0
For %%a in (%Attacks%) do set /A i+=1 & set Attack[!i!]=%%a

Set H1=20
Set A1=8
Set D1=6
Set S1=5
Set H2=14
Set A2=5
Set D2=4
Set S2=8

:Begin
:Cancel
CLS
Echo Bulbasur
Echo %H2%/14      /\       
Echo           (__) ___  
Echo           l __lo.ol 
Echo           l_\ l_\"  
Echo.        
Echo     _ 
Echo *  / \ 
Echo \\l  )
Echo  \\__l   Charmander
Echo             %H1%/20
Echo -Attack -Capture
Echo -Item   -Run 
Set /p Move=Action? 
For %%a in (%Actions%) do if /I %move%==%%a goto %move%
Echo I'm sorry, Charmander can't do that. 
Pause
goto Begin

:Attack
Cls
Echo Attacks
For %%a in (1 2 3 4) do echo %%a)!Attack[%%a]!
Set /p attack=Which one? 
for %%a in (1 2 3 4) do if %attack%==%%a set attack=!Attack[%%a]!
for %%a in (%Attacks%) do if /I %attack%==%%a goto %attack%
Echo I didn't get that
Pause
Goto Attack

:Tackle
call :Confirm Tackle Hits The opponent where it hurts. EVERYWHERE.
If %accept%==Yes goto Combat
goto Begin

:Growl
call :Confirm Growl lowers the opponents attack.
If %accept%==Yes goto Status
goto Begin

:Ember
call :Confirm Ember hits the opponent with a small fire.
If %accept%==Yes goto Combat
goto Begin

:Scratch
call :Confirm Scratch hits the foe with a claw.
If %accept%==Yes goto Combat
goto Begin

:Status
Set /A A1-=1
:Combat
If /I NOT %attack%==Growl set /A H2=H2-(A1^2/D2)
set /A H1=H1-(A2^2/D1)
goto Begin

:Confirm 
Cls
Echo %*
Echo Do you want to?
set /p accept=Yes/No? 
For %%a in (Yes No) do if /I %accept%==%%a exit /B
Echo I didn't get that.
Pause
goto Confirm

Answer 3

Если пользователь ничего не вводит, ваши строки If, вероятно, оцениваются примерно так:

…
If ==Yes goto Combat
If ==No goto Begin
…

, что синтаксически неверно.Я бы предложил инициализировать accept перед командой set /p с некоторым значением по умолчанию:

…
set accept=default
set /p accept=Yes/No?
if …

Таким образом, если пользователь просто нажмет Enter, переменная accept сохранит значение default,и последующий if не приведет к ошибке.

Answer 4

Извините,
Это просто вопрос к отрицательным голосам.
Люди, которые спрашивают просто НЕ УВЕРЕН, проблема должна быть в ЭТОЙ ЧАСТИ.

, например

set a=
if %a%==1 echo yes

Если я просто отправлю эту строку:

if %a%==1 echo yes

Тогда КАЖДЫЙ ЗНАЕТ, ЧТО ТАКОЕ ПРОБЛЕМА?

---

Запомните для переменной, например% abc%, лучше использовать ее с ", [или {, чтобы предотвратить сообщение об ошибке.

---

например.

set /p abc=

и пользователь ничего не вводит.
Тогда следующая строка должна быть:

if %abc%==1 echo Hi

Но стало:

if ==1 echo Hi

, как "% abc%" == ""
Но с "" оно станет

if ""=="1" echo Hi

И "" не равно "1".
Понял?

---

EDIT ---

Если вы используете Windows 7 (или другие версии), вы также можете попробовать это:

choice /c YN /n /m "Confirm? [Y^|N]

^ просто выходит из "трубы" (|).

Надеюсь, это будет вам полезно!