Заменить строку на элементы рекурсивно

Question

Я пытаюсь изменить строки вроде:
Some {words} should be {bold} ...
на что-то вроде
Some <b>words</b> should be <b>bold</b> ...

Однако моя реализация забывает все <b>элементы, кроме последнего:
Some words should be <b>bold</b> ...

Я думаю, что substring-before () удаляет уже вставленные <b> элементы.
Вот мой код:

<xsl:template name="replace">
  <xsl:param name="input"/>

  <xsl:variable name="before" select="substring-before( $input, '{' )" />
  <xsl:variable name="after" select="substring-after( $input, '}' )" />
  <xsl:variable name="replace" select="substring-after( substring-before( $input, '}' ), '${' )" />

  <xsl:choose>
    <xsl:when test="$replace">
      <xsl:call-template name="replace">
        <xsl:with-param name="input">
          <xsl:value-of select="$before" />
          <xsl:element name="b">
            <xsl:value-of select="$replace" />
          </xsl:element>
          <xsl:value-of select="$after" />
        </xsl:with-param>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:copy-of select="$input" />
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Есть идеи?Спасибо за вашу помощь.

Answer 1

Поскольку вы пометили вопрос как XSLT 2.0, я настоятельно рекомендую использовать analyze-string, то есть с

<text>Some {words} should be {bold} ...</text>

и таблица стилей

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

  <xsl:template match="text">
    <xsl:analyze-string select="." regex="\{{(.*?)\}}">
      <xsl:matching-substring>
        <b>
          <xsl:value-of select="regex-group(1)"/>
        </b>
      </xsl:matching-substring>
      <xsl:non-matching-substring>
        <xsl:value-of select="."/>
      </xsl:non-matching-substring>
    </xsl:analyze-string>
  </xsl:template>

</xsl:stylesheet>

выходы

Some <b>words</b> should be <b>bold</b> ...

Answer 2

Я нашел ответ сам ...

Передавал только оставшуюся строку в качестве параметра для рекурсивного вызова:

<xsl:template name="replace">
  <xsl:param name="input"/>

  <xsl:variable name="before" select="substring-before( $input, '{' )" />
  <xsl:variable name="after" select="substring-after( $input, '}' )" />
  <xsl:variable name="replace" select="substring-after( substring-before( $input, '}' ), '${' )" />

  <xsl:choose>
    <xsl:when test="$replace">

      <!-- moved outside the recursive call -->
      <xsl:value-of select="$before" />
      <xsl:element name="b">
        <xsl:value-of select="$replace" />
      </xsl:element>

      <xsl:call-template name="replace">
        <xsl:with-param name="input">
          <xsl:value-of select="$after" />
        </xsl:with-param>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:copy-of select="$input" />
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Так что substring-before () функция не была проблемой ...