Более эффективный XSLT для преобразования XML-документа в плоский файл CSV

Question

У меня есть XSLT, который работает и переводит мой XML-документ в CSV. Но его трудно читать (мне не нравятся все ссылки "../../"), и мне интересно, не влияют ли они и на производительность - файл, который я преобразовываю, большой. Я рассмотрел несколько разных примеров, но мне удалось заставить работать только один из приведенных ниже.

Итак, мои вопросы: 1. Можно ли переписать этот XSLT, чтобы он был более кратким и не использовал ссылки "../ ..". 2. Являются ли ссылки типа "../ .." менее эффективными, чем какое-либо хранение значения.

Образцы ниже. Спасибо, John

---

Вот XSLT:

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:template match="/">
   <xsl:apply-templates select="Document"/>
</xsl:template>
<xsl:template match="Document">
   <xsl:apply-templates select="DocBody"/>
</xsl:template>
<xsl:template match="DocBody">
   <xsl:apply-templates select="Values"/>
</xsl:template>
<xsl:template match="Values">
   <xsl:apply-templates select="IntervalValues"/>
</xsl:template>
<xsl:template match="IntervalValues">
   <xsl:apply-templates select="Quantity"/>
</xsl:template>
<xsl:template match="Quantity">
   <xsl:value-of select="concat(../../../../DocHeader/DocTitle,',',../../../../DocHeader/CreatedAt,',',../../../DeliveryDate,',',../../../DeliveryHour,',',../Interval,',',Type,',',Value)"/>
   <xsl:text>&#xA;</xsl:text>
</xsl:template>
</xsl:stylesheet>

---

Вот небольшой пример XML:

<?xml version="1.0" encoding="UTF-8"?>
<Document>
<DocHeader>
<DocTitle>Totals Report</DocTitle>
<DocRevision>1</DocRevision>
<CreatedAt>2011-02-10T21:25:00</CreatedAt>
</DocHeader>
<DocBody>
<DeliveryDate>2011-02-10</DeliveryDate>
<DeliveryHour>22</DeliveryHour>
<Values>
<IntervalValues>
<Interval>1</Interval>
<Quantity>
<Type>Energy</Type>
<Value>18053.5</Value>
</Quantity>
<Quantity>
<Type>Loss</Type>
<Value>438.7</Value>
</Quantity>
<Quantity>
<Type>Load</Type>
<Value>17614.8</Value>
</Quantity>
</IntervalValues>
<IntervalValues>
<Interval>2</Interval>
<Quantity>
<Type>Energy</Type>
<Value>17940.7</Value>
</Quantity>
<Quantity>
<Type>Loss</Type>
<Value>437.7</Value>
</Quantity>
<Quantity>
<Type>Load</Type>
<Value>17503</Value>
</Quantity>
</IntervalValues>
<IntervalValues>
<Interval>3</Interval>
<Quantity>
<Type>Energy</Type>
<Value>17871.7</Value>
</Quantity>
<Quantity>
<Type>Loss</Type>
<Value>437.4</Value>
</Quantity>
<Quantity>
<Type>Load</Type>
<Value>17434.3</Value>
</Quantity>
</IntervalValues>
</Values>
</DocBody>
</Document>

---

Вот пример вывода

Totals Report,2011-02-10T21:25:00,2011-02-10,22,1,Energy,18053.5
Totals Report,2011-02-10T21:25:00,2011-02-10,22,1,Loss,438.7
Totals Report,2011-02-10T21:25:00,2011-02-10,22,1,Load,17614.8
Totals Report,2011-02-10T21:25:00,2011-02-10,22,2,Energy,17940.7
Totals Report,2011-02-10T21:25:00,2011-02-10,22,2,Loss,437.7
Totals Report,2011-02-10T21:25:00,2011-02-10,22,2,Load,17503
Totals Report,2011-02-10T21:25:00,2011-02-10,22,3,Energy,17871.7
Totals Report,2011-02-10T21:25:00,2011-02-10,22,3,Loss,437.4
Totals Report,2011-02-10T21:25:00,2011-02-10,22,3,Load,17434.3

Answer 1

Вы можете вытащить общие части чуть раньше, примерно так:

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>

<xsl:variable name="head">
 <xsl:for-each select="Document/DocHeader">
  <xsl:value-of  select="concat(DocTitle,',',CreatedAt,',')"/>
 </xsl:for-each>
 <xsl:for-each select="Document/DocBody">
  <xsl:value-of  select="concat(DeliveryDate,',',DeliveryHour,',')"/>
 </xsl:for-each>
</xsl:variable>

<xsl:template match="/">
 <xsl:apply-templates select="Document/DocBody/Values/IntervalValues/Quantity"/>
</xsl:template>

<xsl:template match="Quantity">
 <xsl:value-of select="concat($head,../Interval,',',Type,',',Value)"/>
 <xsl:text>&#xA;</xsl:text>
</xsl:template>

</xsl:stylesheet>

Answer 2

Вам легче читать?

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>
  <xsl:template match="/Document">
    <xsl:variable name="header" select="DocHeader"/>
    <xsl:variable name="body" select="DocBody" />
    <xsl:for-each select="DocBody/Values">
      <xsl:for-each select="IntervalValues">
        <xsl:variable name="interval" select="Interval"/>
        <xsl:for-each select="Quantity">
        <xsl:value-of select="$header/DocTitle"/>
        <xsl:text>,</xsl:text>
        <xsl:value-of select="$header/CreatedAt"/>
        <xsl:text>,</xsl:text>
        <xsl:value-of select="$body/DeliveryDate"/>
        <xsl:text>,</xsl:text>
        <xsl:value-of select="$body/DeliveryHour"/>
        <xsl:text>,</xsl:text>
        <xsl:value-of select="$interval"/>
        <xsl:text>,</xsl:text>
        <xsl:value-of select="Type"/>
        <xsl:text>,</xsl:text>
        <xsl:value-of select="Value"/>
        <xsl:text>&#xA;</xsl:text>
        </xsl:for-each>
      </xsl:for-each>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>