XSLT чтение / изменение дерева результатов при создании

Question

Я пытаюсь создать список элементов в переменной и хочу проверить, есть ли элемент в списке или нет. Элементы даны входным документом, который не очень важен для моего вопроса.

Итак, я пытаюсь решить две проблемы.

1: чтение данных из переменной, которую я сейчас генерирую

2: добавить текст к узлу в переменной

Вот что я пробовал до сих пор:

<xsl:variable name="data">
    <list>
        <xsl:call-template name="generate"/>
    </list>
</xsl:variable>


<xsl:template name="generate" match="/">
    <xsl:apply-templates select="//thing"/>
</xsl:template>


<xsl:template match="//thing">
    <xsl:variable name="temp">
        <xsl:value-of select="./text()"/>
    </xsl:variable>

    <xsl:choose>
        <!-- test however this thing is already in $data -->
        <!-- problem #1: here, trying to read anything out of $data doesn't work -->
        <xsl:when test="contains($data/list/item/text(), $temp/text())">
            <xsl:for-each select="$data/list/item">
                <xsl:if test="contains(./text(), $temp/text())">
                    <!-- problem #2: append any string to self::node()/text() -->
                </xsl:if>
            </xsl:for-each>
        </xsl:when>
        <xsl:otherwise>
            <item>
                <xsl:value-of name="$temp/text()"/>
            </item>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Я много искал фрагмент дерева результатов и так далее, но не знал, как это сделать.

редактировать: Это должен быть код ввода:

<data>
<thing>string1</thing>
<thing>string2</thing>
<thing>string3</thing>
<nested><thing>string1</thing></nested>
<nested><thing>string1</thing></nested>
<nested><thing>string2</thing></nested>
</data>

выход:

<list>
<item>string1 string1 string1</item>
<item>string2 string2</item>
<item>string3</item>
</list>

Chris

Answer 1

Это мой ответ (независимо от Мартина Хонена), но я понимаю, что он не отвечает на ваш главный вопрос - как пройти по дереву, обрабатывать и накапливать данные, где обработка также использует уже накопленные данные. Я предоставляю это разыскиваемое решение во второй части моего ответа ..

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kThingByVal" match="thing"
  use="."/>

 <xsl:template match="/">
     <list>
      <xsl:apply-templates select=
      "//thing
          [generate-id()
          =
           generate-id(key('kThingByVal', .)[1])
          ]
      ">
      </xsl:apply-templates>
     </list>
 </xsl:template>

 <xsl:template match="thing">
  <item>
   <xsl:apply-templates mode="gen"
        select="key('kThingByVal', .)"/>
  </item>
 </xsl:template>

 <xsl:template match="thing" mode="gen">
  <xsl:if test="not(position() = 1)">
   <xsl:text> </xsl:text>
  </xsl:if>
  <xsl:value-of select="."/>
 </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к предоставленному документу XML :

<data>
    <thing>string1</thing>
    <thing>string2</thing>
    <thing>string3</thing>
    <nested>
        <thing>string1</thing>
    </nested>
    <nested>
        <thing>string1</thing>
    </nested>
    <nested>
        <thing>string2</thing>
    </nested>
</data>

желаемый, правильный результат получается :

<list>
   <item>string1 string1 string1</item>
   <item>string2 string2</item>
   <item>string3</item>
</list>

II. Общее решение класса задач эта проблема попадает в :

Мы хотим, чтобы у нас была возможность обрабатывать деревья так же, как мы обрабатываем списки с помощью таких функций, как f:foldl() из FXSL.

Вот классическое приложение, показывающее, как f:foldl() (в случае XSLT 1.0 это шаблон, а не xsl:function) может обрабатывать любой список с любой функцией, которая принимает текущий накопленный результат, и текущий элемент списка и выдает новый результат:

testFoldl.xsl

<xsl:stylesheet version="1.0"
xmlns:f="http://fxsl.sf.net/"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:foldr-func="foldr-func"
exclude-result-prefixes="xsl f foldr-func"
>

   <xsl:import href="foldl.xsl"/>

   <!-- This transformation must be applied to:
        numList.xml 
     -->
   <foldr-func:foldr-func/>
   <xsl:variable name="vFoldrFun" select="document('')/*/foldr-func:*[1]"/>
    <xsl:output  encoding="UTF-8" omit-xml-declaration="yes"/>

    <xsl:template match="/">

      <xsl:call-template name="foldl">
        <xsl:with-param name="pFunc" select="$vFoldrFun"/>
        <xsl:with-param name="pList" select="/*/*"/>
        <xsl:with-param name="pA0" select="0"/>
      </xsl:call-template>
    </xsl:template>

    <xsl:template mode="f:FXSL"
      match="foldr-func:*">
         <xsl:param name="arg1" select="0"/>
         <xsl:param name="arg2" select="0"/>

         <xsl:value-of select="$arg1 + $arg2"/>
    </xsl:template>

