Как я могу получить информацию о полосах прокрутки экземпляра элемента управления Webbrowser или IE Webrowser?

Question

Мне нужно получить информацию о полосах прокрутки (положение, размер, видимость) элемента управления Webbrowser внешнего приложения, я попытался использовать функцию GetScrollBarInfo из моего предыдущего question , но функция всегда возвращает false, я проверил эту функцию с другими приложениями и работает нормально, но не с IE или элементом управления Webbrowser. So how I can get information about the scrollbars of an Webbrowser control instance or the IE Webbrowser?

Answer 1

Вы можете отправить WM_HTML_GETOBJECT сообщение в "Internet Explorer_Server" окно класса внешнего приложения для получения IHtmlDocument2, затем, используя IServiceProvider, вы можете получить IWebBrowser2 интерфейс.
Вот пример кода на Delphi:

uses
  ActiveX, MSHTML;

type
  TObjectFromLResult = function(LRESULT: lResult; const IID: TIID;
    wParam: wParam; out pObject): HRESULT; stdcall;

function GetIEFromHWND(WHandle: HWND; var IE: IWebbrowser2): HRESULT;
var
  hInst: HWND;
  lRes: Cardinal;
  Msg: Integer;
  pDoc: IHTMLDocument2;
  ObjectFromLresult: TObjectFromLresult;
begin
  Result := S_FALSE;
  hInst := LoadLibrary('Oleacc.dll');
  @ObjectFromLresult := GetProcAddress(hInst, 'ObjectFromLresult');
  if @ObjectFromLresult <> nil then
  try
    Msg := RegisterWindowMessage('WM_HTML_GETOBJECT');
    SendMessageTimeOut(WHandle, Msg, 0, 0, SMTO_ABORTIFHUNG, 1000, lRes);
    Result := ObjectFromLresult(lRes, IHTMLDocument2, 0, pDoc);
    if Result = S_OK then
      (pDoc.parentWindow as IServiceprovider).QueryService(
        IWebbrowserApp, IWebbrowser2, IE);
  finally
    FreeLibrary(hInst);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Wnd, WndChild: HWND;
  IE: IWebBrowser2;
  Document: IHtmlDocument2;
  ScrollTop, ScrollLeft: Integer;
begin
  Wnd := FindWindow('IEFrame', nil); // top level IE
  if Wnd = 0 then Exit;
  WndChild := FindWindowEX(Wnd, 0, 'Shell DocObject View', nil);
  if WndChild = 0 then Exit;
  WndChild := FindWindowEX(WndChild, 0, 'Internet Explorer_Server', nil);
  if WndChild = 0 then Exit;

  GetIEFromHWnd(WndChild, IE);
  if IE <> nil then
  begin
    ShowMessage(IE.LocationURL);
    Document := IE.Document as IHtmlDocument2;
    ScrollTop := ((Document as IHTMLDocument3).documentElement as IHTMLElement2).scrollTop;
    ScrollLeft := ((Document as IHTMLDocument3).documentElement as IHTMLElement2).scrollLeft;
    ShowMessage(Format('%d;%d', [ScrollTop, ScrollLeft]));

    // visible|hidden|scroll|auto|no-display|no-content
    ShowMessage(OleVariant(Document).documentElement.currentStyle.overflowX);
    ShowMessage(OleVariant(Document).documentElement.currentStyle.overflowY);
  end;
end;

---

Редактировать: , когда страница использует директиву <!DOCTYPE> для переключения IE6 на строгий стандартный режим использования document.documentElement. (IHTMLDocument3) в предстандартном режиме тело представляет собой область прокрутки, так что вы можете получить положение прокрутки с помощью document.body.scrollTop. В стандартном режиме элемент HTML можно прокручивать, поэтому вы должны использовать document.documentElement.scrollTop.

Если document.documentElement.clientWidth <> 0 использовать элемент documentElement для свойств, в противном случае используйте элемент body.
Полезные свойства, связанные с информацией прокрутки, также clientHeight, scrollWidth, scrollHeight.

Answer 2

Вот как вы можете узнать, видны ли полосы прокрутки или нет. Некоторая проверка ошибок пропущена для краткости.

LPDISPATCH      lpDispatch;
lpDispatch      = m_Browser.GetDocument();

IHTMLDocument2 *doc2 = NULL;
disp->QueryInterface(IID_IHTMLDocument2,(void**)&doc2);

IHTMLElement *lpBodyElement; 
IHTMLBodyElement *lpBody; 

doc2->get_body(&lpBodyElement); 
if ( lpBodyElement )
{
lpBodyElement->QueryInterface(IID_IHTMLBodyElement,(void**)&lpBody); 
if ( lpBody )
{
    BSTR bstrText; 
            pBody->get_scroll(&bstrText);
    lpBody->Release(); 
}
lpBodyElement->Release(); 
}
doc2->Release();

Возможные значения для bstrText: «да», «нет», «авто» (полосы прокрутки отображаются, когда содержимое страницы превышает область клиента)

А вот как узнать текущую позицию прокрутки:

IHTMLElement2 *pElement = NULL;
hr = pBody->QueryInterface(IID_IHTMLElement2,(void**)&pElement);
ASSERT(SUCCEEDED(hr));
ASSERT( pElement );
long scroll_pos;
pElement->get_scrollTop( &scroll_pos);