Как определить, физически ли машина имеет последовательный порт?

Question

Я мог бы попытаться открыть его, но если он используется другой программой, я получу сообщение об ошибке, и мне нужно будет уметь отличить этот случай от случая, когда у машины физически нет последовательного порта.

Есть идеи?

Answer 1

Просто для дополнения ответа Serg, класс Win32_SerialPort, используемый в этой статье , сообщает о физических com-портах, если вы хотите перечислить все последовательные порты, включая USB-Serial/COMпорты, вы должны использовать класс MSSerial_PortName, расположенный в пространстве имен root\wmi.

uses
  SysUtils,
  ActiveX,
  ComObj,
  Variants;

// Serial Port Name

procedure  GetMSSerial_PortNameInfo;
const
  wbemFlagForwardOnly = $00000020;
var
  FSWbemLocator : OLEVariant;
  FWMIService   : OLEVariant;
  FWbemObjectSet: OLEVariant;
  FWbemObject   : OLEVariant;
  oEnum         : IEnumvariant;
  iValue        : LongWord;
begin;
  FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  FWMIService   := FSWbemLocator.ConnectServer('localhost', 'root\WMI', '', '');
  FWbemObjectSet:= FWMIService.ExecQuery('SELECT * FROM MSSerial_PortName','WQL',wbemFlagForwardOnly);
  oEnum         := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
  while oEnum.Next(1, FWbemObject, iValue) = 0 do
  begin
    Writeln(Format('Active          %s',[FWbemObject.Active]));// Boolean
    Writeln(Format('InstanceName    %s',[FWbemObject.InstanceName]));// String
    Writeln(Format('PortName        %s',[FWbemObject.PortName]));// String

    Writeln('');
    FWbemObject:=Unassigned;
  end;
end;


begin
 try
    CoInitialize(nil);
    try
      GetMSSerial_PortNameInfo;
      Readln;
    finally
    CoUninitialize;
    end;
 except
    on E:Exception do
    begin
        Writeln(E.Classname, ':', E.Message);
        Readln;
    end;
  end;
end.

для получения дополнительной информации о последовательных портах попробуйте классы, расположенные в том же пространстве имен

• MSSerial_CommInfo
• MSSerial_CommProperties
• MSSerial_HardwareConfiguration
• MSSerial_PerformanceInformation

Answer 2

Вы можете использовать WMI.Взгляните на мой старый пост

Answer 3

Вы также можете прочитать из реестра:
Перечисление списка Com-портов систем в Delphi