Perl DBI динамическая выборка в то время как петли - PullRequest
Новая
       30

Perl DBI динамическая выборка в то время как петли

2 голосов
/ 15 мая 2009

Я пытаюсь передать имена таблиц в подпрограмму, которая получает все имена полей этой таблицы, сохраняет их в массиве, а затем использует этот массив в сочетании с выборкой другого SQL-запроса для отображения данных в этих поля. Вот код, который у меня есть сейчас:

Примеры вложенных вызовов с именами таблиц в качестве параметра: 

shamoo("reqhead_rec");
shamoo("approv_rec");
shamoo("denial_rec");

Shamoo Sub: 

sub shamoo
{
    my $table = shift;
    print uc($table)."\n=====================================\n";

    #takes arg (table name) and stores all the field names into an array
    $STMT = <<EOF;
    select first 1 * from $table
    EOF

    my $sth = $db1->prepare($STMT);$sth->execute;

    my ($i, @field);
    my $columns = $sth->{NAME_lc};
    while (my $row = $sth->fetch){for $i (0 .. $#$row){$field[$i] = $columns->[$i];}}

    $STMT = <<EOF;
    select * from $table where frm = '$frm' and req_no = $req_no
    EOF
    $sth = $db1->prepare($STMT);$sth->execute;
    $i=0;
    while ($i!=scalar(@field))
    {
    #need code for in here...
    }
}

Я ищу способ превратить это во что-то, что не должно быть явно определено .... 

my ($frm, $req_no, $auth_id, $alt_auth_id, $id_acct, $seq_no, $id, $appr_stat, $add_date, $approve_date, $approve_time, $prim);
while(($frm, $req_no, $auth_id, $alt_auth_id, $id_acct, $seq_no, $id, $appr_stat, $add_date, $approve_date, $approve_time, $prim) = $sth->fetchrow_array())

Ответы [ 2 ]

12 голосов
/ 15 мая 2009

Использовать fetchrow_hashref: 

sub shamoo {
    my ($dbh, $frm, $req_no, $table) = @_;

    print uc($table), "\n", "=" x 36, "\n";

    #takes arg (table name) and stores all the field names into an array
    my $sth = $dbh->prepare(
        "select * from $table where frm = ? and req_no = ?"
    );

    $sth->execute($frm, $req_no);

    my $i = 1;
    while (my $row = $sth->fetchrow_hashref) {
        print "row ", $i++, "\n";
        for my $col (keys %$row) {
            print "\t$col is $row->{$col}\n";
        }
    }
}

Вы также можете установить FetchHashKeyName на "NAME_lc" или "NAME_uc" при создании дескриптора базы данных: 

my $dbh = DBI->connect(
    $dsn,
    $user,
    $pass,
    {
        ChopBlanks       => 1,
        AutoCommit       => 1,
        PrintError       => 0,
        RaiseError       => 1,
        FetchHashKeyName => "NAME_lc",
    }
) or die DBI->errstr;
2 голосов
/ 15 мая 2009

Интересно, сработает ли этот метод для пустой таблицы.

Самый безопасный способ получить метаданные столбца - это не посмотреть ключи возвращенного хэш-значения (которые могут не существовать), а играть по правилам и использовать предоставленные DBI атрибуты самого $ sth: 

$sth->{NAME}->[i]
$sth->{NAME_uc}->[i]
$sth->{NAME_lc}->[i]

Подробнее см. В разделе «Метаданные» справочной страницы DBI.

...