</xsl:stylesheet>

когда это преобразование применяется к этому документу XML (представляет список чисел):

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

желаемый результат (сумма всех элементов списка) получается :

55

Обратите внимание, что если мы передадим в качестве параметра не функцию add(), а функцию mult() (и удалим 0 из списка, укажите новый «нулевой» параметр - 1 - нейтральное число для умножения, мы получим произведение всех элементов списка - 10! (десять факториалов).

Следовательно, f:foldl() - очень мощная функция, которую можно использовать для обработки любых списков, где на основе накопленного результата и текущего элемента списка создается новый результат.

Если вам эта тема кажется интересной, есть еще много интересного здесь .

Интересно, что существует аналогичная функция, которая обрабатывает дерево :

откидные tree2.xsl

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:f="http://fxsl.sf.net/"
 xmlns:msxsl="urn:schemas-microsoft-com:xslt"
 xmlns:ext="http://exslt.org/common"
 exclude-result-prefixes="f ext msxsl xsl"
>
 <xsl:template name="foldl-tree2">
  <xsl:param name="pFuncNode" select="/.."/>
  <xsl:param name="pFuncSubtrees" select="/.."/>
  <xsl:param name="pA0"/>
  <xsl:param name="pNode" select="/.."/>

  <xsl:choose>
   <xsl:when test="not($pNode)">
            <xsl:copy-of select="$pA0"/>
   </xsl:when>

   <xsl:otherwise>
    <xsl:variable name="vSubtrees" select="$pNode/*"/>

    <xsl:variable name="vSubTreeResult">
      <xsl:call-template name="foldl-tree_">
        <xsl:with-param name="pFuncNode" select="$pFuncNode"/>
        <xsl:with-param name="pFuncSubtrees" select="$pFuncSubtrees"/>
        <xsl:with-param name="pA0" select="$pA0"/>
        <xsl:with-param name="pSubTrees" select="$vSubtrees"/>
      </xsl:call-template>
    </xsl:variable>

    <xsl:apply-templates select="$pFuncNode[1]" mode="f:FXSL">
     <xsl:with-param name="arg0" select="$pFuncNode[position() > 1]"/>
     <xsl:with-param name="arg1" select="$pNode"/>
     <xsl:with-param name="arg2" select="ext:node-set($vSubTreeResult)"/>
    </xsl:apply-templates>
   </xsl:otherwise>
  </xsl:choose>
 </xsl:template>

 <xsl:template name="foldl-tree_">
  <xsl:param name="pFuncNode" select="/.."/>
  <xsl:param name="pFuncSubtrees" select="/.."/>
  <xsl:param name="pA0"/>
  <xsl:param name="pSubTrees" select="/.."/>

  <xsl:choose>
   <xsl:when test="not($pSubTrees)">
            <xsl:copy-of select="$pA0"/>
   </xsl:when>
   <xsl:otherwise>
      <xsl:variable name="vSubTree1Result">
        <xsl:call-template name="foldl-tree2">
          <xsl:with-param name="pFuncNode" select="$pFuncNode"/>
          <xsl:with-param name="pFuncSubtrees" select="$pFuncSubtrees"/>
          <xsl:with-param name="pA0" select="$pA0"/>
          <xsl:with-param name="pNode" select="$pSubTrees[1]"/>
        </xsl:call-template>
      </xsl:variable>

      <xsl:variable name="vRestSubtreesResult">
        <xsl:call-template name="foldl-tree_">
          <xsl:with-param name="pFuncNode" select="$pFuncNode"/>
          <xsl:with-param name="pFuncSubtrees" select="$pFuncSubtrees"/>
          <xsl:with-param name="pA0" select="$pA0"/>
          <xsl:with-param name="pSubTrees" select="$pSubTrees[position() > 1]"/>
        </xsl:call-template>
      </xsl:variable>

     <xsl:apply-templates select="$pFuncSubtrees" mode="f:FXSL">
      <xsl:with-param name="arg0" select="$pFuncSubtrees[position() > 1]"/>
      <xsl:with-param name="arg1" select="ext:node-set($vSubTree1Result)"/>
      <xsl:with-param name="arg2" select="ext:node-set($vRestSubtreesResult)"/>
    </xsl:apply-templates>
   </xsl:otherwise>
  </xsl:choose>    
 </xsl:template>
</xsl:stylesheet>

Здесь, кроме дерева, нуля (начальный результат) и функции для обработки каждого узла дерева (вместе с накопленным результатом), мы также передаем в качестве параметра функцию, которая принимает набор всех поддеревьев дерева. узел и накопленный результат до сих пор, и дает новый результат. Также мы должны передать в качестве параметра верхний узел дерева.

Вот простая иллюстрация использования foldl-tree2():

тест-foldlTree2.xsl

<xsl:stylesheet version="1.0" 
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:add-tree="add-tree"
 xmlns:f="http://fxsl.sf.net/"
 exclude-result-prefixes="xsl f add-tree"
>
    <xsl:import href="foldl-tree2.xsl"/>

    <xsl:strip-space elements="*"/>
    <add-tree:add-tree/>

    <xsl:output method="text"/>

    <xsl:template match="/">
      <xsl:variable name="vAdd" select="document('')/*/add-tree:*[1]"/>

      <xsl:call-template name="foldl-tree2">
        <xsl:with-param name="pFuncNode" select="$vAdd"/>
        <xsl:with-param name="pFuncSubtrees" select="$vAdd"/>
        <xsl:with-param name="pA0" select="0"/>
        <xsl:with-param name="pNode" select="/*"/>
      </xsl:call-template>
    </xsl:template>

    <xsl:template match="add-tree:*" mode="f:FXSL">
      <xsl:param name="arg1"/>
      <xsl:param name="arg2"/>

      <xsl:variable name="varg1">
        <xsl:call-template name="nodeValue">
         <xsl:with-param name="pNode" select="$arg1"/>
        </xsl:call-template>
      </xsl:variable>

      <xsl:variable name="varg2">
        <xsl:call-template name="accumValue">
         <xsl:with-param name="pAccum" select="$arg2"/>
        </xsl:call-template>
      </xsl:variable>

      <xsl:value-of select="$varg1 + $varg2"/>
    </xsl:template>

    <xsl:template name="nodeValue">
     <xsl:param name="pNode"/>
     <xsl:call-template name="toNumber">
      <xsl:with-param name="pX" select="$pNode/text()[1]"/>
     </xsl:call-template>
    </xsl:template>

    <xsl:template name="accumValue">
     <xsl:param name="pAccum"/>
     <xsl:call-template name="toNumber">
      <xsl:with-param name="pX" select="$pAccum"/>
     </xsl:call-template>
    </xsl:template>

    <xsl:template name="toNumber">
     <xsl:param name="pX"/>

     <xsl:choose>
      <xsl:when test="not(number($pX) = number($pX))">0</xsl:when>
      <xsl:otherwise>
       <xsl:value-of select="number($pX)"/>
      </xsl:otherwise>
     </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к любому дереву, некоторые из текстовых узлов которого содержат числа :

<nums>
  <a>
   <b>
    <num>01</num>
   </b>
  </a>
  <c>
   <num>02</num>
   <num>03</num>
   <num>04</num>
   <d>
    <num>05</num>
    <num>06</num>
   </d>
  </c>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

выдает сумму всех таких чисел :

55

Теперь нам нужно только передать различные параметры в foldl-tree2(), и он извлечет список совпадений всех значений элемента thing со всеми идентичными значениями в отдельном item, как того требует исходная задача. :

<xsl:stylesheet version="1.0" 
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:msxsl="urn:schemas-microsoft-com:xslt"
 xmlns:ext="http://exslt.org/common"
 xmlns:merge-list="merge-list"
 xmlns:f="http://fxsl.sf.net/"
 exclude-result-prefixes="xsl f ext msxsl merge-list"
>
    <xsl:import href="foldl-tree2.xsl"/>

    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <merge-list:merge-list/>

    <xsl:variable name="vrtfZero">
     <list/>
    </xsl:variable>

    <xsl:variable name="vZero" select=
     "document('')/*/xsl:variable[@name='vrtfZero']/*
     "/>

    <xsl:template match="/">
      <xsl:variable name="vFunMerge" select="document('')/*/merge-list:*[1]"/>

      <list>
       <xsl:call-template name="foldl-tree2">
        <xsl:with-param name="pFuncNode" select="$vFunMerge"/>
        <xsl:with-param name="pFuncSubtrees" select="$vFunMerge"/>
        <xsl:with-param name="pA0" select="$vZero"/>
        <xsl:with-param name="pNode" select="/*"/>
       </xsl:call-template>
      </list>
    </xsl:template>

    <xsl:template match="merge-list:*" mode="f:FXSL">
      <xsl:param name="arg1"/>
      <xsl:param name="arg2"/>

       <xsl:variable name="vrtfArg1">
        <xsl:apply-templates mode="gen" select="$arg1"/>
       </xsl:variable>

       <xsl:variable name="vrtfArg2">
        <xsl:apply-templates mode="gen" select="$arg2"/>
       </xsl:variable>

       <xsl:variable name="vArg1" select="ext:node-set($vrtfArg1)/*"/>
       <xsl:variable name="vArg2" select="ext:node-set($vrtfArg2)/*"/>

       <xsl:for-each select="$vArg1[self::thing or self::item]">
        <xsl:variable name="vMatch" select=
         "$vArg2[self::thing or self::item
               and
                 substring-before(concat(., ' '), ' ')
                =
                 substring-before(concat(current(), ' '), ' ')
                ]"/>
        <xsl:choose>
          <xsl:when test="$vMatch">
            <item>
             <xsl:value-of select="$vMatch/text()"/>
             <xsl:text> </xsl:text>
             <xsl:value-of select="."/>
            </item>
          </xsl:when>
          <xsl:otherwise>
           <xsl:copy-of select="."/>
          </xsl:otherwise>
        </xsl:choose>
       </xsl:for-each>

       <xsl:for-each select="$vArg2[self::thing or self::item]">
        <xsl:variable name="vMatch" select=
         "$vArg1[self::thing or self::item
               and
                 substring-before(concat(., ' '), ' ')
                =
                 substring-before(concat(current(), ' '), ' ')
                ]"/>
          <xsl:if test="not($vMatch)">
           <xsl:copy-of select="."/>
          </xsl:if>
       </xsl:for-each>
    </xsl:template>

    <xsl:template match="thing" mode="gen">
     <item><xsl:value-of select="."/></item>
    </xsl:template>

    <xsl:template match="item" mode="gen">
     <xsl:copy-of select="."/>
    </xsl:template>

    <xsl:template match="*" mode="gen"/>

    <xsl:template mode="gen" match="/">
     <xsl:apply-templates select="*" mode="gen"/>
    </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к первоначально предоставленному документу XML :

