Использование параметра datetime с ADO (ODBC) теряет часть времени - PullRequest
Новая
       21

Использование параметра datetime с ADO (ODBC) теряет часть времени

5 голосов
/ 30 декабря 2011

Я наткнулся на эту проблему вчера, когда был занят написанием некоторых модульных тестов с использованием SQLLite.Моя среда - Windows7 / Delphi XE.

Использование TADOQuery в сочетании с параметром TDateTime приводит к потере части времени. 

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ADODb, DateUtils, DB;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);

var DbConn : TADOConnection;
    Qry    : TADOQuery;
    DT     : TDateTime;

begin
 DBConn := TADOConnection.Create(nil);
 DBConn.ConnectionString := 'Provider=MSDASQL.1;Extended Properties="DRIVER=SQLite3 ODBC Driver;Database=:memory:;LongNames=0;Timeout=1000;NoTXN=0;SyncPragma=NORMAL;StepAPI=0;"';
//   DBConn.ConnectionString := 'Provider=MSDASQL.1;Persist Security Info=True;User ID=%0:s;Password=%1:s;Extended Properties="DRIVER={MySQL ODBC 5.1 Driver};SERVER=localhost;PORT=3306;DATABASE=test;USER=root;PASSWORD=rrr;OPTION=1048579"';
 Qry := TADOQuery.Create(nil);
 Qry.Connection := DbConn;
 try
  DBConn.Connected := True;
  Qry.SQL.Text := 'CREATE TABLE test(d datetime)';
  Qry.ExecSQL;
  Qry.ParamCheck := True;
  Qry.SQL.Text := 'INSERT INTO test (d) VALUES (:d)';
  //Qry.Parameters.ParseSQL(Qry.SQL.Text, True); // not needed
  TryEncodeDateTime(1999, 12, 12, 10, 59, 12, 0, DT);
  Qry.Parameters.ParamByName('d').Value := DT;
  Qry.Parameters.ParamByName('d').DataType := ftDateTime;
  Qry.ExecSQL;
  Qry.SQL.Text := 'SELECT d FROM test';
  Qry.Open;
  ShowMessage(FormatDateTime('MM/DD/YYYY HH:NN:SS', Qry.FieldByName('d').AsDateTime));
 finally
  FreeAndNil(Qry);
  FreeAndNil(DbConn);
 end;
end;

Забавно, когда я комментирую строку Qry.Parameters.ParseSQL(Qry.SQL.Text, True); Это будет работать нормально.Мне нужна часть ParseSQL, потому что я создаю мини-ORM, поэтому он должен знать, какие параметры должны быть отображены.Некоторые замечания:

  • Выполнение того же теста с MySQL5 показывает ту же проблему (независимо от части ParseSQL).
  • Этот код работает с SQL Server и драйвером OLEDB.

Я обыскал сеть и нашел несколько интересных ссылок:

http://tracker.firebirdsql.org/browse/ODBC-27

http://embarcadero.newsgroups.archived.at/public.delphi.database.ado/201107/1107112007.html

http://bugs.mysql.com/bug.php?id=15681

Первая ссылка предлагает «исправить» ADODB.pas, что я не хочу делать.Читая последнюю ссылку, кажется, что ADO отображает значение datetime на date.

Ответ Я не хочу слышать: используйте другую библиотеку / компонент (например, Dbexpress, Zeoslib, ...)

Я не уверен, что будет наиболее разумным подходом к решению этой проблемы.

Как предположили Линас и Марьян Венема, я могу опустить часть ParseSQL.Теперь код работает с SQLlite, ЕСЛИ я пропускаю строку Qry.Parameters.ParamByName('d').DataType := ftDateTime;.

Но MySQL отказывается экономить часть времени.Я вижу проблему совместимости между ADO и MySQL ODBC здесь?

Ответы [ 2 ]

8 голосов
/ 30 декабря 2011

Я немного протестировал это с использованием SQL Server и у меня точно такая же проблема, когда я использую MSDASQL.1 (ODBC). Ваш код отлично работает с SQLOLEDB.1 и SQLNCLI10.1.

Если указать тип параметра ftString, он будет экономить со временем с использованием ODBC (по крайней мере, на SQL Server). 

Qry.Parameters.ParamByName('d').DataType := ftString;
Qry.Parameters.ParamByName('d').Value := DateTimeToStr(DT);

Примечание: будьте осторожны с локальными настройками, когда вы используете DateTimeToStr, он может не дать того, чего хочет ваш БД. Безопасной ставкой было бы использовать yyyy-mm-dd hh:mm:ss[.fff].

Обновление:

Вы также можете установить тип данных параметра ado на adDBTimeStamp самостоятельно. ADODB устанавливает его на adDate, когда вы используете ftDateTime. 

Qry.Parameters.ParamByName('d').ParameterObject.Type_ := adDBTimeStamp;
Qry.Parameters.ParamByName('d').Value := DT;
0 голосов
/ 22 мая 2016

У меня была такая же проблема с VFPOLEDB (драйвер Visual FoxPro), но трюк с adDBTimeStamp не сработал.FWIW, это VFPOLEDB 9.0.0.5815 с Delphi 7, а также с RAD Studio 10 (Сиэтл).

В случае VFPOLEDB существует другой возможный обходной путь, основанный на том факте, что в Fox основное представление для даты/ Значения времени (тип 'T') такие же, как у значений даты (тип 'D'), передаваемых OLEDB, то есть 64-битное двойное число, где целая часть представляет дни с 1 января года 0001 и дробное числоpart представляет время дня.

Если поле таблицы имеет тип 'T', а OLEDB передает дату, то Fox принудительно возвращает значение, ничего не делая вообще.Таким образом, все, что здесь необходимо, это добавить обратно в дробную часть.

Пример, с start_time, являющимся полем даты / времени: 

cmd.CommandText := 'insert into foo (start_time) values (:start_time)';
cmd.Parameters.ParamByName('start_time') := Now;
cmd.Execute;

Это дает 2016-05-22 00:00:00 в таблице.

Теперь добавьте дробную часть следующим образом: 

cmd.CommandText := 'insert into foo (start_time) values (:start_time + :fraction)';
t := Now;
cmd.Parameters.ParamByName('start_time') := t;
cmd.Parameters.ParamByName('fraction') := Frac(t);
cmd.Execute;

Это даст 2016-05-22 02:17:42.Сохраняются даже доли секунды, хотя они не отображаются.

...