XSL повторяет родительский узел для каждого дочернего узла

Question

Для каждого дочернего узла я хочу продублировать свой родительский узел, чтобы в результирующем xml содержался только один дочерний узел для родительского узла, а остальные узлы были одинаковыми.

Вот пример ввода

<a>
  <a1>header1</a1>
  <a2>header2</a2>
  <a3>
     <a31>
          <a311>line_1</a311>
          <a311>line_2</a311>
     </a31>
     <a32>5o$</a32>
     <a33>Add</a33>
  </a3>
  <a4>account_holder</a4>
</a>

Что я хочу сделать - повторить a3 столько раз, сколько приходит узел a311.Остальные все узлы сохраняются

Вывод

<a>
   <a1>header1</a1>
   <a2>header2</a2>
   <a3>
      <a31>
          <a311>line_1</a311>
      </a31>
      <a32>5o$</a32>
      <a33>Add</a33>
   </a3>
   <a3>
      <a31>
          <a311>line_2</a311>
      </a31>
      <a32>5o$</a32>
      <a33>Add</a33>
    </a3>
    <a4>account_holder</a4>
</a>

Answer 1

Следующая (XSLT 1.0) таблица стилей дает желаемый результат:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>
    <xsl:template match="a3">
        <xsl:apply-templates select="a31/a311" />
    </xsl:template>
    <xsl:template match="a311">
        <a3>
            <a31>
                <a311>
                    <xsl:value-of select="." />
                </a311>
            </a31>
            <xsl:apply-templates select="../../*[not(self::a31)]" />
        </a3>
    </xsl:template>
</xsl:stylesheet>

Answer 2

Больше семантики с шаблоном "tunnel param", эта таблица стилей:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()" name="identity">
        <xsl:param name="pCurrent"/>
        <xsl:copy>
            <xsl:apply-templates select="@*|node()">
                <xsl:with-param name="pCurrent" select="$pCurrent"/>
            </xsl:apply-templates>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="a3">
        <xsl:variable name="vCurrent" select="."/>
        <xsl:variable name="vDescendants" select=".//a311"/>
        <xsl:for-each select="$vDescendants|$vCurrent[not($vDescendants)]">
            <xsl:variable name="vDescendant" select="."/>
            <xsl:for-each select="$vCurrent">
                <xsl:call-template name="identity">
                    <xsl:with-param name="pCurrent" select="$vDescendant"/>
                </xsl:call-template>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:template>
    <xsl:template match="a311">
        <xsl:param name="pCurrent"/>
        <xsl:if test="generate-id()=generate-id($pCurrent)">
            <xsl:call-template name="identity"/>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

Вывод:

<a>
    <a1>header1</a1>
    <a2>header2</a2>
    <a3>
        <a31>
            <a311>line_1</a311>
        </a31>
        <a32>5o$</a32>
        <a33>Add</a33>
    </a3>
    <a3>
        <a31>
            <a311>line_2</a311>
        </a31>
        <a32>5o$</a32>
        <a33>Add</a33>
    </a3>
    <a4>account_holder</a4>
</a>

EDIT : Обработка без потомков.

Answer 3

Вы не указали версию XSLT. Вот таблица стилей XSLT2, которая выполнит то, что вы хотите:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="a3" mode="#default">
    <xsl:apply-templates select="a31/a311"/>
  </xsl:template>

  <xsl:template match="a311">
    <xsl:apply-templates select="../.." mode="x">
      <xsl:with-param name="label" select="text()"/>
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="a3" mode="x">
    <xsl:param name="label"/>
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <a31>
        <a311><xsl:value-of select="$label"/></a311>
      </a31>
      <xsl:apply-templates select="* except a31"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

Он использует преобразование идентификаторов для прохождения «неинтересных» элементов при захвате узла <a3> и применении специальной обработки. Если вам нужно решение XSLT1, просто

• Заменить select="* except a31" на select="*[name() != 'a31']"
• Удалите mode="#default" из первого шаблона "a3"