<data>
    <thing>string1</thing>
    <thing>string2</thing>
    <thing>string3</thing>
    <nested>
        <thing>string1</thing>
    </nested>
    <nested>
        <thing>string1</thing>
    </nested>
    <nested>
        <thing>string2</thing>
    </nested>
</data>

желаемый, правильный результат выдается :

<list>
   <item>string1 string1 string1</item>
   <item>string2 string2</item>
   <item>string3</item>
</list>

Answer 2

Таблица стилей

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output method="xml" indent="yes"/>

  <xsl:key name="k1" match="thing" use="."/>

  <xsl:template match="data">
    <list>
      <xsl:apply-templates select="descendant::thing[generate-id() = generate-id(key('k1', .)[1])]" mode="group"/>
    </list>
  </xsl:template>

  <xsl:template match="thing" mode="group">
    <item>
      <xsl:apply-templates select="key('k1', .)"/>
    </item>
  </xsl:template>

  <xsl:template match="thing">
    <xsl:if test="position() &gt; 1">
      <xsl:text> </xsl:text>
    </xsl:if>
    <xsl:value-of select="."/>
  </xsl:template>

</xsl:stylesheet>

преобразует вход

<data>
<thing>string1</thing>
<thing>string2</thing>
<thing>string3</thing>
<nested><thing>string1</thing></nested>
<nested><thing>string1</thing></nested>
<nested><thing>string2</thing></nested>
</data>

в выход

<list>
   <item>string1 string1 string1</item>
   <item>string2 string2</item>
   <item>string3</item>
</list>