Как я могу получить текущий URL браузера с помощью скрипта AutoHotKey?

Question

Я ищу способ в AutoHotkey поместить текущий посещенный URL в переменную.

Цель этого AHK - отследить, что я делал в течение дня, чтобы лучше записывать свои часы. У меня есть другая система, которую я использую для синхронизации своей работы, но иногда я забываю использовать ее, когда меня отвлекают.

loop
{
    ; Get current Window ID & Name
    WinGet, active_id, ID, A
    WinGet, process_name, ProcessName, A

    ; Only do anything if any other windows was activated
    if(active_id = PrevActiveId)
    {
        ; Do nothing
    }
    else
    {
        ; Format the time-stamp.
        current=%A_DD%/%A_MM%/%A_YYYY%, %A_Hour%:%A_Min%

        ; Write this data to the log.txt file.
        fileappend, %current% - %process_name%`n, log.txt

        ; Get the URL if process_name = "chrome.exe"
        if(process_name = "chrome.exe")
        {
            ; Put URL in log file
            ; fileappend, %current% - %current_url%`n, log.txt
        }
    }

    PrevActiveId = %active_id%
    Sleep, 100
}

Answer 1

Для Chrome получите текст элемента управления Chrome_OmniboxView1, который является омнибоксом (как для текущей версии Chrome, 21.0.1180.83).

Этот код помещает содержимое омнибокса в переменную omniboxContents:

ControlGetText omniboxContents, Chrome_OmniboxView1, Chrome

Обратите внимание, что omniboxContents не обязательно содержит правильный URL-адрес, поскольку "http://" пропускается, если URL-адрес начинается с" http://".. Таким образом, вместо "http://www.google.com" вы получите" www.google.com ", который, строго говоря, не является правильным URL-адресом. Это просто потому, что Chrome отображает адрес таким образом в омнибоксе. Вам нужно будет добавить дополнительный код, чтобы получить правильный URL-адрес из содержимого омнибокса.

Answer 2

Все браузеры, которые я использовал, поддерживают Alt + D для фокусировки и выбора URL. Вот мои скрипты AHK, которые дублируют текущую вкладку в Google Chrome, Firefox и Internet Explorer, нажав Ctrl + Shift + D ..

#IfWinActive ahk_class MozillaUIWindowClass ; Mozilla Firefox 3.x
   ^+d::GenericDuplicateTab() ; (Control+Shift+D)
#IfWinActive

#IfWinActive ahk_class MozillaWindowClass ; Firefox 4, 5, 6, 7, 8+ (?)
   ^+d::GenericDuplicateTab() ; (Control+Shift+D)
#IfWinActive

#IfWinActive ahk_class Chrome_WidgetWin_1 ; Chromium and Chrome 19+
   ^+d::GenericDuplicateTab() ; (Control+Shift+D)
#IfWinActive

#IfWinActive ahk_class Chrome_WidgetWin_1 ; Chrome 18 and less
   ^+d::GenericDuplicateTab() ; (Control+Shift+D)
#IfWinActive

#IfWinActive ahk_class IEFrame
   ^+d::InternetExplorerDuplicateTab() ; (Control+Shift+D)
#IfWinActive

GenericDuplicateTab()
{
   ; Wait for both Control and Shift to be released.
   KeyWait Control
   KeyWait Shift

   BackupClipbrd := Clipboard
   Sleep 50

   Send !d ; Select the url textbox
   Sleep 150

   Send ^x ; Copy the url
   ClipWait 0.1
   If ERRORLEVEL
   {
    Clipboard := BackupClipbrd
    Return
   }

   Send ^t ; Open a new tab
   Sleep 50

   Send ^v ; Paste the url into the new tab's url textbox
   Sleep 50
   Send {Enter}

   Clipboard := BackupClipbrd
}

InternetExplorerDuplicateTab()
{
   ; Wait for both Control and Shift to be released.
   KeyWait Control
   KeyWait Shift

   Send ^k ; Call IE's shortcut to duplicate tab (Control+K)
   Sleep 100

   Send ^{TAB} ; Switch to that tab
}

Answer 3

Или вы можете использовать F6 .

Большинство браузеров попадают в адресную строку и выбирают весь URL для вас, когда нажимаете F6 .

Тогда дело только в копировальной пасте.

Для более новых версий Firefox его Ctrl + L , хотя.

Для этого вы можете проверить заголовок окна.

Answer 4

Чистый способ сделать это:

    GroupAdd, WebBrowsers, ahk_class MozillaWindowClass
    GroupAdd, WebBrowsers, ahk_class IEFrame
    GroupAdd, WebBrowsers, ahk_class Chrome_WidgetWin_0
    GroupAdd, WebBrowsers, ahk_class Chrome_WidgetWin_1
    GroupAdd, WebBrowsers, ahk_class OperaWindowClass
    GroupAdd, WebBrowsers, ahk_class {1C03B488-D53B-4a81-97F8-754559640193}
    ; etc.

    #IfWinActive, ahk_group WebBrowsers
    {
        ^+d::
        ; [Instructions...]
        return
    }#If

Answer 5

Также возможно сделать это, не полагаясь на буфер обмена, непосредственно проверяя фактические компоненты, которые составляют окно браузера. Дополнительная информация: http://www.autohotkey.com/board/topic/111114-get-the-url-of-the-current-active-browser-tab/. Этот метод гораздо более эффективен, но использует API-интерфейсы ОС.

Answer 6

Используйте функцию WinGetTitle, так как большинство браузеров устанавливают текущий URL в заголовке.

loop
{
    ; Get current Window ID & Name
    WinGet, active_id, ID, A
    WinGet, process_name, ProcessName, A
    WinGetTitle, this_title, ahk_id %active_id%

    ; Format the time-stamp.
    current=%A_DD%/%A_MM%/%A_YYYY%, %A_Hour%:%A_Min%

    ; Only do anything if any other windows was activated
    if(active_id = PrevActiveId)
    {
        if process_name contains chrome.exe,firefox.exe,iexplore.exe,flock.exe,k-meleon.exe,javaw.exe
        {
            ; Write titles to the log.txt file.
            fileappend, %current% - %process_name% - %this_title%`n, log.txt
        }
    }
    else
    {
        ; Write titles to the log.txt file.
        fileappend, %current% - %process_name% - %this_title%`n, log.txt
    }

    Sleep, 1000
    PrevActiveId = %active_id%

}