Как предотвратить создание дополнительной папкой «moc» в qmake в этом сценарии сборки «вне источника»? - PullRequest
Новая
       25

Как предотвратить создание дополнительной папкой «moc» в qmake в этом сценарии сборки «вне источника»?

3 голосов
/ 06 октября 2011

(Извините, я не могу придумать лучшего способа объяснения, кроме как путем включения следующих деталей)

Структура перед сборкой: 

F:\
└ Project\
  └ Project.pro
  └ ProjectSettings.pri
  └ Source\
    └ Source.pro
    └ My_Library\
      └ My_Library.pro
      └ library.cpp
      └ ...

Содержимое "Project.pro"": 

TEMPLATE = subdirs
SUBDIRS = Source

Содержимое" Source.pro ": 

TEMPLATE = subdirs
CONFIG += ordered
SUBDIRS +=  My_Library

Содержимое" My_Library.pro ": 

include(../../ProjectSettings.pri)

TEMPLATE = lib
SOURCES += library.cpp

Содержимое" ProjectSettings.pri "

TARGET = $$basename(_PRO_FILE_PWD_)

Debug:buildDir = "Debug"
Release:buildDir = "Release"

DESTDIR =     $$PWD/$$buildDir/bin
OBJECTS_DIR = $$PWD/$$buildDir/$$basename(_PRO_FILE_PWD_)/obj
MOC_DIR =     $$PWD/$$buildDir/$$basename(_PRO_FILE_PWD_)/moc
RCC_DIR =     $$PWD/$$buildDir/$$basename(_PRO_FILE_PWD_)/rcc
UI_DIR =      $$PWD/$$buildDir/$$basename(_PRO_FILE_PWD_)/gui

Структура после сборки: 

F:\
└ Project\
  └ Project.pro
  └ ProjectSettings.pri
  └ Source\
    └ Source.pro
    └ My_Library\
      └ My_Library.pro
      └ library.cpp
  └ Debug\
    └ bin\
      └ libMy_Library.a
    └ My_Library\
      └ moc\
      └ obj\
        └ library.o
  └ My_Library\   <------ WTF
    └ moc\
  └ Release\
    └ bin\
      └ libMy_Library.a
    └ My_Library\
      └ moc\
      └ obj\
        └ library.o

Задача

Идея

  • запустите qmake -recursive в папке Project
  • , которая создает все указанные подпроекты
  • , выплевывает кучу хорошо организованных промежуточных файлов
  • и размещает все двоичные файлы дляподпроекты в одну папку
  • все они разделены на основе области отладки или выпуска

Кажется, что это работает блестяще, за исключением дополнительной папки для каждого подпроекта впапка Project, каждая из которых содержит папку moc, которую я выделил "WTF" * выше.

Вопросы

  1. Какая (комбинация) инструкций в файлах .pro создает папки "WTF"?
  2. Для чего будет использоваться папка "WTF"?(учитывая, что области Debug и Release задают свой собственный moc)
  3. Есть ли способ предотвратить создание папок "WTF"?

У меня нет источникафайлы, из-за которых MOC выводит файлы moc, поэтому все папки moc на данный момент пусты.

* "WTF" = "What The Folder"

1 Ответ

3 голосов
/ 07 октября 2011

1. Папки создаются до запуска областей отладки и выпуска. qmake создает один первичный файл сборки (Makefile) и, если есть источник для сборки: два дочерних файла сборки (Makefile.Debug и Makefile.Release). Области заданы для дочерних, но не для родительских, поэтому qmake решает, что должно создавать папки, которые не существуют.

2. Насколько я могу судить, он ни для чего не используется.

3. Добавляя уже существующее определение buildDir (в данном случае Source), qmake не заботится о создании дополнительных временных папок. Кроме того, следует изменить область видимости (см. здесь и здесь для объяснения причин). Это сводится к следующему ProjectSettings.pri: 

PROJECT_NAME = $$basename(PWD)
TARGET = $$basename(_PRO_FILE_PWD_)

buildDir = Source
CONFIG( debug, debug|release ) {
    buildDir = "Debug"
} else {
    buildDir = "Release"
}

DESTDIR =     $$PWD/$$buildDir/bin
OBJECTS_DIR = $$PWD/$$buildDir/$$basename(_PRO_FILE_PWD_)/obj
MOC_DIR =     $$PWD/$$buildDir/$$basename(_PRO_FILE_PWD_)/moc
RCC_DIR =     $$PWD/$$buildDir/$$basename(_PRO_FILE_PWD_)/rcc
UI_DIR =      $$PWD/$$buildDir/$$basename(_PRO_FILE_PWD_)/gui

Не совсем уверен, почему это работает, но, похоже, это решает проблему.

...